Перенаправлення вихідних даних у пакетному файлі

Я створюю пакетний файл з деякими простими командами для збору інформації з системи. Пакетний файл містить команди для отримання часу, інформації про IP, користувачів тощо.

Я зібрав всі команди в пакетному файлі, і він працює, але я хотів би, щоб пакетний файл під час запуску виводив результати в текстовий файл (журнал). Чи є команда, яку я можу додати до групи, яка б це зробила?

Майте на увазі, я не хочу запускати пакет з cmd, а потім перенаправляти вихід; Я хочу перенаправити вихід зсередини партії, якщо це можливо.

Простий наївний спосіб, який повільний, тому що він відкриває та розміщує вказівник файлу на End-Of-File кілька разів.

@echo off
command1 >output.txt
command2 >>output.txt
...
commandN >>output.txt

Кращий спосіб - простіше писати та швидше, оскільки файл відкривається та розміщується лише один раз.

@echo off
>output.txt (
  command1
  command2
  ...
  commandN
)

Ще один хороший та швидкий спосіб, який відкриває та розміщує файл лише один раз

@echo off
call :sub >output.txt
exit /b

:sub
command1
command2
...
commandN

Редагувати 2020-04-17

Раз у раз ви можете неодноразово писати у два чи більше файли. Можливо, вам також потрібні різні повідомлення на екрані. Це все ще можливо зробити це ефективно, перенаправляючи на невизначені ручки за межами круглого блоку або підпрограми, а потім використовувати &позначення для посилання на вже відкриті файли.

call :sub 9>File1.txt 8>File2.txt
exit /b

:sub
echo Screen message 1
>&9 File 1 message 1
>&8 File 2 message 1
echo Screen message 2
>&9 File 1 message 2
>&8 File 2 message 2
exit /b

Я вирішив використовувати ручки 9 і 8 у зворотному порядку, оскільки таким чином, швидше за все, уникнути можливого постійного перенаправлення через недолік дизайну впровадження перенаправлення Microsoft при виконанні декількох перенаправлень в одній команді. Це малоймовірно, але навіть такий підхід може виявити помилку, якщо ви постараєтеся досить. Якщо ви зробите поетапну переадресацію, ви гарантовано уникнете проблеми.

3>File1.txt ( 4>File2.txt call :sub)
exit /b

:sub
etc.

якщо ви хочете, щоб потоки і помилки перенаправлені

dir >> a.txt 2>&1

Я знаю, що це старіший пост, але хтось наткнеться на нього в пошуку Google, і це також виглядає як деякі питання, які ОП задавали в коментарях, спеціально не розглядалися. Крім того, будь ласка, будь ласка, мені, так як це моя перша відповідь, розміщена в ТА. :)

Для перенаправлення виводу на файл, використовуючи динамічно створене ім’я файлу, мій підхід (читання: швидкий і брудний) - це друге рішення, яке пропонує @dbenham. Так, наприклад, це:

@echo off
> filename_prefix-%DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log (
echo Your Name Here
echo Beginning Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
REM do some stuff here
echo Your Name Here
echo Ending Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
)

Створиться файл, подібний до того, що ви бачите в цьому скріншоті файлу в цільовому каталозі

Що буде містити цей вихід:

Your Name Here
Beginning Date/Time: 2016-09-16_141048.log
Your Name Here
Ending Date/Time: 2016-09-16_141048.log

Також майте на увазі, що це рішення залежить від локальної локальності, тому будьте уважні, як / коли ви його використовуєте.

echo some output >"your logfile"

або

(
 echo some output
 echo more output
)>"Your logfile"

має заповнити рахунок.

Якщо ви хочете на APPENDвихід, використовуйте >>замість >. >почне новий файл реєстрації.

@echo off
>output.txt (
echo Checking your system infor, Please wating...

systeminfo | findstr /c:"Host Name" 
systeminfo | findstr /c:"Domain"

ipconfig /all | find "Physical Address" 

ipconfig | find "IPv4" 
ipconfig | find "Default Gateway"

)

@pause

Існує класна маленька програма, яку ви можете використовувати для перенаправлення виводу на файл і консоль

some_command  ^|  TEE.BAT  [ -a ]  filename 

@ECHO OFF
:: Check Windows version
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

:: Keep variables local
SETLOCAL

:: Check command line arguments
SET Append=0
IF /I [%1]==[-a] (
	SET Append=1
	SHIFT
)
IF     [%1]==[] GOTO Syntax
IF NOT [%2]==[] GOTO Syntax

:: Test for invalid wildcards
SET Counter=0
FOR /F %%A IN ('DIR /A /B %1 2^>NUL') DO CALL :Count "%%~fA"
IF %Counter% GTR 1 (
	SET Counter=
	GOTO Syntax
)

:: A valid filename seems to have been specified
SET File=%1

:: Check if a directory with the specified name exists
DIR /AD %File% >NUL 2>NUL
IF NOT ERRORLEVEL 1 (
	SET File=
	GOTO Syntax
)

:: Specify /Y switch for Windows 2000 / XP COPY command
SET Y=
VER | FIND "Windows NT" > NUL
IF ERRORLEVEL 1 SET Y=/Y

:: Flush existing file or create new one if -a wasn't specified
IF %Append%==0 (COPY %Y% NUL %File% > NUL 2>&1)

:: Actual TEE
FOR /F "tokens=1* delims=]" %%A IN ('FIND /N /V ""') DO (
	>  CON    ECHO.%%B
	>> %File% ECHO.%%B
)

:: Done
ENDLOCAL
GOTO:EOF

:Count
SET /A Counter += 1
SET File=%1
GOTO:EOF

:Syntax
ECHO.
ECHO Tee.bat,  Version 2.11a for Windows NT 4 / 2000 / XP
ECHO Display text on screen and redirect it to a file simultaneously
ECHO.
IF NOT "%OS%"=="Windows_NT" ECHO Usage:  some_command  ³  TEE.BAT  [ -a ]  filename
IF NOT "%OS%"=="Windows_NT" GOTO Skip
ECHO Usage:  some_command  ^|  TEE.BAT  [ -a ]  filename
:Skip
ECHO.
ECHO Where:  "some_command" is the command whose output should be redirected
ECHO         "filename"     is the file the output should be redirected to
ECHO         -a             appends the output of the command to the file,
ECHO                        rather than overwriting the file
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com
ECHO Modified by Kees Couprie
ECHO http://kees.couprie.org
ECHO and Andrew Cameron

Додайте ці два рядки у верхній частині вашого пакетного файлу, після чого всі stdout та stderr будуть перенаправлені на log.txt:

if not "%1"=="STDOUT_TO_FILE"  %0 STDOUT_TO_FILE %*  >log.txt 2>&1
shift /1

@echo OFF
[your command] >> [Your log file name].txt

Я використав команду вище в своєму пакетному файлі, і вона працює. У файлі журналу відображаються результати моєї команди.

Це може вийти з ладу у випадку "токсичних" символів на вводі. Зважаючи на такий вхід, як цеIsAnIn ^^^^, це хороший спосіб зрозуміти, що відбувається. Звичайно, є правило, що рядок введення ОБОВ'ЯЗКОВО повинен бути всередині подвійних цитованих знаків, але я маю відчуття, що це правило є дійсним правилом, лише якщо значенням введення є розташування на розділі NTFS (можливо, це правило для URL-адрес I не впевнений). Але це не правило для довільного рядка введення, звичайно (це "хороша практика", але ви не можете з цим порахувати).

Додавання наступних рядків у нижній частині пакетного файлу дозволить схопити все так само, як відображено у вікні CMD та експортувати у текстовий файл:

powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^a')
powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^c')
powershell Get-Clipboard > MyLog.txt

В основному він виконує функцію виділення всіх -> копіювати в буфер обміну -> вставити у текстовий файл .