Встановлення Emacs розділених буферів поруч

Багато функцій Emacs автоматично розділяють екран. Однак усі вони роблять це так, щоб вікна стояли одне над одним. Чи є спосіб змусити їх розділити так, щоб вони замість цього стояли поруч?

(setq split-height-threshold nil)
(setq split-width-threshold 0)

Довідковий посібник GNU Emacs Lisp: Вибір параметрів вікна

Тут є два рішення, використовуйте будь-яке, яке вам подобається:

В: Вертикально (ліворуч / праворуч) за замовчуванням:

(setq split-height-threshold nil)
(setq split-width-threshold 0)

B: Автоматичне розділення вікна по вертикалі (ліворуч / праворуч), якщо поточне вікно досить широке

(defun display-new-buffer (buffer force-other-window)
  "If BUFFER is visible, select it.
If it's not visible and there's only one window, split the
current window and select BUFFER in the new window. If the
current window (before the split) is more than 100 columns wide,
split horizontally(left/right), else split vertically(up/down).
If the current buffer contains more than one window, select
BUFFER in the least recently used window.
This function returns the window which holds BUFFER.
FORCE-OTHER-WINDOW is ignored."
  (or (get-buffer-window buffer)
    (if (one-window-p)
        (let ((new-win
               (if (> (window-width) 100)
                   (split-window-horizontally)
                 (split-window-vertically))))
          (set-window-buffer new-win buffer)
          new-win)
      (let ((new-win (get-lru-window)))
        (set-window-buffer new-win buffer)
        new-win))))
;; use display-buffer-alist instead of display-buffer-function if the following line won't work
(setq display-buffer-function 'display-new-buffer)

Помістіть будь-який .emacs/init.elфайл у свій файл. Ви можете змінити значення "100" на потрібне вам значення залежно від екрана.

Якщо у вас є два вікна в одному кадрі, і ви хочете змінити макет з вертикального на горизонтальний або навпаки, ось рішення:

(defun toggle-window-split ()
  (interactive)
    (if (= (count-windows) 2)
      (let* ((this-win-buffer (window-buffer))
            (next-win-buffer (window-buffer (next-window)))
            (this-win-edges (window-edges (selected-window)))
            (next-win-edges (window-edges (next-window)))
            (this-win-2nd
             (not (and (<= (car this-win-edges)
                        (car next-win-edges))
                    (<= (cadr this-win-edges)
                        (cadr next-win-edges)))))
         (splitter
          (if (= (car this-win-edges)
                 (car (window-edges (next-window))))
              'split-window-horizontally
            'split-window-vertically)))
    (delete-other-windows)
    (let ((first-win (selected-window)))
      (funcall splitter)
      (if this-win-2nd (other-window 1))
      (set-window-buffer (selected-window) this-win-buffer)
      (set-window-buffer (next-window) next-win-buffer)
      (select-window first-win)
      (if this-win-2nd (other-window 1))))))
;; C-x 4 t 'toggle-window-split
(define-key ctl-x-4-map "t" 'toggle-window-split)

Помістіть його у свій .emacs/init.elфайл, використовуйте C-x 4 tдля перемикання макета ваших вікон.

(setq split-height-threshold 0) (setq split-width-threshold 0)

це те, що мені довелося використовувати для отримання бажаної поведінки (без горизонтального розбиття)

Іноді нам потрібна зміна між Горизонтальним та Вертикальним відповідно до поточного відображення та нашої вимоги (більше рядків або більше стовпців).

Я рекомендую великий ToggleWindowSplit , і я прив'язую ключ до "Cc y"

http://www.emacswiki.org/emacs/ToggleWindowSplit

проста відповідь встановлення 2 змінних на нуль та 0 не працювала для мене, тому я написав 2 прості функції: одна просто розбиває вікно на вертикальні буфери NX і відкриває файли з іменем (наприклад) file.1 file.2 .. . file.NX у кожному та іншому думає так само, за винятком того, що робить це у 2D (NY рядки за стовпцями NX для відкриття файлів f.1 f.2 ... f. [NX * NY]). Щоб встановити, додайте цей код до .emacs:

    (defun grid-files-h (nx wx pfx)
  "Using dotimes, split the window into NX side-by-side buffers of width WX and load files starting with prefix PFX and ending in numbers 1 through NX"
  (let (ox fn k)  ; ox is not used, but fn is used to store the filename, and k to store the index string
    (dotimes (x (- nx 1) ox) ; go through buffers, x goes from 0 to nx-2 and ox is not used here
;     (print x)
      (setq k (number-to-string (+ x 1) ) )  ; k is a string that goes from "1" to "nx-1"
;     (print k)
      (setq fn (concat pfx k) ) ; fn is filename - concatenate prefix with k
;     (print fn)
      (find-file fn) ; open the filename in current buffer
      (split-window-horizontally wx) ; split window (current buffer gets wx-columns)
      (other-window 1) ; switch to the next (right) buffer
      )
    (setq k (number-to-string nx )) ; last (rightmost) buffer gets the "nx" file
    (setq fn (concat pfx k) ) ; fn = "pfx"+"nx"
    (find-file fn ) ; open fn
    (other-window 1) ; go back to the first buffer
    )  
  )

   (defun grid-files-sq (ny wy nx wx pfx)
      "Using dotimes, split the window into NX columns of width WX and NY rows of height WY and load files starting with prefix PFX and ending in numbers 1 through NX*NY"
      (let (oy ox fn k)  
        (dotimes (y ny oy) ; go through rows, y goes from 0 to ny-1 and oy is not used here
          (split-window-vertically wy) ; create this row
          (dotimes (x (- nx 1) ox) ; go through columns, x goes from 0 to nx-2 and ox is not used here
        (setq k (number-to-string (+ 1 (+ x (* y nx) ) ) ) ) ; k must convert 2 indecies (x,y) into one linear one (like sub2ind in matlab)
        (setq fn (concat pfx k) ) ; filename
        (find-file fn ) ; open
        (split-window-horizontally wx) ; create this column in this row (this "cell")
        (other-window 1) ; go to the next buffer on the right 
        )
          (setq k (number-to-string (+ nx (* y nx) ) ) ) ; rightmost buffer in this row needs a file too
          (setq fn (concat pfx k) ) ; filename
          (find-file fn ) ; open
          (other-window 1) ; go to next row (one buffer down)
          )
        )
      )

а потім, щоб використовувати вертикальний, я переходжу до * scratch * ( C-x b *scratch* RET, C-x 1), введіть (grid-files-h 3 20 "file.")then C-x C-e, або якщо ви хочете протестувати квадратний qrid C-x 1, введіть, (grid-files-sq 2 15 3 20 "f.")а потімC-x C-e і ви побачите щось на зразок

Можливо, це можна зробити краще / ефективніше, але це початок, і він робить те, що мені потрібно (відображати купу послідовно названих невеликих файлів). Не соромтеся вдосконалювати або використовувати повторно.

Я регулярно використовую кілька кадрів (вікна OSX) в emacs для різних проектів. Ось як я налаштував кілька кадрів, спочатку розділених на ліве та праве вікно.

  (defun make-maximized-split-frame (name)
    (let (( f (make-frame (list (cons 'name  name))) ))
      (maximize-frame f)
      (split-window (frame-root-window f) nil t)
      ))

  (make-maximized-split-frame "DocRaptor")
  (make-maximized-split-frame "Gauges")
  (make-maximized-split-frame "Instrumental")