String.Format як функціональність у T-SQL?

90

Я шукаю вбудовану функцію / розширену функцію в T-SQL для маніпулювання рядками, подібну до String.Formatметоду в .NET.

tsql  string 
— Джефф
джерело

Відповіді:

70

Якщо ви використовуєте SQL Server 2012 і вище, ви можете використовувати FORMATMESSAGE. напр.

DECLARE @s NVARCHAR(50) = 'World';
DECLARE @d INT = 123;
SELECT FORMATMESSAGE('Hello %s, %d', @s, @d)
-- RETURNS 'Hello World, 123'

Інші приклади від MSDN: FORMATMESSAGE

SELECT FORMATMESSAGE('Signed int %i, %d %i, %d, %+i, %+d, %+i, %+d', 5, -5, 50, -50, -11, -11, 11, 11);
SELECT FORMATMESSAGE('Signed int with leading zero %020i', 5);
SELECT FORMATMESSAGE('Signed int with leading zero 0 %020i', -55);
SELECT FORMATMESSAGE('Unsigned int %u, %u', 50, -50);
SELECT FORMATMESSAGE('Unsigned octal %o, %o', 50, -50);
SELECT FORMATMESSAGE('Unsigned hexadecimal %x, %X, %X, %X, %x', 11, 11, -11, 50, -50);
SELECT FORMATMESSAGE('Unsigned octal with prefix: %#o, %#o', 50, -50);
SELECT FORMATMESSAGE('Unsigned hexadecimal with prefix: %#x, %#X, %#X, %X, %x', 11, 11, -11, 50, -50);
SELECT FORMATMESSAGE('Hello %s!', 'TEST');
SELECT FORMATMESSAGE('Hello %20s!', 'TEST');
SELECT FORMATMESSAGE('Hello %-20s!', 'TEST');
SELECT FORMATMESSAGE('Hello %20s!', 'TEST');

ПРИМІТКИ:

  • Без документів у 2012 році
  • Обмежено до 2044 символів
  • Щоб уникнути знака%, потрібно подвоїти його.
  • Якщо ви FORMATMESSAGEреєструєте помилки в розширених подіях, виклик виявляється як (нешкідлива) помилка
— g2server
джерело
1
Якщо ви використовуєте SQL 2012, ви можете використовувати функцію FORMAT без усіх перерахованих вище ускладнень :)
— Reversed Engineer
1
Це має набагато більше голосів! Дивовижної знахідки завжди уникали, оскільки припускали, що вона буде працювати лише з вбудованим msg_number.
— Ланкімарт
1
@Lankymart, удар! Я згоден, що це повинна бути прийнята відповідь: проста, вбудована і чудово працювала.
— Роберт Синорадкі
5
@bijayk він приймає лише конкретні імена заповнювачів, наприклад,% s для рядків,% i для ints.
— g2server
2
@lostmylogin У string.FormatT-SQL немає функціональних можливостей, це найближче.
— Ян Кемп,
53

погляньте на xp_sprintf . приклад нижче.

DECLARE @ret_string varchar (255)
EXEC xp_sprintf @ret_string OUTPUT, 
    'INSERT INTO %s VALUES (%s, %s)', 'table1', '1', '2'
PRINT @ret_string

Результат виглядає так:

INSERT INTO table1 VALUES (1, 2)

Щойно знайшов проблему з максимальним розміром (обмеження 255 символів) рядка з цим, тому є альтернативна функція, яку ви можете використовувати:

create function dbo.fnSprintf (@s varchar(MAX), 
                @params varchar(MAX), @separator char(1) = ',')
returns varchar(MAX)
as
begin
declare @p varchar(MAX)
declare @paramlen int

set @params = @params + @separator
set @paramlen = len(@params)
while not @params = ''
begin
    set @p = left(@params+@separator, charindex(@separator, @params)-1)
    set @s = STUFF(@s, charindex('%s', @s), 2, @p)
    set @params = substring(@params, len(@p)+2, @paramlen)
end
return @s
end

Щоб отримати той самий результат, що і вище, ви викликаєте функцію наступним чином:

print dbo.fnSprintf('INSERT INTO %s VALUES (%s, %s)', 'table1,1,2', default)
— Джош
джерело
7
Просто FYI, якщо будь-який із ваших параметрів містить кому, тоді вам не пощастило. Якщо ви випадково проїхали одного випадково, у вас виникнуть певні проблеми, коли з’ясувати, що пішло не так.
— Kyle
15

Я створив призначену користувачем функцію для імітації функціональності string.format. Ви можете ним скористатися.

stringformat-in-sql

— Картик Д.В.
джерело
Мені подобається це рішення, оскільки я маю застереження щодо використання функцій xp_ / SP у виробництві. Я використав ваш код як основу і дозволив передати роздільник, що виключає будь-яку стурбованість комами, які використовуються в даних.
— Тім Фрізен
4

Є спосіб, але він має свої обмеження. Ви можете скористатися FORMATMESSAGE()функцією. Це дозволяє форматувати рядок із використанням форматування, подібного доprintf() функції в C.

Однак найбільшим обмеженням є те, що він буде працювати лише з повідомленнями в таблиці sys.messages. Ось стаття про це: microsoft_library_ms186788

Шкода, що не існує простішого способу зробити це, тому що бувають випадки, коли ви хочете відформатувати рядок / varchar у базі даних. Сподіваємось, ви лише прагнете відформатувати рядок стандартним способом і можете використовувати sys.messagesтаблицю.

За збігом обставин, ви також можете використовувати RAISERROR()функцію з дуже низьким ступенем серйозності, документація для riseerror навіть згадує про це, але результати лише друкуються. Отже, ви не зможете нічого зробити з отриманою цінністю (наскільки я розумію).

Удачі!

— jj.
джерело
1
Зрозумійте , що це старий відповідь , але припущення про FORMATMESSAGE()невірно, проте зрозуміло , тому що він не документований , але він буде приймати будь-який рядок в якості першого параметра, див цієї відповіді на @ g2server .
— Ланкімарт
@Lankymart Ви маєте рацію - це стара відповідь. Можливість приймати рядок не була додана до SQL 2012.
— jj.
3

Сировина t-sql обмежена CHARINDEX (), PATINDEX (), REPLACE () та SUBSTRING () для маніпулювання рядками. Але на сервері sql 2005 та пізніших версій ви можете налаштувати визначені користувачем функції, що працюють у .Net, що означає, що налаштування string.format () UDF не повинно бути занадто жорстким.

— Джоел Кегурн
джерело
2

Ще одна ідея.

Хоча це не універсальне рішення - воно просте і працює, принаймні для мене :)

Для одного заповнювача {0}:

create function dbo.Format1
(
    @String  nvarchar(4000),
    @Param0  sql_variant
)
returns nvarchar(4000)
as
begin
    declare @Null nvarchar(4) = N'NULL';

    return replace(@String, N'{0}', cast(isnull(@Param0, @Null) as nvarchar(4000)));    
end

Для двох заповнювачів {0} та {1}:

create function dbo.Format2
(
    @String  nvarchar(4000),
    @Param0  sql_variant,
    @Param1  sql_variant
)
returns nvarchar(4000)
as
begin
    declare @Null nvarchar(4) = N'NULL';

    set @String = replace(@String, N'{0}', cast(isnull(@Param0, @Null) as nvarchar(4000)));
       return     replace(@String, N'{1}', cast(isnull(@Param1, @Null) as nvarchar(4000))); 
end

Для трьох заповнювачів {0}, {1} та {2}:

create function dbo.Format3
(
    @String  nvarchar(4000),
    @Param0  sql_variant,
    @Param1  sql_variant,
    @Param2  sql_variant
)
returns nvarchar(4000)
as
begin
    declare @Null nvarchar(4) = N'NULL';

    set @String = replace(@String, N'{0}', cast(isnull(@Param0, @Null) as nvarchar(4000)));
    set @String = replace(@String, N'{1}', cast(isnull(@Param1, @Null) as nvarchar(4000))); 
       return     replace(@String, N'{2}', cast(isnull(@Param2, @Null) as nvarchar(4000)));
end

і так далі...

Такий підхід дозволяє нам використовувати ці функції в операторі SELECT та з параметрами типів даних nvarchar, number, bit та datetime.

Наприклад:

declare @Param0 nvarchar(10) = N'IPSUM' ,
        @Param1 int          = 1234567  ,
        @Param2 datetime2(0) = getdate();

select dbo.Format3(N'Lorem {0} dolor, {1} elit at {2}', @Param0, @Param1, @Param2);
— Вадим Лобода
джерело
1

Думаю, є невелика корекція під час обчислення кінцевої позиції.

Ось правильна функція

**>>**IF OBJECT_ID( N'[dbo].[FormatString]', 'FN' ) IS NOT NULL
DROP FUNCTION [dbo].[FormatString]
GO
/***************************************************
Object Name : FormatString
Purpose : Returns the formatted string.
Original Author : Karthik D V http://stringformat-in-sql.blogspot.com/
Sample Call:
SELECT dbo.FormatString ( N'Format {0} {1} {2} {0}', N'1,2,3' )
*******************************************/
CREATE FUNCTION [dbo].[FormatString](
    @Format NVARCHAR(4000) ,
    @Parameters NVARCHAR(4000)
)
RETURNS NVARCHAR(4000)
AS
BEGIN
    --DECLARE @Format NVARCHAR(4000), @Parameters NVARCHAR(4000) select @format='{0}{1}', @Parameters='hello,world'
    DECLARE @Message NVARCHAR(400), @Delimiter CHAR(1)
    DECLARE @ParamTable TABLE ( ID INT IDENTITY(0,1), Parameter VARCHAR(1000) )
    Declare @startPos int, @endPos int
    SELECT @Message = @Format, @Delimiter = ','**>>**

    --handle first parameter
     set @endPos=CHARINDEX(@Delimiter,@Parameters)
    if (@endPos=0 and @Parameters is not null) --there is only one parameter
        insert into @ParamTable (Parameter) values(@Parameters)
    else begin
        insert into @ParamTable (Parameter) select substring(@Parameters,0,@endPos)
    end

    while @endPos>0
    Begin
        --insert a row for each parameter in the 
        set @startPos = @endPos + LEN(@Delimiter)
        set @endPos = CHARINDEX(@Delimiter,@Parameters, @startPos)
        if (@endPos>0)
            insert into @ParamTable (Parameter) 
                select substring(@Parameters,@startPos,@endPos - @startPos)
            else
                insert into @ParamTable (Parameter) 
                select substring(@Parameters,@startPos,4000)            
    End

    UPDATE @ParamTable SET @Message = 
        REPLACE ( @Message, '{'+CONVERT(VARCHAR,ID) + '}', Parameter )
    RETURN @Message
END
Go
grant execute,references on dbo.formatString to public
— SP007
джерело
1

Ось моя версія. Можна розширити, щоб вмістити більшу кількість параметрів, а також розширити форматування залежно від типу. На даний момент відформатовано лише типи дати та часу.

Приклад:

select dbo.FormatString('some string %s some int %s date %s','"abcd"',100,cast(getdate() as date),DEFAULT,DEFAULT)
select dbo.FormatString('some string %s some int %s date time %s','"abcd"',100,getdate(),DEFAULT,DEFAULT)

Вихід:

some string "abcd" some int 100 date 29-Apr-2017
some string "abcd" some int 100 date time 29-Apr-2017 19:40

Функції:

create function dbo.FormatValue(@param sql_variant)
returns nvarchar(100)
begin
/*
Tejasvi Hegde, 29-April-2017
Can extend formatting here.
*/
    declare @result nvarchar(100)

    if (SQL_VARIANT_PROPERTY(@param,'BaseType') in ('date'))
    begin
       select @result = REPLACE(CONVERT(CHAR(11), @param, 106), ' ', '-')
    end
    else  if (SQL_VARIANT_PROPERTY(@param,'BaseType') in ('datetime','datetime2'))
    begin
       select @result = REPLACE(CONVERT(CHAR(11), @param, 106), ' ', '-')+' '+CONVERT(VARCHAR(5),@param,108)
    end
    else
    begin
       select @result = cast(@param as nvarchar(100))
    end
    return @result

/*
BaseType:
bigint
binary
char
date
datetime
datetime2
datetimeoffset
decimal
float
int
money
nchar
numeric
nvarchar
real
smalldatetime
smallint
smallmoney
time
tinyint
uniqueidentifier
varbinary
varchar
*/   

end;


create function dbo.FormatString(
    @format nvarchar(4000)
    ,@param1 sql_variant = null
    ,@param2 sql_variant = null
    ,@param3 sql_variant = null
    ,@param4 sql_variant = null
    ,@param5 sql_variant = null
    )
returns nvarchar(4000)
begin
/*
Tejasvi Hegde, 29-April-2017

select dbo.FormatString('some string value %s some int %s date %s','"abcd"',100,cast(getdate() as date),DEFAULT,DEFAULT)
select dbo.FormatString('some string value %s some int %s date time %s','"abcd"',100,getdate(),DEFAULT,DEFAULT)
*/

    declare @result nvarchar(4000)

    select @param1 = dbo.formatValue(@param1)
    ,@param2 = dbo.formatValue(@param2)
    ,@param3 = dbo.formatValue(@param3)
    ,@param4 = dbo.formatValue(@param4)
    ,@param5 = dbo.formatValue(@param5)

    select @param2 = cast(@param2 as nvarchar)
    EXEC xp_sprintf @result OUTPUT,@format , @param1, @param2, @param3, @param4, @param5

    return @result

end;
— Теясві Хеґде
джерело
Найпростіша відповідь на SQL Server 2008+. Зберігає введення як окремі параметри. Використовує функцію xp_sprintf і може бути легко розширений. xp_sprintf - docs.microsoft.com/en-us/sql/relational-databases/…
— Джефф Льюїс,
0

ось що я знайшов у своїх експериментах із використанням вбудованого

Функція FORMATMESSAGE ()

sp_addmessage @msgnum=50001,@severity=1,@msgText='Hello %s you are #%d',@replace='replace'
SELECT FORMATMESSAGE(50001, 'Table1', 5)

коли ви викликаєте sp_addmessage, ваш шаблон повідомлення зберігається в системній таблиці master.dbo.sysmessages (перевірено на SQLServer 2000).

Ви повинні керувати додаванням і видаленням рядків шаблонів із таблиці, що незручно, якщо все, що ви дійсно хочете, - це вивести швидке повідомлення на екран результатів.

Рішення, яке надає Kathik DV, виглядає цікавим, але не працює з SQL Server 2000, тому я його трохи змінив, і ця версія повинна працювати з усіма версіями SQL Server:

IF OBJECT_ID( N'[dbo].[FormatString]', 'FN' ) IS NOT NULL
    DROP FUNCTION [dbo].[FormatString]
GO
/***************************************************
Object Name : FormatString
Purpose : Returns the formatted string.
Original Author : Karthik D V http://stringformat-in-sql.blogspot.com/
Sample Call:
SELECT dbo.FormatString ( N'Format {0} {1} {2} {0}', N'1,2,3' )
*******************************************/
CREATE FUNCTION [dbo].[FormatString](
@Format NVARCHAR(4000) ,
@Parameters NVARCHAR(4000)
)
RETURNS NVARCHAR(4000)
AS
BEGIN
    --DECLARE @Format NVARCHAR(4000), @Parameters NVARCHAR(4000) select @format='{0}{1}', @Parameters='hello,world'
    DECLARE @Message NVARCHAR(400), @Delimiter CHAR(1)
    DECLARE @ParamTable TABLE ( ID INT IDENTITY(0,1), Parameter VARCHAR(1000) )
    Declare @startPos int, @endPos int
    SELECT @Message = @Format, @Delimiter = ','

    --handle first parameter
     set @endPos=CHARINDEX(@Delimiter,@Parameters)
    if (@endPos=0 and @Parameters is not null) --there is only one parameter
        insert into @ParamTable (Parameter) values(@Parameters)
    else begin
        insert into @ParamTable (Parameter) select substring(@Parameters,0,@endPos)
    end

    while @endPos>0
    Begin
        --insert a row for each parameter in the 
        set @startPos = @endPos + LEN(@Delimiter)
        set @endPos = CHARINDEX(@Delimiter,@Parameters, @startPos)
        if (@endPos>0)
            insert into @ParamTable (Parameter) select substring(@Parameters,@startPos,@endPos)
        else
            insert into @ParamTable (Parameter) select substring(@Parameters,@startPos,4000)            
    End

    UPDATE @ParamTable SET @Message = REPLACE ( @Message, '{'+CONVERT(VARCHAR,ID) + '}', Parameter )
    RETURN @Message
END
Go
    grant execute,references on dbo.formatString to public

Використання:

print dbo.formatString('hello {0}... you are {1}','world,good')
--result: hello world... you are good
— BraveNewMath
джерело
-1

Насправді немає вбудованої функції, подібної до рядка. Функція форматування .NET доступна на сервері SQL.

На сервері SQL є функція FORMATMESSAGE (), але вона імітує функцію printf () для C, а не рядка. Формат функції .NET.

SELECT FORMATMESSAGE('This is the %s and this is the %s.', 'first variable', 'second variable') AS Result
— Brijesh Kumar Tripathi
джерело
-3

це поганий підхід. вам слід працювати з асемблерними DLL-файлами, які зроблять те саме для вас із кращою продуктивністю.

— pelegk1
джерело
Використовуючи наш веб-сайт, ви визнаєте, що прочитали та зрозуміли наші Політику щодо файлів cookie та Політику конфіденційності.
Licensed under cc by-sa 3.0 with attribution required.