Perl
Я вирішив бути трохи антиконкурентним і показати, як ви зазвичай кодуєте таку проблему в Perl.
У кінці також є запис (46) із загальним кодом гольфу.
Ці перші три приклади починаються з цього заголовка.
#! /usr/bin/env perl
use Modern::Perl;
# which is the same as these three lines:
# use 5.10.0;
# use strict;
# use warnings;
while( <> ){
chomp;
last unless $_;
Collatz( $_ );
}
Проста рекурсивна версія
use Sub::Call::Recur;
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
die 'Integer values only' unless $n == int $n;
say $n;
given( $n ){
when( 1 ){}
when( $_ % 2 != 0 ){ # odd
recur( 3 * $n + 1 );
}
default{ # even
recur( $n / 2 );
}
}
}
Проста ітераційна версія
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
die 'Integer values only' unless $n == int $n;
say $n;
while( $n > 1 ){
if( $n % 2 ){ # odd
$n = 3 * $n + 1;
} else { #even
$n = $n / 2;
}
say $n;
}
}
Оптимізована ітераційна версія
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
die 'Integer values only' unless $n == int $n;
#
state @next;
$next[1] //= 0; # sets $next[1] to 0 if it is undefined
#
# fill out @next until we get to a value we've already worked on
until( defined $next[$n] ){
say $n;
#
if( $n % 2 ){ # odd
$next[$n] = 3 * $n + 1;
} else { # even
$next[$n] = $n / 2;
}
#
$n = $next[$n];
}
say $n;
# finish running until we get to 1
say $n while $n = $next[$n];
}
Зараз я збираюся показати, як ви зробите цей останній приклад з версією Perl до v5.10.0
#! /usr/bin/env perl
use strict;
use warnings;
while( <> ){
chomp;
last unless $_;
Collatz( $_ );
}
{
my @next = (0,0); # essentially the same as a state variable
sub Collatz{
my( $n ) = @_;
$n += 0; # ensure that it is numeric
die 'invalid value' unless $n > 0;
# fill out @next until we get to a value we've already worked on
until( $n == 1 or defined $next[$n] ){
print $n, "\n";
if( $n % 2 ){ # odd
$next[$n] = 3 * $n + 1;
} else { # even
$next[$n] = $n / 2;
}
$n = $next[$n];
}
print $n, "\n";
# finish running until we get to 1
print $n, "\n" while $n = $next[$n];
}
}
Орієнтир
По-перше, IO завжди буде повільною частиною. Отже, якщо ви насправді порівняли їх як є, ви повинні отримати приблизно однакову швидкість з кожного.
Щоб перевірити їх тоді, я відкрив дескриптор файлу в /dev/null( $null) і відредагував кожен, say $nщоб замість цього прочитати say {$null} $n. Це для зменшення залежності від ВВ.
#! /usr/bin/env perl
use Modern::Perl;
use autodie;
open our $null, '>', '/dev/null';
use Benchmark qw':all';
cmpthese( -10,
{
Recursive => sub{ Collatz_r( 31 ) },
Iterative => sub{ Collatz_i( 31 ) },
Optimized => sub{ Collatz_o( 31 ) },
});
sub Collatz_r{
...
say {$null} $n;
...
}
sub Collatz_i{
...
say {$null} $n;
...
}
sub Collatz_o{
...
say {$null} $n;
...
}
Після запуску 10 разів, ось репрезентативний результат вибірки:
Оцініть рекурсивний ітеративний оптимізатор
Рекурсивний 1715 / с - -27% -46%
Ітеративний 2336 / с 36% - -27%
Оптимізовано 3187 / с 86% 36% -
Нарешті, справжній запис коду-гольфу:
perl -nlE'say;say$_=$_%2?3*$_+1:$_/2while$_>1'
46 символів
Якщо вам не потрібно друкувати початкове значення, ви можете видалити ще 5 символів.
perl -nE'say$_=$_%2?3*$_+1:$_/2while$_>1'
41 символ усього
31 символ для фактичної частини коду, але код не працюватиме без -nперемикача. Тож я включаю весь приклад до свого підрахунку.