Groovy виконання команд оболонки

Groovy додає executeспосіб Stringзробити виконання снарядів досить простим;

println "ls".execute().text

але якщо трапляється помилка, то результату немає. Чи є простий спосіб усунути як стандартну помилку, так і стандартну? (крім створення куки коду; створити два потоки для читання обох вхідних потоків, а потім за допомогою батьківського потоку дочекатися їх завершення, а потім перетворити рядки назад у текст?)

Було б непогано мати щось на кшталт;

 def x = shellDo("ls /tmp/NoFile")
 println "out: ${x.out} err:${x.err}"

Гаразд, вирішив це сам;

def sout = new StringBuilder(), serr = new StringBuilder()
def proc = 'ls /badDir'.execute()
proc.consumeProcessOutput(sout, serr)
proc.waitForOrKill(1000)
println "out> $sout err> $serr"

дисплеї:

out> err> ls: cannot access /badDir: No such file or directory

"ls".execute()повертає Processоб'єкт, через що "ls".execute().textпрацює. Ви повинні мати можливість просто прочитати потік помилок, щоб визначити, чи були помилки.

Існує додатковий метод на Processякі дозволяють пропускати , StringBufferщоб отримати текст: consumeProcessErrorStream(StringBuffer error).

Приклад:

def proc = "ls".execute()
def b = new StringBuffer()
proc.consumeProcessErrorStream(b)

println proc.text
println b.toString()

// a wrapper closure around executing a string                                  
// can take either a string or a list of strings (for arguments with spaces)    
// prints all output, complains and halts on error                              
def runCommand = { strList ->
  assert ( strList instanceof String ||
           ( strList instanceof List && strList.each{ it instanceof String } ) \
)
  def proc = strList.execute()
  proc.in.eachLine { line -> println line }
  proc.out.close()
  proc.waitFor()

  print "[INFO] ( "
  if(strList instanceof List) {
    strList.each { print "${it} " }
  } else {
    print strList
  }
  println " )"

  if (proc.exitValue()) {
    println "gave the following error: "
    println "[ERROR] ${proc.getErrorStream()}"
  }
  assert !proc.exitValue()
}

Я вважаю це більш ідіоматичним:

def proc = "ls foo.txt doesnotexist.txt".execute()
assert proc.in.text == "foo.txt\n"
assert proc.err.text == "ls: doesnotexist.txt: No such file or directory\n"

Як згадується інша публікація, це блокування дзвінків, але оскільки ми хочемо працювати з висновком, це може знадобитися.

Щоб додати ще одну важливу інформацію до наведених вище відповідей -

Для процесу

def proc = command.execute();

завжди намагайтеся використовувати

def outputStream = new StringBuffer();
proc.waitForProcessOutput(outputStream, System.err)
//proc.waitForProcessOutput(System.out, System.err)

а не

def output = proc.in.text;

для захоплення виходів після виконання команд у groovy, оскільки останній є блокуючим викликом ( ТАК питання з причини ).

def exec = { encoding, execPath, execStr, execCommands ->

def outputCatcher = new ByteArrayOutputStream()
def errorCatcher = new ByteArrayOutputStream()

def proc = execStr.execute(null, new File(execPath))
def inputCatcher = proc.outputStream

execCommands.each { cm ->
    inputCatcher.write(cm.getBytes(encoding))
    inputCatcher.flush()
}

proc.consumeProcessOutput(outputCatcher, errorCatcher)
proc.waitFor()

return [new String(outputCatcher.toByteArray(), encoding), new String(errorCatcher.toByteArray(), encoding)]

}

def out = exec("cp866", "C:\\Test", "cmd", ["cd..\n", "dir\n", "exit\n"])

println "OUT:\n" + out[0]
println "ERR:\n" + out[1]

command = "ls *"

def execute_state=sh(returnStdout: true, script: command)

але в разі відмови команди процес припиняється