Приховані функції пакетних файлів Windows

Які є менш знаючі, але важливі та корисні функції пакетних файлів Windows?

Правила:

• Одна особливість на відповідь
• Дайте як короткий опис функції, так і приклад , а не лише посилання на документацію
• Обмежуйте відповіді на власну функціональність , тобто не потребує додаткового програмного забезпечення, як-от Windows Resource Kit

Пояснення: ми посилаємося сюди на скрипти, які обробляються cmd.exe, що є типовим для варіантів WinNT.

(Див. Також: Пакетні файли Windows: .bat vs .cmd? )

Продовження рядка:

call C:\WINDOWS\system32\ntbackup.exe ^
    backup ^
    /V:yes ^
    /R:no ^
    /RS:no ^
    /HC:off ^
    /M normal ^
    /L:s ^
    @daily.bks ^
    /F daily.bkf

PUSHD path

Переходить в каталог , вказаний шлях .

POPD

Повертає вас до каталогу, з якого ви "натиснули".

Не впевнений, наскільки це було б корисно у пакетному файлі, але це дуже зручна команда для використання в командному рядку:

C:\some_directory> start .

Це відкриє Провідник Windows у папці "some_directory".

Я вважав це чудовим часом.

Мені завжди складно читати коментарі, які позначені ключовим словом у кожному рядку:

REM blah blah blah

Легше читати:

:: blah blah blah

Змінні підрядки:

> set str=0123456789
> echo %str:~0,5%
01234
> echo %str:~-5,5%
56789
> echo %str:~3,-3%
3456

Команда FOR ! Хоча я ненавиджу писати пакетні файли, я вдячний за це.

FOR /F "eol=; tokens=2,3* delims=, " %i in (myfile.txt) do @echo %i %j %k

проаналізував би кожен рядок у myfile.txt, ігноруючи рядки, які починаються з крапки з комою, передаючи 2-й та 3-й жетони від кожного рядка до тіла для тегів, розмежованих комами та / або пробілами. Зауважте, що для операторів body посилання% i для отримання 2-го маркера,% j для отримання 3-го маркера, і% k для отримання всіх залишилися лексем після 3-го.

Ви також можете використовувати це для повторення каталогів, вмісту каталогів тощо ...

Замість того, щоб замітати сценарій із рядками REM або ::, я виконую наступні дії у верхній частині кожного сценарію:

@echo OFF
goto :START

Description of the script.

Usage:
   myscript -parm1|parm2 > result.txt

:START

Зверніть увагу, як ви можете використовувати символи труби та перенаправлення, не уникаючи їх.

Шлях (з диском), де сценарій: ~ dp0

set BAT_HOME=%~dp0
echo %BAT_HOME%
cd %BAT_HOME%

Частка% ~ dp0 вже згадувалася, але насправді в ній є більше: персонаж (и) після ~ визначають інформацію, що вилучається.
Жодна літера не призводить до повернення імені файлу патчу
d - повертає букву диска
p - повертає шлях
s - повертає короткий шлях
x - повертає розширення файлу.
Отже, якщо ви виконаєте скрипт test.bat нижче від c: \ Temp \ long dir name \ папка,

@echo off
echo %0
echo %~d0
echo %~p0
echo %~dp0
echo %~x0
echo %~s0
echo %~sp0

Ви отримуєте наступний вихід

test
c:
\Temp\long dir name\
c:\Temp\long dir name\
.bat
c:\Temp\LONGDI~1\test.bat
\Temp\LONGDI~1\

І якщо параметр буде переданий у ваш сценарій, як у
тесті c: \ temp \ mysrc \ test.cpp,
ті ж маніпуляції можна виконати зі змінною% 1.

Але результат розширення% 0 залежить від місця розташування!
На "верхньому рівні" партії вона розширюється до поточного імені пакета.
У функції (виклик) вона розширюється до назви функції.

@echo off
echo %0
call :test
goto :eof

:test
echo %0
echo %~0
echo %~n0

Вихід є (batchfile запускається з myBatch.bat)

myBatch.bat
:test
:test
myBatch

За допомогою CALL, EXIT / B, SETLOCAL & ENDLOCAL можна реалізувати підпрограми з локальними змінними.

приклад:

@echo off

set x=xxxxx
call :sub 10
echo %x%
exit /b

:sub
setlocal
set /a x=%1 + 1
echo %x%
endlocal
exit /b

Це надрукується

11
xxxxx

незважаючи на те, що: sub змінює x.

Підлий трюк, щоб зачекати N секунд (не є частиною cmd.exe, але не є додатковим програмним забезпеченням, оскільки він поставляється з Windows), дивіться рядок ping. Вам потрібно N + 1 пінг, оскільки перший пінг виходить без затримки.

    echo %time%
    call :waitfor 5
    echo %time%
    goto :eof
:waitfor
    setlocal
    set /a "t = %1 + 1"
    >nul ping 127.0.0.1 -n %t%
    endlocal
    goto :eof

Втеча від "сантехніки":

echo ^| ^< ^> ^& ^\ ^^

Можливість запускати команди та обробляти результат (на зразок зворотних посилань '$ ()' у баші).

for /f %i in ('dir /on /b *.jpg') do echo --^> %i

Якщо у назви файлів є пробіли, скористайтеся цим:

for /f "tokens=*" %i in ('dir /on /b *.jpg') do echo --^> %i

Створення порожнього файлу:

> copy nul filename.ext

Щоб приховати весь вихід з команди переспрямування на> nul 2> & 1.

Наприклад, деякі програми командного рядка відображають вихід, навіть якщо ви перенаправляєте на> nul. Але, якщо ви будете перенаправляти висновок, як рядок нижче, весь результат буде придушений.

PSKILL NOTEPAD >nul 2>&1

EDIT: Див. Ігнорування виводу команди для пояснення того, як це працює.

PAUSE

Зупиняє виконання та відображає таку підказку:

Натисніть будь-яку кнопку, щоб продовжити . . .

Корисно, якщо ви хочете запустити пакет, двічі клацнувши його в Провіднику Windows і хочете насправді побачити вихід, а не просто спалах вікна команд.

Еквівалент bash (та інших оболонок)

echo -n Hello # or
echo Hello\\c

який виводить " Hello" без кінцевого нового рядка. Зробити cmd-хак для цього:

<nul set /p any-variable-name=Hello

set /pце спосіб запросити користувача на введення. Він випускає заданий рядок і потім чекає (на тому ж рядку, тобто немає CRLF), щоб користувач ввів відповідь.

<nulпросто передає порожню відповідь на set /pкоманду, тому чистим результатом є випромінюваний рядок підказок. (Використовувана змінна залишається незмінною через порожній відгук.)

Проблеми: неможливо вивести провідний знак рівності, а на Vista провідні символи пробілу видаляються, але не на XP.

Шукайте та замінюйте, коли встановлюєте змінні середовища:

> @set fname=%date:/=%

... видаляє "/" з дати для використання в іменах файлів, розмічених часом.

і підрядки теж ...

> @set dayofweek=%fname:~0,3%

Арифметика цілого числа:

> SET /A result=10/3 + 1
4

Розділювачі команд:

cls & dir
copy a b && echo Success
copy a b || echo Failure

У другому рядку команда після && запускається лише в тому випадку, якщо перша команда успішна.

У 3-му рядку команда після || запускається, лише якщо перша команда не вдалася.

Виведіть порожній рядок:

echo.

Ви можете зв'язати ланцюжок, якщо заяви отримують ефект, наприклад, булеві значення "та" короткого замикання.

if foo if bar baz

Швидке перетворення текстового файлу Unicode (16 біт / char) у файл ASCII DOS (8 біт / char).

C:\> type unicodeencoded.txt > dosencoded.txt

як бонус, якщо можливо, символи правильно відображаються.

якщо структура блоку:

if "%VS90COMNTOOLS%"=="" (
  echo: Visual Studio 2008 is not installed
  exit /b
)

Затримка розширення змінних (з хорошими мірками, підкинуті підрядками):

    @echo off
    setlocal enableextensions enabledelayedexpansion
    set full=/u01/users/pax
:loop1
    if not "!full:~-1!" == "/" (
        set full2=!full:~-1!!full2!
        set full=!full:~,-1!
        goto :loop1
    )
    echo !full!
    endlocal

Не забезпечує багато функціональних можливостей, але ви можете використовувати команду заголовка для декількох застосувань, як-от надання статусу довгим сценарієм на панелі завдань або просто для покращення зворотного зв’язку з користувачем.

@title Searching for ...
:: processing search
@title preparing search results
:: data processing

У вас немає зручного редактора і вам потрібно створити пакетний файл?

copy con test.bat

Просто введіть команди, натисніть клавішу Enter для нового рядка. Натисніть Ctrl-Z і Enter, щоб закрити файл.

приклад віднімання рядків dateі timeотримати файл під назвою "РРРР-MM-DD HH: MM: SS.txt"

echo test > "%date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%_%time:~3,2%_%time:~6,2%.txt"

Я використовую, colorщоб вказати, чи мій сценарій закінчився успішно, не вдався чи потрібен певний ввід, змінивши колір тексту та фону. Це дійсно допомагає, коли у вас є деяка машина, яка знаходиться в межах зору, але досить далеко

колір XY

де X і Y - шістнадцяткове значення від 0до F, де X - фон, Y - текст, коли X = Y колір не зміниться.

колір Z

змінює колір тексту на 'Z' та встановлює чорний фон, 'color 0' не працюватиме

для назв кольорів зателефонуйте

колір?

Повний контроль над висновком з пробілами та знаками пробігу

echo.    ^<resourceDir^>/%basedir%/resources^</resourceDir^>

TheSoftwareJedi вже згадував команду for, але я знову згадаю про неї, оскільки вона дуже потужна.

Далі виводиться поточна дата у форматі YYYYMMDD, я використовую це під час створення каталогів для резервного копіювання.

for /f "tokens=2-4 delims=/- " %a in ('DATE/T') do echo %c%b%a