Зробити Vim показати ВСІ білі пробіли як персонаж

Я не можу знайти спосіб змусити Віма показати всі пробіли як персонаж. Все, що я знайшов, було про вкладки, пробіли тощо.

Як уже говорили інші, ви могли використовувати

:set list

який буде в поєднанні з

:set listchars=...

відображення невидимих ​​символів.
Тепер не існує явного варіанту, який можна використовувати для показу пробілів, але в списках ви можете встановити символ, який повинен показуватися для всього, але НЕ пробілу. Наприклад, моя виглядає так

:set listchars=eol:$,tab:>-,trail:~,extends:>,precedes:<

тому зараз, після використання

:set list

все, що явно не відображається як щось інше, - це, справді, звичайний простий пробіл.

Як завжди, щоб зрозуміти, як listcharsпрацює, скористайтеся допомогою. Він надає чудову інформацію про те, які символи можуть бути відображені (наприклад, пробіл, наприклад) та як це зробити:

:help listchars

Можливо, буде корисно додати перемикач до нього, щоб ви могли легко бачити зміни в середині редагування (джерело: VIM: встановити список! Як перемикання у .vimrc ):

noremap <F5> :set list!<CR>
inoremap <F5> <C-o>:set list!<CR>
cnoremap <F5> <C-c>:set list!<CR>

Станом на патч 7.4.710 тепер ви можете встановити символ, який повинен відображатися на місці місця, використовуючи listchars!

:set listchars+=space:␣

Отже, щоб показати ВСІ символи пробілу як символу, ви можете зробити наступне:

:set listchars=eol:¬,tab:>·,trail:~,extends:>,precedes:<,space:␣
:set list

Обговорення списку розсилки: https://groups.google.com/forum/?fromgroups#!topic/vim_dev/pjmW6wOZW_Q

:set list для того, щоб.

:set nolist відключити.

Я думаю, що інші відповіді тут є більш вичерпними, але я подумав, що поділюсь трюком, який зазвичай використовую для візуальної диференціації вкладок і пробілів:

:syntax on
:set syntax=whitespace

Це правила виділення синтаксису для мови програмування Whitespace - вкладки відображаються зеленим кольором, а пробіли - червоним кольором. :)

Може поєднуватися із :set listзазначенням багатьох інших відповідей, хоча вкладки будуть відображатися як ^ Я без зеленого світла, але пробіли відображатимуться червоним кольором.

:set listпокаже всі пробіли як персонаж. Все, крім простору, буде виглядати інакше, ніж його звичайний стан, а це означає, що якщо ви все-таки бачите звичайний старий простір, це справді звичайний простір. :)

Якщо ви встановите:

:highlight Search cterm=underline gui=underline ctermbg=none guibg=none ctermfg=none guifg=none

а потім виконайте пошук пробілу, кожен пробільний символ буде показаний як підкреслений символ.

Ви можете використовувати цю команду в зручній функції, яка перемикає "підкреслення" пробілів.

set hls
let g:HLSpace = 1
let g:HLColorScheme = g:colors_name
function ToggleSpaceUnderscoring()
    if g:HLSpace
        highlight Search cterm=underline gui=underline ctermbg=none guibg=none ctermfg=none guifg=none
        let @/ = " "
    else
        highlight clear
        silent colorscheme "".g:HLColorScheme
        let @/ = ""
    endif
    let g:HLSpace = !g:HLSpace
endfunction

Позначте функцію на клавіші швидкого доступу за допомогою:

nmap <silent> <F3> <Esc>:call ToggleSpaceUnderscoring()<CR>

Примітка: Визначте функцію vimrc після встановлення схеми кольорів.

Залежно від ваших правил синтаксису для поточного буфера, щось подібне може працювати:

:syn match WhiteSpace / / containedin=ALL conceal cchar=Æ
:setl conceallevel=2 concealcursor=nv

Для цього потрібен vim 7.3 з функцією + приховати

Оновіть 24.10.2014, щоб трохи розширити це. Звичайно, можна визначити деяке виділення для конізованих символів.

• Ви можете налаштувати, як виглядають приховані символи. Для виділення вам доведеться хоча б раз налаштувати групу виділення "Conceal" (Дивіться довідку за адресою :h hl-ConcealЦе можна зробити у вашій кольоровій схемі, і тоді вам не потрібно її повторно налаштовувати . Але це впливає на всі приховані символи (наприклад, якщо ваш скрипт синтаксису приховує ще деякі елементи, вони будуть відображатися як ваші символи пробілу). Це може виглядати приблизно так:

  :hi Conceal ctermfg=7 ctermbg=NONE guifg=LightGrey guibg=NONE

• Здається, є особливість, що Vim не виділяє пробіли, якщо в синтаксичному скрипті використовується skipwhiteключове слово. Не обійдеться ніякого шляху (можливо, це буде виправлено, я виклав патч )

• Здається, патч плаває навколо, що дозволить налаштувати, як будуть виглядати пробіли в listрежимі. Останній на момент написання, здається, цей . (Це означає, що вам потрібно створити власний Vim, щоб скористатися цим).
• conceallevelІ concealcursorє вікна локальних параметрів. Це означає, що вони можуть бути різними у різних вікнах (і можливо, вони також встановлюватимуться плагінами файлів або іншими скриптами плагінів).
• Групи підсвічування синтаксису потрібно виконувати щоразу, коли файл визначення синтаксису буде перезавантажений. Це можна зробити за допомогою BufWinEnterабо, можливо, Syntaxнавіть FileTypeавтозапису. (Я не перевіряв, хто з них працює).

Останні два пункти означають, що вам доведеться встановити кілька автокоманд, які скидають правила синтаксису та параметри кореспонденції. Для першого, можливо, потрібно налаштувати виділення за допомогою ColorSchemeавтокоманди (щоб приховані символи завжди виглядали однаково, незалежно від того, що насправді встановлює кольорова схема). Щоб отримати повне рішення, погляньте на відповідь romainl, яка повинна вам почати. Якщо ви налаштовуєте функцію, ви можете легко налаштувати команду перемикання, щоб перемикати відображення спеціальних підсвічувань увімкнено або вимкнено.

Оновлення 26.10.2014 Я зробив плагін із цього питання.

Оновлення 22.04.2015 Патч включений у Vim, що робить це можливим за допомогою listпараметра. Просто встановіть. set list listchars+=space:␣ Це працює з Vim 7.4.711

Я цим користуюся

/\s
:set hlsearch

виділити пробіли білі. Він шукає всі пробіли, а потім дозволяє виділити, щоб вони вискочили. Однак він не друкує спеціального символу.

Якщо під пробілами ви маєте на увазі символ '', то моя пропозиція буде просто пошуком / заміною. Як натякнули інші, set listзміни символів , що не друкуються, на видимий символ, який налаштовано listchars.

Щоб явно показати пробіли як якийсь інший символ, щось подібне до наведеного нижче має зробити фокус:

:%s/ /█/g

Потім просто скасуйте зміну, щоб повернутися знову.

(Щоб отримати █ я натиснув цю точну послідовність клавіш: :%s/ /CTRL-KFB/g)

Щоб виділити пробіли, просто знайдіть його:

/ <пробіл>

Примітки:

Код нижче заснований на відповіді Крістіана Брабандта і, здається, робить те, що хоче ОП:

function! Whitespace()
    if !exists('b:ws')
        highlight Conceal ctermbg=NONE ctermfg=240 cterm=NONE guibg=NONE guifg=#585858 gui=NONE
        highlight link Whitespace Conceal
        let b:ws = 1
    endif

    syntax clear Whitespace
    syntax match Whitespace / / containedin=ALL conceal cchar=·
    setlocal conceallevel=2 concealcursor=c
endfunction

augroup Whitespace
    autocmd!
    autocmd BufEnter,WinEnter * call Whitespace()
augroup END

Додайте ці рядки до свого ~/.vimrcі почніть новий сеанс Vim, щоб побачити, як все ще відбувається недосконала магія.

Не соромтесь редагувати кольори за замовчуванням та приховувати характер.

Caveat: щось із *FuncBodyгрупи синтаксису кількома мовами заважає показувати середню крапку. Я не знаю (ще?), Як зробити це рішення більш надійним.

Я був розчарований усіма іншими відповідями на це питання, тому що жодна з них корисно не висвітлює космічний персонаж. Показ пробілів як символів особливо допоможе для мов, що форматують пробіли, де змішування вкладок та пробілів є шкідливим.

Моє рішення - показати вкладки та підкреслити кілька пробілів. Він запозичує відповідь mrucci і цей підручник . Оскільки він використовує підсвічування синтаксису, він є стійким:

set list listchars=tab:\|\ 
highlight Whitespace cterm=underline gui=underline ctermbg=NONE guibg=NONE ctermfg=yellow guifg=yellow
autocmd ColorScheme * highlight Whitespace gui=underline ctermbg=NONE guibg=NONE ctermfg=yellow guifg=yellow
match Whitespace /  \+/

Використовуючи це, вкладки відображаються як |і пробіли як _, що дозволяє дуже легко визначити, коли я змішую стилі коду.

Єдиний мінус, який я виявив - це те, що цей фрагмент не коригує колір тла відповідно до контексту (як у коментарі).

всі відповіді вище намагаються зробити пробіли видимими зсередини vim. Якщо ви дійсно наполягаєте на тому, щоб видимі місця були як точки, є ще один підхід ...

Якщо це неможливо зробити у форматі vim, повністю змініть свій шрифт. Я скопіював шрифт Ubuntu One Mono і відредагував його за допомогою FontForge. Не забудьте змінити повне ім'я, сімейство, бажане сімейство, сумісне повне (у FontFoge це під TTF Names в інформації про шрифт), щоб мати його як окремий шрифт. Просто відредагуйте пробіл, щоб мати крапку посередині, і зберегти шрифт у ~ / .fonts. Тепер ви можете використовувати його для свого gvim або всього терміналу ... Я скопіював "!" символу, вилучив лінію і перемістив крапку в середину. Це зайняло трохи більше 5 хвилин ...

Примітка: зміна символу пробілу (0x20) призводить до незручності мати точки на всьому екрані vim ... (але це відокремить пробіли від вкладок ...)

Я не знайшов саме того, що хотів із наявних відповідей. Код нижче буде виділяти всі пробіли яскраво-червоними. Просто додайте наступне до свого.vimrc

highlight ExtraWhitespace ctermbg=red guibg=red
match ExtraWhitespace /\s\+$/
autocmd BufWinEnter * match ExtraWhitespace /\s\+$/
autocmd InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
autocmd InsertLeave * match ExtraWhitespace /\s\+$/
autocmd BufWinLeave * call clearmatches()

:match CursorLine /\s\+/

дозволяє уникнути біту "вам потрібно шукати пробіли, щоб вони відображалися", але afaict не може бути налаштований на те, щоб робити непрофільні речі до просторів. CursorLine може бути будь-якою групою hilighting, і в темі за замовчуванням це просте підкреслення.

Мені подобається використовувати спеціальні символи для показу пробілів, це більш зрозуміло. Навіть карта для перемикання - ключова особливість, для швидкої перевірки.

Ви можете знайти ці функції в старому скрипті vim, не оновленому з 2004 року:

vim-scripts/cream-showinvisibles@vim.org

Завдяки проектним vim-скриптам і vundle ви зможете оживити цей плагін

vim-script / cream-showinvisibles @ github

Ще краще, мої два центи на цьому - додати налаштований ярлик (замість попередньо визначеного F4)

тому додайте це до ~ / .vimrc

Plugin 'albfan/cream-invisibles'

let g:creamInvisibleShortCut = "<F5>" "for my F4 goto next error

встановити плагін на vim

:PluginInstall

і там ти йдеш

Щоб охопити символи пробілів Unicode:

set list
set listchars=tab:│\ ,nbsp:·
highlight StrangeWhitespace guibg=Red ctermbg=Red
" The list is from https://stackoverflow.com/a/37903645 (with `\t`, `\n`, ` `, `\xa0` removed):
call matchadd('StrangeWhitespace', '[\x0b\x0c\r\x1c\x1d\x1e\x1f\x85\u1680\u2000\u2001\u2002\u2003\u2004\u2005\u2006\u2007\u2008\u2009\u200a\u2028\u2029\u202f\u205f\u3000]')

Результат:

• тільки порядковий простір (U + 0020) виглядає просто як пробіл (" ")
• вкладка (U + 0009) має вигляд " │ " (два символи: довга труба, а потім порядковий пробіл; вони сірі colorscheme murphy)
• нормальний пробіл (U + 00A0) виглядає як " ·" (один символ; він сірий colorscheme murphy)
• будь-який інший символ пробілу схожий на червоний " "

Ви можете використовувати

:set list

дійсно бачити структуру лінії. Ви явно побачите вкладки та нові рядки. Коли ви бачите порожню, це справді порожня.

висвітлити пошук

:set hlsearch 

в .vimrcтому є

і пошук вкладок пробілу та повернення перевезення

/ \|\t\|\r

або шукати всіх символів пробілу

/\s

пошуку всіх символів пробілу (символи пробілу не показані, тому ви бачите символи пробілу між словами, але не знаки пробілу пробілу)

/\S

щоб показати всі знаки пробілу білого пробілу - в кінці рядка

/\s$

Залишайте ці хаки в .vimrc як коментарі, так що в оболонці просто:

echo '
  " how-to see the non-visible while spaces
  " :set listchars=eol:¬,tab:>·,trail:~,extends:>,precedes:<,space:␣
  " set listchars=eol:$,tab:>-,trail:~,extends:>,precedes:<
  " :set list
  " but hei how-to unset the visible tabs ?!
  " :set nolist
  ' >> ~/.vimrc

:se list
:se nolist

:seдостатньо, :setне потрібно.

Ви також можете виділити пробіли (замінивши пробіли на блок):

:%s/ /█/g

(перед тим, як написати його скасувати)

Додавання цього до мого .vimrc працює для мене. Просто переконайтесь, що у вас немає нічого іншого конфліктного ..

autocmd VimEnter * :syn match space /\s/
autocmd VimEnter * :hi space ctermbg=lightgray ctermfg=black guibg=lightgray guifg=black