Прокладіть рядок з провідними нулями, так що це три символи в SQL Server 2008

У мене є рядок довжиною до 3 символів, коли вона вперше створена в SQL Server 2008 R2.

Я хотів би зафіксувати його провідними нулями, тож якщо його початкове значення було «1», новим значенням було б «001». Або якщо його початкове значення було "23", нове значення - "023". Або якщо його початкове значення - 124, то нове значення те саме, що і вихідне значення.

Я використовую SQL Server 2008 R2. Як би це зробити за допомогою T-SQL?

Якщо в полі вже є рядок, це буде працювати

 SELECT RIGHT('000'+ISNULL(field,''),3)

Якщо ви хочете, щоб нулі відображалися як "000"

Це може бути ціле число - тоді ви хочете

 SELECT RIGHT('000'+CAST(field AS VARCHAR(3)),3)

Відповідно до запитання, ця відповідь працює лише в тому випадку, якщо довжина <= 3, якщо ви хочете щось більше, вам потрібно змінити констант рядка і дві цілі константи на потрібну ширину. напр'0000' and VARCHAR(4)),4

Хоча питання стосувалося і SQL Server 2008 R2, якщо хтось читає це з версією 2012 року і вище, з тих пір це стало набагато простіше через використання FORMAT .

Як аргумент формату можна передавати стандартний рядок чисельного формату або спеціальний рядок чисельного формату (дякую Вадиму Овчинникову за цей підказку).

Наприклад, для цього питання

DECLARE @myInt INT = 1;
-- One way using a standard numeric format string
PRINT FORMAT(@myInt,'D3');
-- Other way using a custom numeric format string
PRINT FORMAT(@myInt,'00#');

виходи

001
001

Безпечний метод:

SELECT REPLACE(STR(n,3),' ','0')

Це має перевагу повернення рядка '***'для n <0 або n> 999, що є приємним і очевидним показником введення поза межами діапазону. Інші перераховані тут способи будуть беззвучно відрізати вхід в 3-символьну підрядку.

Ось більш загальна методика накладки зліва на будь-яку бажану ширину:

declare @x     int     = 123 -- value to be padded
declare @width int     = 25  -- desired width
declare @pad   char(1) = '0' -- pad character

select right_justified = replicate(
                           @pad ,
                           @width-len(convert(varchar(100),@x))
                           )
                       + convert(varchar(100),@x)

Однак якщо ви маєте справу з негативними значеннями та прокладкою з провідними нулями, ні ця, ні інша запропонована методика не спрацюють. Ви отримаєте щось таке:

00-123

[Мабуть, не те, чого ти хотів]

Отже ... вам доведеться перестрибнути кілька додаткових обручів Ось один підхід, який буде правильно форматувати від’ємні числа:

declare @x     float   = -1.234
declare @width int     = 20
declare @pad   char(1) = '0'

select right_justified = stuff(
         convert(varchar(99),@x) ,                            -- source string (converted from numeric value)
         case when @x < 0 then 2 else 1 end ,                 -- insert position
         0 ,                                                  -- count of characters to remove from source string
         replicate(@pad,@width-len(convert(varchar(99),@x)) ) -- text to be inserted
         )

Слід зазначити, що у convert()викликах має бути вказана [n]varcharдостатня довжина, щоб утримувати перетворений результат із усіченням.

Ось варіант відповіді Хогана, який я використовую в SQL Server Express 2012:

SELECT RIGHT(CONCAT('000', field), 3)

Замість того, щоб турбуватися, чи є поле рядком чи ні, я просто CONCATйого, оскільки воно все одно виведе рядок. Крім того, якщо поле може бути а NULL, ISNULLможливо, знадобиться використання, щоб уникнути отримання функцій NULLрезультатів.

SELECT RIGHT(CONCAT('000', ISNULL(field,'')), 3)

Я завжди вважав наступний метод дуже корисним.

REPLICATE('0', 5 - LEN(Job.Number)) + CAST(Job.Number AS varchar) as 'NumberFull'

Використовуйте цю функцію, яка відповідає кожній ситуації.

CREATE FUNCTION dbo.fnNumPadLeft (@input INT, @pad tinyint)
RETURNS VARCHAR(250)
AS BEGIN
    DECLARE @NumStr VARCHAR(250)

    SET @NumStr = LTRIM(@input)

    IF(@pad > LEN(@NumStr))
        SET @NumStr = REPLICATE('0', @Pad - LEN(@NumStr)) + @NumStr;

    RETURN @NumStr;
END

Вибірка зразка

SELECT [dbo].[fnNumPadLeft] (2016,10) -- returns 0000002016
SELECT [dbo].[fnNumPadLeft] (2016,5) -- returns 02016
SELECT [dbo].[fnNumPadLeft] (2016,2) -- returns 2016
SELECT [dbo].[fnNumPadLeft] (2016,0) -- returns 2016 

Для тих, хто хоче оновити свої наявні дані, ось такий запит:

update SomeEventTable set eventTime=RIGHT('00000'+ISNULL(eventTime, ''),5)

Для цілих чисел можна використовувати неявне перетворення з int в varchar:

SELECT RIGHT(1000 + field, 3)

Я знаю його старий квиток, який я просто думав поділитися ним.

Я знайшов цей код шукає рішення. Не впевнений, чи працює він у всіх версіях MSSQL У мене є MSSQL 2016.

declare @value as nvarchar(50) = 23
select REPLACE(STR(CAST(@value AS INT) + 1,4), SPACE(1), '0') as Leadingzero

повертає "0023" 4 у функції STR - загальна довжина, включаючи значення. У прикладах 4, 23 та 123 всі будуть мати 4 у STR та буде додано правильну кількість нулів. Ви можете збільшити або зменшити його. Не потрібно отримувати довжину на 23.

Редагувати: я бачу це так само, як і пост @Anon.

У мене була аналогічна проблема з цілим стовпцем як вхід, коли мені потрібен був вихід фіксованого розміру (або рядок). Наприклад, від 1 до '01', 12 до '12'. Цей код працює:

SELECT RIGHT(CONCAT('00',field::text),2)

Якщо вхід є також стовпцем варшара, ви можете уникнути частини лиття.

Для більш динамічного підходу спробуйте це.

declare @val varchar(5)
declare @maxSpaces int
set @maxSpaces = 3
set @val = '3'
select concat(REPLICATE('0',@maxSpaces-len(@val)),@val)

Спробуйте це з фіксованою довжиною.

select right('000000'+'123',5)

select REPLICATE('0', 5 - LEN(123)) + '123'

Писав це тому, що у мене були вимоги до певної довжини (9). Прокладіть ліворуч @pattern ТІЛЬКИ, коли для введення потрібна підкладка. Завжди повинен повертати довжину, визначену в @pattern.

declare @charInput as char(50) = 'input'

--always handle NULL :)
set @charInput = isnull(@charInput,'')

declare @actualLength as int = len(@charInput)

declare @pattern as char(50) = '123456789'
declare @prefLength as int = len(@pattern)

if @prefLength > @actualLength
    select Left(Left(@pattern, @prefLength-@actualLength) + @charInput, @prefLength)
else
    select @charInput

Повертає 1234вхід

Просто це

Подібно до:

DECLARE @DUENO BIGINT
SET @DUENO=5

SELECT 'ND'+STUFF('000000',6-LEN(RTRIM(@DueNo))+1,LEN(RTRIM(@DueNo)),RTRIM(@DueNo)) DUENO

Сюди я приїхав спеціально, щоб розібратися, як я міг перетворити зміщення часового поясу в рядок часового поясу для перетворення дат у DATETIMEOFFSET в SQL Server 2008. Валовий, але необхідний.

Тому мені потрібен 1 метод, який впорається з від’ємними та додатними числами, відформатувавши їх на два символи з нульовим нулем, якщо потрібно. Відповідь Anons мене наблизила, але негативні значення часового поясу виявляться як 0-5швидше, ніж необхідні-05

Тож, дещо змінивши свою відповідь, це працює для всіх перетворень годинного поясу

DECLARE @n INT = 13 -- Works with -13, -5, 0, 5, etc
SELECT CASE 
    WHEN @n < 0 THEN '-' + REPLACE(STR(@n * -1 ,2),' ','0') 
    ELSE '+' + REPLACE(STR(@n,2),' ','0') END + ':00'

Я створив цю функцію, яка обслуговує bigint і один провідний нуль або інший єдиний символ (повернуто максимум 20 символів) і дозволяє отримати тривалість результатів менше довжини вхідного числа:

create FUNCTION fnPadNum (
  @Num BIGINT --Number to be padded, @sLen BIGINT --Total length of results , @PadChar varchar(1))
  RETURNS VARCHAR(20)
  AS
  --Pads bigint with leading 0's
            --Sample:  "select dbo.fnPadNum(201,5,'0')" returns "00201"
            --Sample:  "select dbo.fnPadNum(201,5,'*')" returns "**201"
            --Sample:  "select dbo.fnPadNum(201,5,' ')" returns "  201"
   BEGIN
     DECLARE @Results VARCHAR(20)
     SELECT @Results = CASE 
     WHEN @sLen >= len(ISNULL(@Num, 0))
     THEN replicate(@PadChar, @sLen - len(@Num)) + CAST(ISNULL(@Num, 0) AS VARCHAR)
     ELSE CAST(ISNULL(@Num, 0) AS VARCHAR)
     END

     RETURN @Results
     END
     GO

     --Usage:
      SELECT dbo.fnPadNum(201, 5,'0')
      SELECT dbo.fnPadNum(201, 5,'*')
      SELECT dbo.fnPadNum(201, 5,' ')