Мені потрібно призначити вихідну програму змінній, використовуючи пакетний файл MS.
Так що в оболонці GNU Bash я б використовував VAR=$(application arg0 arg1). Мені потрібна подібна поведінка в Windows, використовуючи пакетний файл.
Щось подібне set VAR=application arg0 arg1.
Відповіді:
Один із способів:
application arg0 arg1 > temp.txt
set /p VAR=<temp.txt
Інше:
for /f %%i in ('application arg0 arg1') do set VAR=%%i
Зауважте, що перший %в %%iвикористовується для виходу %після нього і потрібен при використанні вищевказаного коду в пакетному файлі, а не в командному рядку. Уявіть, у вас test.batє щось на кшталт:
for /f %%i in ('c:\cygwin64\bin\date.exe +"%%Y%%m%%d%%H%%M%%S"') do set datetime=%%i
echo %datetime%
for /f "tokens=3" %%i in ('route print ^| findstr "\<0.0.0.0\>"') do set "myVar=%%i"
Як додаток до цієї попередньої відповіді , труби можна використовувати всередині а для висловлювання, уникнуті символом каретки:
for /f "tokens=*" %%i in ('tasklist ^| grep "explorer"') do set VAR=%%i
for /f "tokens=*" %i in ('tasklist ^| findstr explorer') do @echo %iАле загалом usebackqслід використовувати для обробки складних команд.
for /f "tokens=*" %%i in ('"tasklist | grep explorer"') do set VAR=%%i. Простіше для мене, якщо в самій команді немає лапок.
@OP, ви можете використовувати для циклів для отримання статусу повернення програми, якщо вона видає щось інше, ніж числа
припускаючи, що на виході вашої програми є числовий код повернення, ви можете зробити наступне
application arg0 arg1
set VAR=%errorlevel%
Під час виконання: for /f %%i in ('application arg0 arg1') do set VAR=%%iя отримував помилку: %% я в цей час був несподіваним. Як виправлення, мені довелося виконати вище якfor /f %i in ('application arg0 arg1') do set VAR=%i
%%і поза ним пакетний файл у потрібному вам командному рядку%
На додаток до відповіді, ви не можете безпосередньо використовувати операторів переадресації виводу у встановленій частині forциклу (наприклад, якщо ви хочете приховати висновок stderror від користувача та надати приємніше повідомлення про помилку). Натомість вам доведеться уникати символів карети ( ^):
for /f %%O in ('some-erroring-command 2^> nul') do (echo %%O)
Довідка: Перенаправлення виводу команди в циклі пакетного сценарію
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
REM Prefer backtick usage for command output reading:
REM ENABLEDELAYEDEXPANSION is required for actualized
REM outer variables within for's scope;
REM within for's scope, access to modified
REM outer variable is done via !...! syntax.
SET CHP=C:\Windows\System32\chcp.com
FOR /F "usebackq tokens=1,2,3" %%i IN (`%CHP%`) DO (
IF "%%i" == "Aktive" IF "%%j" == "Codepage:" (
SET SELCP=%%k
SET SELCP=!SELCP:~0,-1!
)
)
echo actual codepage [%SELCP%]
ENDLOCAL
Ви можете використовувати пакетний макрос для простого захоплення командних виходів, трохи схожий на поведінку оболонки bash.
Використання макросу просте і схоже
%$set% VAR=application arg1 arg2
І це працює навіть з трубами
%$set% allDrives="wmic logicaldisk get name /value | findstr "Name""
Макрос використовує змінну, як масив, і зберігає кожен рядок в окремому індексі.
У вибірці %$set% allDrives="wmic logicaldiskстворено такі змінні:
allDrives.Len=5
allDrives.Max=4
allDrives[0]=Name=C:
allDrives[1]=Name=D:
allDrives[2]=Name=F:
allDrives[3]=Name=G:
allDrives[4]=Name=Z:
allDrives=<contains the complete text with line feeds>
Щоб його використовувати, не важливо зрозуміти, як працює сам макрос.
Повний приклад
@echo off
setlocal
call :initMacro
%$set% ipOutput="ipconfig"
call :ShowVariable ipOutput
echo First line is %ipOutput[0]%
echo(
%$set% driveNames="wmic logicaldisk get name /value | findstr "Name""
call :ShowVariable driveNames
exit /b
:ShowVariable
setlocal EnableDelayedExpansion
for /L %%n in (0 1 !%~1.max!) do (
echo %%n: !%~1[%%n]!
)
echo(
exit /b
:initMacro
if "!!"=="" (
echo ERROR: Delayed Expansion must be disabled while defining macros
(goto) 2>nul
(goto) 2>nul
)
(set LF=^
%=empty=%
)
(set \n=^^^
%=empty=%
)
set $set=FOR /L %%N in (1 1 2) dO IF %%N==2 ( %\n%
setlocal EnableDelayedExpansion %\n%
for /f "tokens=1,* delims== " %%1 in ("!argv!") do ( %\n%
endlocal %\n%
endlocal %\n%
set "%%~1.Len=0" %\n%
set "%%~1=" %\n%
if "!!"=="" ( %\n%
%= Used if delayed expansion is enabled =% %\n%
setlocal DisableDelayedExpansion %\n%
for /F "delims=" %%O in ('"%%~2 | findstr /N ^^"') do ( %\n%
if "!!" NEQ "" ( %\n%
endlocal %\n%
) %\n%
setlocal DisableDelayedExpansion %\n%
set "line=%%O" %\n%
setlocal EnableDelayedExpansion %\n%
set pathExt=: %\n%
set path=; %\n%
set "line=!line:^=^^!" %\n%
set "line=!line:"=q"^""!" %\n%
call set "line=%%line:^!=q""^!%%" %\n%
set "line=!line:q""=^!" %\n%
set "line="!line:*:=!"" %\n%
for /F %%C in ("!%%~1.Len!") do ( %\n%
FOR /F "delims=" %%L in ("!line!") Do ( %\n%
endlocal %\n%
endlocal %\n%
set "%%~1[%%C]=%%~L" ! %\n%
if %%C == 0 ( %\n%
set "%%~1=%%~L" ! %\n%
) ELSE ( %\n%
set "%%~1=!%%~1!!LF!%%~L" ! %\n%
) %\n%
) %\n%
set /a %%~1.Len+=1 %\n%
) %\n%
) %\n%
) ELSE ( %\n%
%= Used if delayed expansion is disabled =% %\n%
for /F "delims=" %%O in ('"%%~2 | findstr /N ^^"') do ( %\n%
setlocal DisableDelayedExpansion %\n%
set "line=%%O" %\n%
setlocal EnableDelayedExpansion %\n%
set "line="!line:*:=!"" %\n%
for /F %%C in ("!%%~1.Len!") DO ( %\n%
FOR /F "delims=" %%L in ("!line!") DO ( %\n%
endlocal %\n%
endlocal %\n%
set "%%~1[%%C]=%%~L" %\n%
) %\n%
set /a %%~1.Len+=1 %\n%
) %\n%
) %\n%
) %\n%
set /a %%~1.Max=%%~1.Len-1 %\n%
) %\n%
) else setlocal DisableDelayedExpansion^&set argv=
goto :eof
Я написав сценарій, який коментує google.com кожні 5 секунд і реєструє результати з поточним часом. Тут ви можете знайти вихід до змінних "commandLineStr" (з індексами)
@echo off
:LOOPSTART
echo %DATE:~0% %TIME:~0,8% >> Pingtest.log
SETLOCAL ENABLEDELAYEDEXPANSION
SET scriptCount=1
FOR /F "tokens=* USEBACKQ" %%F IN (`ping google.com -n 1`) DO (
SET commandLineStr!scriptCount!=%%F
SET /a scriptCount=!scriptCount!+1
)
@ECHO %commandLineStr1% >> PingTest.log
@ECHO %commandLineStr2% >> PingTest.log
ENDLOCAL
timeout 5 > nul
GOTO LOOPSTART