У електронній таблиці Google: Як я можу порахувати рядки даної області, які мають значення? Усі підказки про це я знайшов до цього часу, що призводять до формул, які підраховують рядки, які мають не порожній вміст (включаючи формулу), але клітинку з

=IF(1=2;"";"")  // Shows an empty cell

зараховується також.

Яке рішення цього простого завдання?

Створіть інший стовпець, який визначає, чи посилається клітинка порожня, використовуючи функцію "CountBlank". Потім використовуйте підрахунок значень, створених у новому стовпці "CountBlank".

Я щойно використовував, =COUNTIF(Range, "<>")і він рахував непусті клітини для мене.

=counta(range) 

• counta: "Повертає підрахунок кількості значень у наборі даних"

  Примітка: CountAвважає ""бути значення . Тільки комірки, які є порожніми (натисніть видалити в комірці, щоб очистити її), не враховуються.

  Підтримка Google: https://support.google.com/docs/answer/3093991

• countblank: "Повертає кількість порожніх комірок у заданому діапазоні"

  Примітка: CountBlankрозглядаються як порожні комірки (натисніть видалити, щоб порожня клітинка), так і комірки, у яких формула повертається ""до порожніх комірок.

  Служба підтримки Google: https://support.google.com/docs/answer/3093403

Якщо у вас є діапазон, який включає формули, в результаті яких ""ви можете змінити свою формулу

=counta(range)

до:

=Counta(range) - Countblank(range)

EDIT: функція є countblank, ні countblanks, остання видасть помилку.

Ось що я вважаю найкращим рішенням поки що:

=CountIf(ArrayFormula(range<>""),TRUE)

Ось чому в 3 простих кроки

Крок 1: Простий як пиріг - додайте додатковий стовпчик

Відповідь на eniacAvenger дасть правильне рішення , не піклуючись про випадки країв , як =A1<>""здається , щоб прийти до правильного truthy / falsy вартості , заснованим на тому , як ми інтуїтивно думати про порожніх клітинках, або незаймані заготовки або створені заготовки.

Тож уявіть, що у нас є ці дані, і ми хочемо, щоб кількість непрацьованих звітів була B2:B6:

|   |      A      |   B   |    C    |
|---|-------------|-------|---------|
| 1 | Description | Value | B1<>""  |
| 2 | Text        | H     | TRUE    |
| 3 | Number      | 1     | TRUE    |
| 4 | IF -> ""    |       | FALSE   |
| 5 | IF -> Text  | h     | TRUE    |
| 6 | Blank       |       | FALSE   |

Якби ми покладалися на стовпчик С , ми могли б отримати кількість значень у B так:

=COUNTIF(C2:C6,True)

Крок 2: Використовуйте FormulaArrayдля динамічного створення додаткового стовпця

Однак коментар obzirRatio є дійсним - якщо вам потрібен додатковий стовпець, ви часто можете досягти тієї самої мети, з ArrayFormulaякою можна створити стовпець у пам'яті, не витрачаючи місця на аркуші.

Отже, якщо ми хочемо створити C динамічно, ми можемо використовувати формулу масиву на зразок цієї:

=ArrayFormula(B2:B6<>"")

Якщо ми просто помістимо його в C2, він створив би вертикальний масив одним натисканням пера:

|   |      A      |   B   |    C                     |
|---|-------------|-------|--------------------------|
| 1 | Description | Value | =ArrayFormula(B2:B6<>"") |
| 2 | Text        | H     | TRUE                     |
| 3 | Number      | 1     | TRUE                     |
| 4 | IF -> ""    |       | FALSE                    |
| 5 | IF -> Text  | h     | TRUE                     |
| 6 | Blank       |       | FALSE                    |

Крок 3: Підрахунок значень у динамічному стовпці

Але коли це вирішено, нам більше не потрібен стовпець, щоб просто відображати значення.

ArrayFormulaбуде вирішувати в наступному діапазоні: {True,True,False,True,False}.
CountIfпросто займає будь-який діапазон, і в цьому випадку можна порахувати кількість значень True.

Таким чином, ми можемо обернутися CountIfнавколо значень, отриманих ArrayFormulaтаким чином:

=CountIf(ArrayFormula(B2:B6<>""),TRUE)

Подальше читання

Інші рішення в цій темі або надмірно складні, або не вдається в окремих крайніх випадках, які я перерахував у цьому тестовому аркуші:

Електронна таблиця Google - Тест CountA - Демо

Чому це CountAпрацює виграшно, як це робиться, дивіться мою відповідь тут

Для мене жоден з відповідей не працював для діапазонів, що включають як незаймані клітини, так і клітини, які порожні на основі формули (наприклад =IF(1=2;"";""))

Що для мене це вирішило:

=COUNTA(FILTER(range, range <> ""))

Вирішено за допомогою рішення, який я знайшов googling від Yogi Anand: https://productforums.google.com/d/msg/docs/3qsR2m-1Xx8/sSU6Z6NYLOcJ

У наведеному нижче прикладі підраховується кількість непустих рядків у діапазоні A3: C, не забудьте оновити обидва діапазони у формулі відповідно до ваших інтересів.

=ArrayFormula(SUM(SIGN(MMULT(LEN(A3:C), TRANSPOSE(SIGN(COLUMN(A3:C)))))))

Також не забудьте уникнути кругових залежностей, це станеться, якщо ви, наприклад, порахуєте кількість не порожніх рядків у A: C і помістите цю формулу в стовпчик A або C.

Це для мене робота:

=SUMPRODUCT(NOT(ISBLANK(F2:F)))

Підрахунок усіх не порожніх комірок від F2 до кінця стовпця

З огляду на діапазон A:A, я припускаю:

=COUNTA(A:A)-(COUNTIF(A:A,"*")-COUNTIF(A:A,"?*"))

Проблема полягає в перенарахуванні COUNTA точно на кількість комірок з рядками нульової довжини "".

Рішення полягає в тому, щоб знайти кількість саме цих комірок. Це можна знайти, шукаючи всі текстові комірки та віднімаючи всі текстові комірки принаймні з одним символом

• COUNTA (A: A): комірки зі значенням, включаючи, ""але виключаючи справді порожні комірки
• COUNTIF (A: A, "*"): комірки, що розпізнаються як текст, включаючи, ""але виключаючи справді порожні комірки , але виключаючи їх
• COUNTIF (A: A, "? *"): Комірки, розпізнані як текст, принаймні один символ

Це означає, що значення COUNTIF(A:A,"*")-COUNTIF(A:A,"?*")повинно бути числом текстових комірок мінус кількість текстових комірок, що мають принаймні один символ, тобто кількість комірок, що містять точно""

Більш просте рішення, яке працює для мене:

=COUNTIFS(A:A;"<>"&"")

Він рахує як числа, рядки, дати тощо, які не є порожніми

Наскільки я бачу, більшість рішень тут підраховують кількість не порожніх комірок, а не кількість рядків із порожньою коміркою всередині.

B3:E29Наприклад, одне можливе рішення для асортименту

=SUM(ArrayFormula(IF(B3:B29&C3:C29&D3:D29&E3:E29="";0;1)))

Тут ArrayFormula(IF(B3:B29&C3:C29&D3:D29&E3:E29="";0;1))повертається стовпчик 0(якщо рядок порожній) та 1(else).

Ще одна дана у відповіді Раціо .

Ви можете визначити власну функцію за допомогою програми Script (Інструменти> Редактор сценаріїв), яка називається, наприклад numNonEmptyRows:

function numNonEmptyRows(range) {
  Logger.log("inside");
  Logger.log(range);
  if (range && range.constructor === Array) {
    return range.map(function(a){return a.join('')}).filter(Boolean).length
  }
  else {
    return range ? 1 : 0;
  }
}

А потім скористайтеся цією коміркою =numNonEmptyRows(A23:C25)для підрахунку кількості порожніх рядків у діапазоні A23:C25;

У Таблицях Google, щоб підрахувати кількість рядків, що містять принаймні одну не порожню клітинку в двовимірному діапазоні :

=ARRAYFORMULA(
  SUM(
    N(
      MMULT(
        N(A1:C5<>""),
        TRANSPOSE(COLUMN(A1:C5)^0)
      )
      >0
    )
  )
)

Де A1: C5 - це діапазон, який ви перевіряєте на непорожні рядки.

Формула походить і пояснюється в наступній статті від EXCELXOR - https://excelxor.com/2015/03/30/counting-rows-where-at-least-one-condition-is-met/

Дуже гнучкий спосіб робити такі речі - це використовувати ARRAYFORMULA.

Як приклад, уявіть, що ви хочете порахувати непорожні рядки (текстові поля), ви можете використовувати цей код:

=ARRAYFORMULA(SUM(IF(Len(B3:B14)>0, 1, 0)))

Тут відбувається те, що "ArrayFormula" дозволяє вам працювати над набором значень. Використовуючи функцію SUM, ви вказуєте "ArrayFormula" для підсумовування будь-якого значення набору. Пункт "Якщо" використовується лише для позначення "порожній" або "не порожній", 1 - не порожній, а 0 - в іншому випадку. "Лен" повертає довжину різних текстових полів, там ви визначаєте набір (діапазон), який ви хочете перевірити. Нарешті, "ArrayFormula" підсумовує 1 для кожного поля всередині набору (діапазону), в якому "len" повертає більше 0.

Якщо ви хочете перевірити будь-яку іншу умову, просто змініть перший аргумент пункту IF.