Мені потрібно перевірити, встановлена ​​чи ні змінна. Я спробував кілька прийомів, але вони, здається, не вдається, коли %1оточені цитатами, такими як випадок, коли %1є "c:\some path with spaces".

IF NOT %1 GOTO MyLabel // This is invalid syntax
IF "%1" == "" GOTO MyLabel // Works unless %1 has double quotes which fatally kills bat execution
IF %1 == GOTO MyLabel // Gives an unexpected GOTO error.

За даними цього сайту , це підтримувані IFтипи синтаксису. Отже, я не бачу способу це зробити.

IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command

Використовуйте квадратні дужки замість лапок:

IF [%1] == [] GOTO MyLabel

Дужки є безпечними : використовуйте лише квадратні дужки.

Ви можете використовувати:

IF "%~1" == "" GOTO MyLabel

зняти зовнішній набір лапок. Взагалі, це більш надійний метод, ніж використання квадратних дужок, оскільки він буде працювати, навіть якщо в змінній є пробіли.

Одне з найкращих напіврозв’язків - скопіювати %1в змінну, а потім використовувати уповільнене розширення, як delaedExp. завжди безпечний від будь-якого вмісту.

set "param1=%~1"
setlocal EnableDelayedExpansion
if "!param1!"=="" ( echo it is empty )
rem ... or use the DEFINED keyword now
if defined param1 echo There is something

Перевагою цього є те, що поводження з param1 абсолютно безпечно.

І налаштування param1 спрацює у багатьох випадках, як

test.bat hello"this is"a"test
test.bat you^&me

Але це все ще не вдається з таким дивним вмістом, як

test.bat ^&"&

Вміти отримати 100% правильну відповідь на існування

Він визначає, чи %1порожній, але для деякого вмісту він не може отримати вміст.
Це також може бути корисним для розрізнення порожнього %1та одного з "".
Він використовує здатність CALLкоманди відмовитися, не перериваючи пакетний файл.

@echo off
setlocal EnableDelayedExpansion
set "arg1="
call set "arg1=%%1"

if defined arg1 goto :arg_exists

set "arg1=#"
call set "arg1=%%1"
if "!arg1!" EQU "#" (
    echo arg1 exists, but can't assigned to a variable
    REM Try to fetch it a second time without quotes
    (call set arg1=%%1)
    goto :arg_exists
)

echo arg1 is missing
exit /b

:arg_exists
echo arg1 exists, perhaps the content is '!arg1!'

Якщо ви хочете отримати 100% куленепробиву для отримання вмісту, ви можете прочитати Як отримати навіть найдивніші параметри командного рядка?

Від ІФ / ?:

Якщо ввімкнено розширення команд, якщо змінюються такі дії:

IF [/I] string1 compare-op string2 command
IF CMDEXTVERSION number command
IF DEFINED variable command

......

ВИЗНАЧЕННЯ умовна працює так само, як ІСНУЄТЬСЯ, за винятком того, що вона має назву змінної середовища та повертає істину, якщо визначена змінна середовище.

На жаль, у мене немає достатньої репутації, щоб коментувати чи голосувати за нинішні відповіді на те, що мені довелося написати свою власну.

Спочатку питання ОП зазначало "змінну", а не "параметр", що стало дуже заплутаним, тим більше, що це посилання номер один в google для пошуку тестування пустих змінних. З моєї оригінальної відповіді Стефан відредагував оригінальне запитання, щоб використовувати правильну термінологію, але замість того, щоб видалити свою відповідь, я вирішив залишити його, щоб допомогти усунути будь-яку плутанину, особливо у випадку, якщо Google все ще надсилає людей сюди також для змінних:

% 1 НЕ ЗМІН! Це КОМАНДАЛЬНИЙ ПАРАМЕТР.

Дуже важлива відмінність. Одиничний знак відсотка з цифрою після того, як він відноситься до параметра командного рядка, а не до змінної.

Змінні встановлюються за допомогою команди set і відкликаються за допомогою 2-відсоткових знаків - один до і один після. Наприклад,% myvar%

Для перевірки порожньої змінної ви використовуєте синтаксис "якщо не визначено" (команди, явно для змінних, не вимагають жодних знаків відсотків), наприклад:

set myvar1=foo  
if not defined myvar1 echo You won't see this because %myvar1% is defined.  
if not defined myvar2 echo You will see this because %myvar2% isn't defined.

(Якщо ви хочете перевірити параметри командного рядка, то рекомендую звернутися до відповіді jamesdlin.)

Використовуйте "IF DEFINED команда змінної" для тестування змінної у пакетному файлі.

Але якщо ви хочете перевірити параметри партії, спробуйте нижче коди, щоб уникнути хитромудрих даних (наприклад, "1 2" або ab ^> cd)

set tmp="%1"
if "%tmp:"=.%"==".." (
    echo empty
) else (
    echo not empty
)

Я тестую з кодом нижче, і це добре.

@echo off

set varEmpty=
if not "%varEmpty%"=="" (
    echo varEmpty is not empty
) else (
    echo varEmpty is empty
)
set varNotEmpty=hasValue
if not "%varNotEmpty%"=="" (
    echo varNotEmpty is not empty
) else (
    echo varNotEmpty is empty
)

Я зазвичай використовую це:

IF "%1."=="." GOTO MyLabel

Якщо% 1 порожній, IF порівнює ". до "." який оцінить до істини.

Я створив цей невеликий пакетний сценарій на основі відповідей тут, оскільки існує багато дійсних. Не соромтеся додавати до цього, якщо ви дотримуєтесь того самого формату:

REM Parameter-testing

Setlocal EnableDelayedExpansion EnableExtensions

IF NOT "%~1"=="" (echo Percent Tilde 1 failed with quotes) ELSE (echo SUCCESS)
IF NOT [%~1]==[] (echo Percent Tilde 1 failed with brackets) ELSE (echo SUCCESS)
IF NOT  "%1"=="" (echo Quotes one failed) ELSE (echo SUCCESS)
IF NOT [%1]==[] (echo Brackets one failed) ELSE (echo SUCCESS)
IF NOT "%1."=="." (echo Appended dot quotes one failed) ELSE (echo SUCCESS)
IF NOT [%1.]==[.] (echo Appended dot brackets one failed) ELSE (echo SUCCESS)

pause

Порожній рядок - це пара double-quotes/ "", ми можемо просто перевірити довжину:

set ARG=%1
if not defined ARG goto nomore

set CHAR=%ARG:~2,1%
if defined CHAR goto goon

потім протестуйте це 2 символи на double-quotes:

if ^%ARG:~1,1% == ^" if ^%ARG:~0,1% == ^" goto blank
::else
goto goon

Ось пакетний сценарій, з яким можна грати. Я думаю, що це належним чином вловлює порожню рядок.

Це лише приклад, вам просто потрібно налаштувати 2 (або 3?) Кроки вище, відповідно до вашого сценарію.

@echo off
if not "%OS%"=="Windows_NT" goto EOF
:: I guess we need enableExtensions, CMIIW
setLocal enableExtensions
set i=0
set script=%0

:LOOP
set /a i=%i%+1

set A1=%1
if not defined A1 goto nomore

:: Assumption:
:: Empty string is (exactly) a pair of double-quotes ("")

:: Step out if str length is more than 2
set C3=%A1:~2,1%
if defined C3 goto goon

:: Check the first and second char for double-quotes
:: Any characters will do fine since we test it *literally*
if ^%A1:~1,1% == ^" if ^%A1:~0,1% == ^" goto blank
goto goon

:goon
echo.args[%i%]: [%1]
shift
goto LOOP

:blank
echo.args[%i%]: [%1] is empty string
shift
goto LOOP

:nomore
echo.
echo.command line:
echo.%script% %*

:EOF

Цей результат випробування на катування:

.test.bat :: ""  ">"""bl" " "< "">"  (")(") "" :: ""-"  " "( )"">\>" ""
args[1]: [::]
args[2]: [""] is empty string
args[3]: [">"""bl" "]
args[4]: ["< "">"]
args[5]: [(")(")]
args[6]: [""] is empty string
args[7]: [::]
args[8]: [""-"  "]
args[9]: ["( )"">\>"]
args[10]: [""] is empty string

command line:
.test.bat :: ""  ">"""bl" " "< "">"  (")(") "" :: ""-"  " "( )"">\>" ""

Можна використовувати

if defined (variable) echo That's defined!
if not defined (variable) echo Nope. Undefined.

Сценарій 1:

Input ("Видалити Quotes.cmd" "Це тест")

@ECHO OFF

REM Set "string" variable to "first" command line parameter
SET STRING=%1

REM Remove Quotes [Only Remove Quotes if NOT Null]
IF DEFINED STRING SET STRING=%STRING:"=%

REM IF %1 [or String] is NULL GOTO MyLabel
IF NOT DEFINED STRING GOTO MyLabel


REM   OR   IF "." equals "." GOTO MyLabel
IF "%STRING%." == "." GOTO MyLabel

REM GOTO End of File
GOTO :EOF

:MyLabel
ECHO Welcome!

PAUSE

Вихід (немає,% 1 НЕ було порожнім, порожнім або NULL):

Запустіть ("Видалити квоти.cmd") без будь-яких параметрів із вищевказаним сценарієм 1

Вихід (% 1 порожній, порожній або NULL):

Welcome!

Press any key to continue . . .

Примітка. Якщо ви встановите змінну всередині IF ( ) ELSE ( ) оператора, вона буде недоступною для DEFINED до того моменту, поки вона не закриє оператор "IF" (якщо не ввімкнено "Затримка змінного розширення"; після ввімкнення використовується знак оклику "!" Замість відсоток "%" символ}.

Наприклад:

Сценарій 2:

Input ("Видалити Quotes.cmd" "Це тест")

@ECHO OFF

SETLOCAL EnableDelayedExpansion

SET STRING=%0
IF 1==1 (
  SET STRING=%1
  ECHO String in IF Statement='%STRING%'
  ECHO String in IF Statement [delayed expansion]='!STRING!'
) 

ECHO String out of IF Statement='%STRING%'

REM Remove Quotes [Only Remove Quotes if NOT Null]
IF DEFINED STRING SET STRING=%STRING:"=%

ECHO String without Quotes=%STRING% 

REM IF %1 is NULL GOTO MyLabel
IF NOT DEFINED STRING GOTO MyLabel

REM GOTO End of File
GOTO :EOF

:MyLabel
ECHO Welcome!

ENDLOCAL
PAUSE

Вихід:

C:\Users\Test>"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd" "This is a Test"  
String in IF Statement='"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd"'  
String in IF Statement [delayed expansion]='"This is a Test"'  
String out of IF Statement='"This is a Test"'  
String without Quotes=This is a Test  

C:\Users\Test>  

Примітка. Це також видалить лапки з всередині рядка.

Наприклад (за допомогою сценарію 1 або 2): C: \ Users \ Test \ Documents \ Batch Files> "Remove Quotes.cmd" "Це" a "Test"

Вихід (сценарій 2):

String in IF Statement='"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd"'  
String in IF Statement [delayed expansion]='"This is "a" Test"'  
String out of IF Statement='"This is "a" Test"'  
String without Quotes=This is a Test  

Виконати ("Видалити Quotes.cmd") без будь-яких параметрів у Сценарії 2:

Вихід:

Welcome!

Press any key to continue . . .

Підводячи підсумки:

set str=%~1
if not defined str ( echo Empty string )

Цей код виведе "Порожній рядок", якщо% 1 є "" або "або порожнім. Додано його до прийнятої відповіді, яка наразі є невірною.

У мене було багато питань з великою кількістю відповідей в мережі. Більшість працює на більшість речей, але завжди є кутовий корпус, який порушує кожну.
Можливо, воно не працює, якщо у нього є цитати, можливо, воно порушується, якщо у нього немає лапок, синтаксична помилка, якщо у варі є пробіл, деякі працюватимуть лише на параметрах (на відміну від змінних оточуючих середовищ), інші методи дозволяють пустувати набір лапок, які пройдуть як "визначені", а деякі складніші не дозволять вам ланцюжокelse згодом .

Ось таке рішення, яким я задоволений, повідомте мене, якщо ви знайдете кутовий корпус, для якого він не буде працювати.

:ifSet
if "%~1"=="" (Exit /B 1) else (Exit /B 0)

Мати цю підпрограму або у вашому сценарії, або у власному .bat, має працювати.
Тож якщо ви хотіли написати (псевдо):

if (var)
then something
else somethingElse

Ви можете написати:

(Call :ifSet %var% && (
    Echo something
)) || (
    Echo something else
)

Він працював для всіх моїх тестів:

(Call :ifSet && ECHO y) || ECHO n
(Call :ifSet a && ECHO y) || ECHO n
(Call :ifSet "" && ECHO y) || ECHO n
(Call :ifSet "a" && ECHO y) || ECHO n
(Call :ifSet "a a" && ECHO y) || ECHO n

Echo'd n, y, n, y,y

Більше прикладів:

• Хочете просто перевірити if?Call :ifSet %var% && Echo set
• Тільки якщо ні (лише інше)? Call :ifSet %var% || Echo set
• Перевірка пройденого аргументу; працює чудово.Call :ifSet %1 && Echo set
• Не хотіли засмічувати ваші сценарії / код дупу, тому ви помістили його у свій власний ifSet.bat? Нема проблем:((Call ifSet.bat %var%) && Echo set) || (Echo not set)

Використовуючи! замість "для перевірки порожніх рядків

@echo off
SET a=
SET b=Hello
IF !%a%! == !! echo String a is empty
IF !%b%! == !! echo String b is empty

Я зайшов у вік трохи менше місяця (хоча це було запитано 8 років тому) ... Я сподіваюся, що він / він перейшов за межі пакетних файлів. ;-) Я раніше це робив. Я не впевнений, яка кінцева мета. Якщо він / він лінивий, як я, мій go.bat працює на такі речі. (Див. Нижче) Але, 1, команда в ОП може бути недійсною, якщо ви безпосередньо використовуєте вхід як команду. тобто

"C:/Users/Me"

є недійсною командою (або раніше, якщо ви були на іншому диску). Потрібно розбити його на дві частини.

C:
cd /Users/Me

І, 2, що означає "визначене" чи "невизначене"? GIGO. Я використовую за замовчуванням для введення помилок. Якщо вхід не потрапляє, він переходить до довідки (або команди за замовчуванням). Отже, жодне введення не є помилкою. Ви можете спробувати перейти на вхід і зрозуміти помилку, якщо така є. (Гаразд, за допомогою DOS завантаження (лише один батько) потрапляє в DOS. (Суворе!))

cd "%1"
if %errorlevel% neq 0 goto :error

І, 3, лапки потрібні лише навколо шляху, а не команди. тобто

"cd C:\Users" 

було погано (або звикли раніше), якщо ви не були на іншому приводі.

cd "\Users" 

є функціональним.

cd "\Users\Dr Whos infinite storage space"

працює, якщо у вас є пробіли на шляху.

@REM go.bat
@REM The @ sigh prevents echo on the current command
@REM The echo on/off turns on/off the echo command. Turn on for debugging
@REM You can't see this.
@echo off
if "help" == "%1" goto :help

if "c" == "%1" C:
if "c" == "%1" goto :done

if "d" == "%1" D:
if "d" == "%1" goto :done

if "home"=="%1" %homedrive%
if "home"=="%1" cd %homepath%
if "home"=="%1" if %errorlevel% neq 0 goto :error
if "home"=="%1" goto :done

if "docs" == "%1" goto :docs

@REM goto :help
echo Default command
cd %1
if %errorlevel% neq 0 goto :error
goto :done

:help
echo "Type go and a code for a location/directory
echo For example
echo go D
echo will change disks (D:)
echo go home
echo will change directories to the users home directory (%homepath%)
echo go pictures
echo will change directories to %homepath%\pictures
echo Notes
echo @ sigh prevents echo on the current command
echo The echo on/off turns on/off the echo command. Turn on for debugging
echo Paths (only) with folder names with spaces need to be inclosed in         quotes (not the ommand)
goto :done

:docs
echo executing "%homedrive%%homepath%\Documents"
%homedrive%
cd "%homepath%\Documents"\test error\
if %errorlevel% neq 0 goto :error
goto :done

:error
echo Error: Input (%1 %2 %3 %4 %5 %6 %7 %8 %9) or command is invalid
echo go help for help
goto :done

:done