Найпростіший, але повний приклад CMake

Якось мене зовсім збентежує те, як працює CMake. Кожен раз, коли я думаю, що я все ближче розумію, як мається на увазі писати CMake, це зникає в наступному прикладі, який я читаю. Все, що я хочу знати, - це як я структурувати свій проект, щоб мій CMake вимагав найменшого обслуговування в майбутньому. Наприклад, я не хочу оновлювати свій CMakeList.txt, коли я додаю нову папку в своє дерево src, яка працює точно так само, як і всі інші папки src.

Так я уявляю структуру свого проекту, але будь ласка, це лише приклад. Якщо рекомендований спосіб відрізняється, скажіть, будь ласка, і розкажіть, як це зробити.

myProject
    src/
        module1/
            module1.h
            module1.cpp
        module2/
            [...]
        main.cpp
    test/
        test1.cpp
    resources/
        file.png
    bin
        [execute cmake ..]

До речі, важливо, щоб моя програма знала, де знаходяться ресурси. Я хотів би знати рекомендований спосіб управління ресурсами. Я не хочу отримувати доступ до своїх ресурсів за допомогою "../resources/file.png"

після деяких досліджень у мене зараз є своя версія самого простого, але повного прикладу cmake. Ось він і намагається охопити більшість основ, включаючи ресурси та упаковку.

одне, що робить нестандартно - це обробка ресурсів. За замовчуванням cmake хоче поставити їх у / usr / share /, / usr / local / share / і щось еквівалентне у Windows. Я хотів мати простий zip / tar.gz, який можна витягти де завгодно і запустити. Тому ресурси завантажуються відносно виконуваного файлу.

основне правило для розуміння команд cmake - це наступний синтаксис: <function-name>(<arg1> [<arg2> ...])без коми або крапки. Кожен аргумент - це рядок. foobar(3.0)і foobar("3.0")те саме. ви можете встановити списки / змінні за допомогою set(args arg1 arg2). З цією змінною безліч foobar(${args}) і foobar(arg1 arg2)фактично однакові. Неіснуюча змінна еквівалентна порожньому списку. Список - це внутрішньо лише рядок з крапками з комою для розділення елементів. Тому список із лише одним елементом є за визначенням саме цим елементом, бокс не відбувається. Змінні - глобальні. Вбудовані функції пропонують певну форму названих аргументів тим, що вони очікують деяких ідентифікаторів, як PUBLICабоDESTINATIONу списку аргументів, щоб згрупувати аргументи. Але це не мовна особливість, ці ідентифікатори - це також лише рядки та проаналізовані реалізацією функції.

ви можете клонувати все з github

cmake_minimum_required(VERSION 3.0)
project(example_project)

###############################################################################
## file globbing ##############################################################
###############################################################################

# these instructions search the directory tree when cmake is
# invoked and put all files that match the pattern in the variables 
# `sources` and `data`
file(GLOB_RECURSE sources      src/main/*.cpp src/main/*.h)
file(GLOB_RECURSE sources_test src/test/*.cpp)
file(GLOB_RECURSE data resources/*)
# you can use set(sources src/main.cpp) etc if you don't want to
# use globing to find files automatically

###############################################################################
## target definitions #########################################################
###############################################################################

# add the data to the target, so it becomes visible in some IDE
add_executable(example ${sources} ${data})

# just for example add some compiler flags
target_compile_options(example PUBLIC -std=c++1y -Wall -Wfloat-conversion)

# this lets me include files relative to the root src dir with a <> pair
target_include_directories(example PUBLIC src/main)

# this copies all resource files in the build directory
# we need this, because we want to work with paths relative to the executable
file(COPY ${data} DESTINATION resources)

###############################################################################
## dependencies ###############################################################
###############################################################################

# this defines the variables Boost_LIBRARIES that contain all library names
# that we need to link to
find_package(Boost 1.36.0 COMPONENTS filesystem system REQUIRED)

target_link_libraries(example PUBLIC
  ${Boost_LIBRARIES}
  # here you can add any library dependencies
)

###############################################################################
## testing ####################################################################
###############################################################################

# this is for our testing framework
# we don't add REQUIRED because it's just for testing
find_package(GTest)

if(GTEST_FOUND)
  add_executable(unit_tests ${sources_test} ${sources})

  # we add this define to prevent collision with the main
  # this might be better solved by not adding the source with the main to the
  # testing target
  target_compile_definitions(unit_tests PUBLIC UNIT_TESTS)

  # this allows us to use our executable as a link library
  # therefore we can inherit all compiler options and library dependencies
  set_target_properties(example PROPERTIES ENABLE_EXPORTS on)

  target_link_libraries(unit_tests PUBLIC
    ${GTEST_BOTH_LIBRARIES}
    example
  )

  target_include_directories(unit_tests PUBLIC
    ${GTEST_INCLUDE_DIRS} # doesn't do anything on Linux
  )
endif()

###############################################################################
## packaging ##################################################################
###############################################################################

# all install commands get the same destination. this allows us to use paths
# relative to the executable.
install(TARGETS example DESTINATION example_destination)
# this is basically a repeat of the file copy instruction that copies the
# resources in the build directory, but here we tell cmake that we want it
# in the package
install(DIRECTORY resources DESTINATION example_destination)

# now comes everything we need, to create a package
# there are a lot more variables you can set, and some
# you need to set for some package types, but we want to
# be minimal here
set(CPACK_PACKAGE_NAME "MyExample")
set(CPACK_PACKAGE_VERSION "1.0.0")

# we don't want to split our program up into several things
set(CPACK_MONOLITHIC_INSTALL 1)

# This must be last
include(CPack)

Найбільш основний, але повний приклад можна знайти в навчальному посібнику CMake :

cmake_minimum_required (VERSION 2.6)
project (Tutorial)
add_executable(Tutorial tutorial.cxx)

Для прикладу проекту ви можете мати:

cmake_minimum_required (VERSION 2.6)
project (MyProject)
add_executable(myexec src/module1/module1.cpp src/module2/module2.cpp src/main.cpp)
add_executable(mytest test1.cpp)

Для вашого додаткового запитання в підручнику знову знайдеться один із способів: створіть файл заголовка, який можна настроювати, який ви включите у свій код. Для цього зробіть файл configuration.h.inіз таким вмістом:

#define RESOURCES_PATH "@RESOURCES_PATH@"

Потім у вашому CMakeLists.txtдодаванні:

set(RESOURCES_PATH "${PROJECT_SOURCE_DIR}/resources/"
# configure a header file to pass some of the CMake settings
# to the source code
configure_file (
  "${PROJECT_SOURCE_DIR}/configuration.h.in"
  "${PROJECT_BINARY_DIR}/configuration.h"
)

# add the binary tree to the search path for include files
# so that we will find TutorialConfig.h
include_directories("${PROJECT_BINARY_DIR}")

Нарешті, там, де вам потрібен шлях у вашому коді, ви можете:

#include "configuration.h"

...

string resourcePath = string(RESOURCE_PATH) + "file.png";

Тут я пишу найпростіший, але повний зразок файлів CMakeLists.txt.

Вихідний код

1. Підручники з привітного світу для переходу на платформу Android / iOS / Web / Desktop.
2. На кожній платформі я випустив зразок програми.
3. Структура файлів 08-cross_platform перевірена моєю роботою
4. Це може бути не ідеальною, але корисною та найкращою практикою для команди самостійно

Після цього я запропонував документ для деталей.

Якщо у вас є якісь питання, ви можете зв’язатися зі мною, і я хотів би пояснити це.