Я додав notepad++.exeдо моїх змінних Path in Environment.

Тепер у командному рядку notepad++.exe filename.txtвідкривається filename.txt. Але я хочу зробити просто np filename.txtвідкрити файл.

Я спробував використовувати DOSKEY np=notepad++. Але це лише виведення на перший план уже відкритого блокнота ++ без відкриття файлу. Як змусити його відкрити файл?

Дякую.

Щоб додати відповідь Джоша,

ви можете зробити псевдоніми стійкими, виконавши наступні кроки,

1. Створіть .bat або .cmd файл зі своїми DOSKEYкомандами.
2. Запустіть regedit і перейдіть до HKEY_CURRENT_USER\Software\Microsoft\Command Processor

3. Додайте запис String Value з назвою AutoRunта повним шляхом вашого файлу .bat / .cmd.

   Наприклад, %USERPROFILE%\alias.cmdзаміна початкового сегмента шляху %USERPROFILE%корисною для синхронізації між декількома машинами.

Таким чином, при кожному запуску cmd псевдоніми завантажуються.

Для Windows 10 додайте запис HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command Processorзамість цього.

Для повноти, ось шаблон для ілюстрації типу псевдонімів, який може бути корисним.

@echo off

:: Temporary system path at cmd startup

set PATH=%PATH%;"C:\Program Files\Sublime Text 2\"

:: Add to path by command

DOSKEY add_python26=set PATH=%PATH%;"C:\Python26\"
DOSKEY add_python33=set PATH=%PATH%;"C:\Python33\"

:: Commands

DOSKEY ls=dir /B
DOSKEY sublime=sublime_text $*  
    ::sublime_text.exe is name of the executable. By adding a temporary entry to system path, we don't have to write the whole directory anymore.
DOSKEY gsp="C:\Program Files (x86)\Sketchpad5\GSP505en.exe"
DOSKEY alias=notepad %USERPROFILE%\Dropbox\alias.cmd

:: Common directories

DOSKEY dropbox=cd "%USERPROFILE%\Dropbox\$*"
DOSKEY research=cd %USERPROFILE%\Dropbox\Research\

• Зауважимо, що $* синтаксис працює після рядка каталогів, а також виконуваного файлу, який бере аргументи. Отже, у наведеному вище прикладі визначені користувачем команди dropbox researchвказують на той самий каталог, що і research.
• Як зазначав Rivenfall, корисно включити команду, яка дозволяє зручно редагувати alias.cmdфайл. Дивіться aliasвище. Якщо ви перебуваєте в сеансі cmd, введіть, cmdщоб перезапустити cmd і перезавантажитиalias.cmd файл.

Коли я шукав в Інтернеті відповідь на запитання, то якимось чином дискусії були зосереджені лише на наполегливості або на деякому використанні DOSKEY. Я сподіваюся, що хтось виграє з цих двох аспектів, будучи тут разом!

Ось .regфайл, який допоможе вам встановити alias.cmd. Тепер він встановлений як приклад до папки, що випадає, як було запропоновано вище.

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="%USERPROFILE%\\alias.cmd"

Для однокористувацьких додатків це буде зроблено вище. Тим не менш, є ситуації, коли потрібно перевірити, чи єalias.cmd існує перший в ключі реєстру. Дивіться приклад нижче.

У C:\Users\Public\init.cmdфайлі, що розміщує потенційно конфігурації для користувачів, виконайте вказані нижче дії.

@ECHO OFF
REM Add other configurations as needed
IF EXIST "%USERPROFILE%\alias.cmd" ( CALL "%USERPROFILE%\alias.cmd" )

Ключ реєстру слід оновити відповідно до файлу C:\Users\Public\init.cmdабо, використовуючи його .reg:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="C:\\Users\\Public\\init.cmd"

Вам потрібно передати параметри, спробуйте це:

doskey np=notepad++.exe $*

Редагувати (відповідаючи на коментар Ромонова) Питання: Чи є спосіб я змусити запам'ятати командний рядок, тому мені не доведеться запускати це кожен раз, коли я відкриваю новий командний рядок?

doskey це текстова команда, що інтерпретується командним процесором (наприклад, cmd.exe), вона не може знати стан змін у якомусь іншому процесі (особливо в тому, який ще не запущений).

Люди, які використовують doskeyдля встановлення своїх початкових середовищ командної оболонки, зазвичай використовують /Kопцію (часто за допомогою ярлика), щоб запустити пакетний файл, який виконує всі загальні настройки (наприклад, заголовок вікна, кольори тощо).

cmd.exe /K env.cmd

env.cmd:

title "Foo Bar"
doskey np=notepad++.exe $*
...

Якщо ви просто збираєтеся виконати кілька простих команд, ви можете виконати наступні дії:

1. Створіть папку під назвою C: \ Aliases
2. Додайте С: \ Псевдоніми на свій шлях (щоб будь-які файли в ньому знаходилися щоразу)
3. Створіть .bat файл у C: \ Псевдоніми для кожного потрібного псевдоніму

Можливо, надмірність, але на відміну від (інакше відмінної) відповіді від @Argyll, це вирішує проблему завантаження кожного разу.

Наприклад, у мене є файл під назвою dig2.bat із наступним:

@echo off
echo.
dig +noall +answer %1

Ваш файл np просто матиме таке:

@echo off
echo.
notepad++.exe %1

Потім просто додайте папку C: \ Aliases до змінної середовища PATH. Якщо у вас вже відкрився CMD або PowerShell, вам потрібно буде його перезапустити.

FWIW, у мене в каталозі C: ​​\ Aliases близько 20 псевдонімів (окремих файлів .bat) - я просто створюю нові, якщо потрібно. Можливо, не найновіший, але це чудово працює.

ОНОВЛЕННЯ : За чудовою пропозицією користувача @Mav, навіть краще використовувати % *, а не % 1 , щоб ви могли передавати кілька команд у команду, наприклад:

@echo off
echo.
notepad++.exe %*

Таким чином, ви могли це зробити:

np c:\temp\abc.txt c:\temp\def.txt c:\temp\ghi.txt

і він відкриє всі 3 файли.

Крім того, ви можете використовувати, cmderякий дозволяє додавати псевдоніми, як і Linux:

alias subl="C:\Program Files\Sublime Text 3\subl.exe" $*

З огляду на те, що ви додали блокнот ++ .ee до змінної PATH, це надзвичайно просто. Створіть файл у папці System32, який викликається np.batіз таким кодом:

@echo off
call notepad++.exe %*

У %*проходжу по всіх аргументів ви даєте npкоманду до notepad++.exeкоманді.

РЕДАКТУВАННЯ: Вам знадобиться доступ адміністратора для збереження файлів у папку System32, що для мене було трохи химерним. Я просто створив файл десь ще і перемістив його в System32 вручну.

Також ви можете створити на своєму шляху alias.cmd (наприклад, C: \ Windows) за допомогою команди

@echo %2 %3 %4 %5 %6 > %windir%\%1.cmd

Після цього ви можете зробити щось подібне:

alias nameOfYourAlias commands to run 

Після цього ви можете ввести командний рядок

nameOfYourAlias 

це виконає

commands to run 

Але найкращим способом для мене є лише додавання шляху програми.

setx PATH "%PATH%;%ProgramFiles%\Sublime Text 3" /M 

І тепер я запускаю піднесене як

subl index.html

Псевдонім консолі у Windows 10

Для визначення псевдоніму консолі використовуйте Doskey.exeдля створення макросу або використання AddConsoleAliasфункції.

доскей

doskey test=cd \a_very_long_path\test

Для передачі параметрів додайте $*в кінці:doskey short=longname $*

AddConsoleAlias

AddConsoleAlias( TEXT("test"), 
                 TEXT("cd \\<a_very_long_path>\\test"), 
                 TEXT("cmd.exe"));

Більше інформації тут Псевдоніми консолей , Доскі , Параметри

Ви хочете створити псевдонім, просто ввівши:

c:\>alias kgs kubectl get svc

Created alias for kgs=kubectl get svc

І використовувати псевдонім таким чином:

c:\>kgs alfresco-svc

NAME           TYPE        CLUSTER-IP     EXTERNAL-IP   PORT(S)   AGE
alfresco-svc   ClusterIP   10.7.249.219   <none>        80/TCP    8d

Просто додайте наступний alias.batфайл до шляху. Він просто створює додаткові пакетні файли в тому ж каталозі, що і сам.

  @echo off
  echo.
  for /f "tokens=1,* delims= " %%a in ("%*") do set ALL_BUT_FIRST=%%b
  echo @echo off > C:\Development\alias-script\%1.bat
  echo echo. >> C:\Development\alias-script\%1.bat
  echo %ALL_BUT_FIRST% %%* >> C:\Development\alias-script\%1.bat
  echo Created alias for %1=%ALL_BUT_FIRST%

Приклад пакетного файлу, створеного цим файлом, називається kgs.bat:

@echo off 
echo. 
kubectl get svc %* 

Насправді я піду вам на один кращий і дозвольте вам зайнятись невеликою технікою, якою я користувався з часу програмування на Амізі. У будь-якій новій системі, яку ви використовуєте, будь то персональна чи професійна, першим кроком є ​​створення двох папок: C:\BINі C:\BATCH. Потім змініть свою інструкцію шляху, щоб вона ставила обидва на початку в порядку C:\BATCH;C:\BIN;[rest of path].

Зробивши це, якщо у вас є мало утилітних утиліт, вам потрібен доступ, щоб просто скопіювати їх у C:\BINпапку, і вони на вашому шляху. Щоб тимчасово змінити ці завдання, ви можете додати пакет файлу з тим самим іменем, що і виконуваний файлC:\BATCH і шлях знайде його до файлу в C: \ BIN. Він повинен охоплювати все, що вам може знадобитися робити.

Звичайно, в ці дні канонічно правильним способом зробити це було б створення символьного з'єднання з файлом, але застосовується той самий принцип. Також є додатковий додатковий бонус. Якщо ви хочете помістити в систему щось, що суперечить чомусь, що вже перебуває на шляху, розміщення його в папці C:\BINабо C:\Batchпапці просто попередньо видалить оригінал - дозволяючи вам переміщувати речі тимчасово або назавжди або перейменовувати речі на імена, які ви зручніше - без фактичної зміни оригіналу.

Розширення на відповідь roryhewitt .

Перевагою використання файлів .cmd над DOSKEY є те, що ці "псевдоніми" потім доступні в інших оболонках, таких як PowerShell або WSL (підсистема Windows для Linux).

Єдина проблема з використанням цих команд в bash - це те, що це може зайняти трохи більше налаштування, оскільки вам може знадобитися зробити деяку маніпуляцію шляхом, перш ніж викликати свій "псевдонім".

наприклад, у мене є vs.cmd, який є моїм "псевдонімом" для редагування файлу в Visual Studio

@echo off
if [%1]==[] goto nofiles
start "" "c:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" /edit %1
goto end
:nofiles
start "" "C:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" "[PATH TO MY NORMAL SLN]"
:end

Який запускає VS (в даному випадку VS2012 - але налаштовуйте на смак), використовуючи мій "звичайний" проект, не вказаний файл, але при наданні файлу спробує приєднати до запущеного VS, відкриваючи цей файл "в рамках цього проекту", а не запускаючи новий екземпляр VS.

Для використання цього з bash я додаю додатковий рівень непрямості, оскільки "vs Myfile" не завжди працюватиме

alias vs='/usr/bin/run_visual_studio.sh'

Який коригує контури перед викликом vs.cmd

#!/bin/bash
cmd.exe /C 'c:\Windows\System32\vs.cmd' "`wslpath.sh -w -r $1`"

Тож таким чином я можу просто зробити

vs SomeFile.txt

У командному рядку, Power Shell або bash, і він відкривається в моїй запущеній Visual Studio для редагування (що просто рятує мій бідний мозок від роботи з VI командами або деякими подібними, коли я щойно редагував у VS годинами).

Це рішення не є влучним, але в деяких випадках служить меті.

Спочатку створіть папку та додайте її до системного шляху. Перейдіть до виконуваної програми будь-якої програми, для якої ви хочете створити псевдонім. Клацніть правою кнопкою миші та надішліть на робочий стіл (створення ярлика). Перейменуйте ярлик на будь-яке ім’я псевдоніма. Тепер візьміть ярлик і помістіть у свою папку.

З підказки запуску ви можете ввести ім'я швидкого доступу безпосередньо, і ви можете відкрити програму для вас. Але з командного рядка вам потрібно додати .lnk і натиснути Enter, програма буде відкрита.

Природно, я б не відпочивав, поки не маю найзручнішого рішення з усіх. Поєднавши дуже багато відповідей та тем у широкому Інтернеті, ось що ви можете мати.

• Завантажується автоматично з кожним екземпляром cmd
• Не потрібне ключове слово DOSKEYдля псевдонімів

Зауважте, що це багато в чому ґрунтується на відповіді та коментарях Аргілла, безумовно, прочитайте його, щоб зрозуміти поняття.

Як це працює?

1) створити файл макросу з псевдонімами (або bat / cmd-файл, щоб також запускати інші речі)
2) зареєструйте його в Реєстрі, щоб запустити на кожному екземплярі cmd
  - ви також можете запустити його за допомогою ярлика, лише якщо хочете

Це все

;==============================================================================
;= This file is registered via registry to auto load with each instance of cmd.
;================================ general info ================================
;= https://stackoverflow.com/a/59978163/985454  -  how to set it up?
;= https://gist.github.com/postcog/5c8c13f7f66330b493b8  -  example doskey macrofile
;========================= loading with cmd shortcut ==========================
;= create a cmd link with the following target :
;= %comspec% /k "(doskey /macrofile=%userprofile%\cmd\aliases.mac)"

alias=subl %USERPROFILE%\cmd\aliases.mac
hosts=runas /noprofile /savecred /user:QWERTY-XPS9370\administrator "subl C:\Windows\System32\drivers\etc\hosts" > NUL

ls=ls --color=auto $*
ll=ls -l --color=auto $*
la=ls -la --color=auto $*
grep=grep --color

~=cd %USERPROFILE%
cdr=cd c:\repos
cdd=cd c:\repos\dixons
cds=cd c:\repos\stekkie
cdu=cd c:\repos\uplus
cduo=cd c:\repos\uplus\oxbridge-fe
cdus=cd c:\repos\uplus\stratus

;============================= :end ============================
;= rem ******************************************************************
;= rem * EOF - Don't remove the following line.  It clears out the ';'
;= rem * macro. We're using it because there is no support for comments
;= rem * in a DOSKEY macro file.
;= rem ******************************************************************
;=

Тепер у вас є два варіанти:
а) зареєструйте лише макрофайл;
б) використовуйте звичайнийcmd/bat файл, щоб також запустити довільні команди.
Перейменуйте потрібну команду Autorun.

  Autorun    REG_SZ    doskey /macrofile=%userprofile%\cmd\aliases.mac
  Autorun_    REG_SZ    %USERPROFILE%\cmd\env.cmd

Windows Registry Editor Version 5.00
[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"Autorun"="doskey /macrofile=%userprofile%\\cmd\\aliases.mac"
"Autorun_"="%USERPROFILE%\\cmd\\env.cmd"

:: This file is registered via registry to auto load with each instance of cmd.
:: https://stackoverflow.com/a/59978163/985454

@echo off
doskey /macrofile=%userprofile%\cmd\aliases.mac

:: put other commands here

Оскільки у вас вже є notepad++.exeна вашому шляху. Створіть ярлик у цій папці з назвою npта вкажіть на нього notepad++.exe.

По-перше, ви можете створити файл під назвою np.cmd і помістити його в папку, яка знаходиться в списку пошуку PATH. Потім відредагуйте файл np.cmd, як показано нижче:

@echo off
notepad++.exe

Якщо ви хочете ввімкнути псевдоніми на основі каталогу / проекту , спробуйте:

1. Спочатку створіть пакетний файл, який шукатиме файл із іменем aliasesу поточному каталозі та ініціалізує псевдоніми з нього, давайте назвемо йогоmake-aliases.cmd

   @echo off
   if not exist aliases goto:eof
   echo [Loading aliases...]
   for /f "tokens=1* delims=^=" %%i in (aliases) do (
      echo   %%i ^<^=^> %%j
      doskey %%i=%%j
   )
   doskey aliases=doskey /macros
   echo   --------------------
   echo   aliases ^=^> list  all
   echo   alt+F10 ^=^> clear all
   echo [Done]
   

2. Потім створіть, aliasesде вони вам потрібні, використовуючи наступний формат:

   alias1 = command1
   alias2 = command2
   ...
   

   наприклад:

   b = nmake
   c = nmake clean
   r = nmake rebuild
   

3. Потім додайте розташування make-aliases.cmdдо %PATH%змінної, щоб зробити її загальносистемною, або просто збережіть її у відомому місці.

4. Зробити це автоматично з cmd.

   • Я б напевно радив не використовувати HKEY_CURRENT_USER\Software\Microsoft\Command Processor\AutoRunдля цього, оскільки деякі засоби розробки запускають сценарій автозапуску кілька разів на сеанс.

   • Якщо ви використовуєте ConEmu ви могли б піти іншим шляхом і запустити сценарій з завдання запуску ( Settings> Startup> Tasks), наприклад, я створив запис під назвою {MSVC}:

     cmd.exe /k "vcvars64 && make-aliases",

     а потім зареєстрував його в контекстному меню Провідника через Settings> Integration>з Command: {MSVC} -cur_console:n, так що тепер я можу клацнути правою кнопкою миші папку і запустити підказку розробника VS всередині неї aliasesавтоматично з моїм завантаженим, якщо вони трапляються у цій папці.

     Без ConEmu ви можете просто створити ярлик до cmd.exeвідповідної команди або просто запускати make-aliasesвручну кожен раз.

Якщо ви забули псевдоніми, використовуйте aliasesмакрос, і якщо щось піде не так, просто скиньте поточний сеанс натисканням клавіші Alt+ F10, що є вбудованою командою cmd.

Використання doskey - це правильний спосіб зробити це, але він скидається, коли вікно командного рядка закриється. Вам потрібно додати цей рядок до чогось подібного .bashrc еквівалента. Тому я зробив наступне:

1. Додайте "C: \ Program Files (x86) \ Notepad ++" до змінної системного шляху
2. Зробіть копію блокнота ++. Exe (звичайно, в тій же папці) та перейменуйте його в np.exe

Працює просто чудово!