Groovy вбудований REST / HTTP-клієнт?

Я чув, що Groovy має вбудований REST / HTTP-клієнт. Єдина бібліотека, яку я можу знайти - HttpBuilder , це це?

В основному я шукаю спосіб зробити HTTP GET з внутрішнього коду Groovy без необхідності імпортувати будь-які бібліотеки (якщо це можливо). Але оскільки цей модуль, здається, не є частиною ядра Groovy, я не впевнений, чи маю тут правильну бібліотеку.

Рідний Groovy GET і POST

// GET
def get = new URL("https://httpbin.org/get").openConnection();
def getRC = get.getResponseCode();
println(getRC);
if(getRC.equals(200)) {
    println(get.getInputStream().getText());
}

// POST
def post = new URL("https://httpbin.org/post").openConnection();
def message = '{"message":"this is a message"}'
post.setRequestMethod("POST")
post.setDoOutput(true)
post.setRequestProperty("Content-Type", "application/json")
post.getOutputStream().write(message.getBytes("UTF-8"));
def postRC = post.getResponseCode();
println(postRC);
if(postRC.equals(200)) {
    println(post.getInputStream().getText());
}

Якщо ваші потреби прості, і ви хочете уникати додавання додаткових залежностей, ви можете використовувати getText()методи, які Groovy додає до java.net.URLкласу:

new URL("http://stackoverflow.com").getText()

// or

new URL("http://stackoverflow.com")
        .getText(connectTimeout: 5000, 
                readTimeout: 10000, 
                useCaches: true, 
                allowUserInteraction: false, 
                requestProperties: ['Connection': 'close'])

Якщо ви очікуєте двійкові дані назад, існує також подібна функціональність, передбачена newInputStream()методами.

Найпростішим повинен бути:

def html = "http://google.com".toURL().text

Ви можете скористатися перевагами функцій Groovy, таких як with (), вдосконалення URLConnection та спрощених методів отримання / налаштування:

ОТРИМАТИ:

String getResult = new URL('http://mytestsite/bloop').text

ПОСТ:

String postResult
((HttpURLConnection)new URL('http://mytestsite/bloop').openConnection()).with({
    requestMethod = 'POST'
    doOutput = true
    setRequestProperty('Content-Type', '...') // Set your content type.
    outputStream.withPrintWriter({printWriter ->
        printWriter.write('...') // Your post data. Could also use withWriter() if you don't want to write a String.
    })
    // Can check 'responseCode' here if you like.
    postResult = inputStream.text // Using 'inputStream.text' because 'content' will throw an exception when empty.
})

Зверніть увагу, то POST починається при спробі прочитати значення з HttpURLConnection, наприклад responseCode, inputStream.textабо getHeaderField('...').

HTTPBuilder це. Дуже проста у використанні.

import groovyx.net.http.HTTPBuilder

def http = new HTTPBuilder('https://google.com')
def html = http.get(path : '/search', query : [q:'waffles'])

Це особливо корисно, якщо вам потрібна обробка помилок і загалом більша функціональність, ніж просто отримання вмісту за допомогою GET.

Я не думаю, що http-builder є модулем Groovy, а скоріше зовнішнім API поверх http-клієнта apache, тому вам потрібно імпортувати класи та завантажувати купу API. Вам краще використовувати Gradle або @Grabзавантажити jar та залежності:

@Grab(group='org.codehaus.groovy.modules.http-builder', module='http-builder', version='0.7.1' )
import groovyx.net.http.*
import static groovyx.net.http.ContentType.*
import static groovyx.net.http.Method.*

Примітка: оскільки сайт CodeHaus не працює, ви можете знайти JAR за адресою ( https://mvnrepository.com/artifact/org.codehaus.groovy.modules.http-builder/http-builder )

import groovyx.net.http.HTTPBuilder;

public class HttpclassgetrRoles {
     static void main(String[] args){
         def baseUrl = new URL('http://test.city.com/api/Cirtxyz/GetUser')

         HttpURLConnection connection = (HttpURLConnection) baseUrl.openConnection();
         connection.addRequestProperty("Accept", "application/json")
         connection.with {
           doOutput = true
           requestMethod = 'GET'
           println content.text
         }

     }
}