Як вказати різні налагодження / випуск вихідних каталогів у файлі QMake .pro

У мене є проект Qt, і я хотів би вивести файли компіляції поза вихідним деревом.

В даний час у мене є така структура каталогів:

/
|_/build
|_/mylib
  |_/include
  |_/src
  |_/resources

Залежно від конфігурації (налагодження / випуск), я хотів би вивести отримані файли всередині каталогу збирання під каталогами build / debug або build / release.

Як я можу це зробити за допомогою файлу .pro?

Коротка відповідь: ви цього не робите .

Вам слід запустити, qmakeза яким слід makeу будь-який каталог збірки, в який ви хочете побудувати. Отже, запустіть його один раз у debugкаталозі, раз у releaseкаталозі.

Ось як очікує, що той, хто будує ваш проект, спрацює, і саме так Qt налаштований на створення, саме так Qt Creator очікує, що ваш .proфайл поводиться: він просто запускається, qmakeа потім - makeу папку збірки для вибраної конфігурації вашої цілі.

Якщо ви хочете створити ці папки та виконати дві (або більше) складання в них, вам знадобиться makefile верхнього рівня, можливо, створений з файлу проекту верхнього рівня через qmake.

Не рідкість мати більше двох конфігурацій збірки, тому ви без потреби призначаєте себе лише розрізняти збірку і реліз; у вас можуть бути збірки з різними рівнями оптимізації тощо . Дихотомія налагодження / випуску найкраще залишити спокійно.

Для мого проекту Qt я використовую цю схему у файлі * .pro:

HEADERS += src/dialogs.h
SOURCES += src/main.cpp \
           src/dialogs.cpp

Release:DESTDIR = release
Release:OBJECTS_DIR = release/.obj
Release:MOC_DIR = release/.moc
Release:RCC_DIR = release/.rcc
Release:UI_DIR = release/.ui

Debug:DESTDIR = debug
Debug:OBJECTS_DIR = debug/.obj
Debug:MOC_DIR = debug/.moc
Debug:RCC_DIR = debug/.rcc
Debug:UI_DIR = debug/.ui

Це просто, але приємно! :)

Щоб змінити каталог для цільового dll / exe, використовуйте це у своєму профі-файлі:

CONFIG(debug, debug|release) {
    DESTDIR = build/debug
} else {
    DESTDIR = build/release
}

Ви також можете змінити каталоги для інших цілей побудови, таких як об'єктні файли та moc-файли (перевірте посилання на змінну qmake для детальної інформації або посилання на функцію qmake CONFIG () ).

У мене більш компактний підхід:

release: DESTDIR = build/release
debug:   DESTDIR = build/debug

OBJECTS_DIR = $$DESTDIR/.obj
MOC_DIR = $$DESTDIR/.moc
RCC_DIR = $$DESTDIR/.qrc
UI_DIR = $$DESTDIR/.ui

Правильний спосіб зробити це наступним чином (дякую команді підтримки QT):

CONFIG(debug, debug|release) {
    DESTDIR = build/debug
}
CONFIG(release, debug|release) {
    DESTDIR = build/release
}

OBJECTS_DIR = $$DESTDIR/.obj
MOC_DIR = $$DESTDIR/.moc
RCC_DIR = $$DESTDIR/.qrc
UI_DIR = $$DESTDIR/.u

Більше інформації тут: https://wiki.qt.io/Qt_project_org_faq#What_does_the_syntax_CONFIG.28debug.2Cdebug.7Crelease.29_mean_.3F_What_does_the_1st_argument_specify_and_s similarly_what_is_the_the_2the

Я використовую той самий метод, який запропонував chalup,

ParentDirectory = <your directory>

RCC_DIR = "$$ParentDirectory\Build\RCCFiles"
UI_DIR = "$$ParentDirectory\Build\UICFiles"
MOC_DIR = "$$ParentDirectory\Build\MOCFiles"
OBJECTS_DIR = "$$ParentDirectory\Build\ObjFiles"

CONFIG(debug, debug|release) { 
    DESTDIR = "$$ParentDirectory\debug"
}
CONFIG(release, debug|release) { 
    DESTDIR = "$$ParentDirectory\release"
}

Старе запитання, але все-таки варте актуальної відповіді. Сьогодні прийнято робити те, що робить Qt Creator, коли використовуються тіньові побудови (вони вмикаються за замовчуванням під час відкриття нового проекту).

Для кожної різної цілі і типу збірки право qmakeзапускається правильними аргументами в іншому каталозі збірки. Тоді це просто будується з простого make.

Отже, уявна структура каталогів може виглядати приблизно так.

/
|_/build-mylib-qt5-mingw32-debug
|_/build-mylib-qt5-mingw32-release
|_/build-mylib-qt4-msvc2010-debug
|_/build-mylib-qt4-msvc2010-release
|_/build-mylib-qt5-arm-debug
|_/build-mylib-qt5-arm-release
|_/mylib
  |_/include
  |_/src
  |_/resources

І найважливішим є те, що a qmakeзапускається в каталозі збірки:

cd build-mylib-XXXX
/path/to/right/qmake ../mylib/mylib.pro CONFIG+=buildtype ...

Тоді він генерує makefiles у каталозі збирання, а потім makeтакож генерує файли під ним. Немає ризику змішування різних версій, доки qmake ніколи не запускається у вихідному каталозі (якщо він є, краще добре очистіть його!).

І коли це зроблено так, .proфайл із прийнятої відповіді ще простіше:

HEADERS += src/dialogs.h
SOURCES += src/main.cpp \
           src/dialogs.cpp

Також корисно мати трохи інше ім'я для виконуваного виводу. Ви не можете використовувати щось на кшталт:

release: Target = ProgramName
debug: Target = ProgramName_d

Чому це не працює, не ясно, але це не так. Але:

CONFIG(debug, debug|release) {
    TARGET = ProgramName
} else {
    TARGET = ProgramName_d
}

Це працює до тих пір, поки CONFIG +=лінія передує їй.

У новій версії Qt Creator також є можливість "профілю" збірки між налагодженням та випуском. Ось як я це виявляю:

CONFIG(debug, debug|release) {  DEFINES += DEBUG_MODE }
else:CONFIG(force_debug_info) { DEFINES += PROFILE_MODE }
else {                          DEFINES += RELEASE_MODE }

1. Знайдіть налагодження / випуск у CONFIG

Отримайте поточний (налагодження | випуск).

specified_configs=$$find(CONFIG, "\b(debug|release)\b")
build_subdir=$$last(specified_configs)

(Може бути декілька, тому зберігайте лише останні, вказані у збірці):

2. Встановіть DESTDIR

Використовувати його має ім'я підкатару збірки

DESTDIR = $$PWD/build/$$build_subdir

Це мій Makefile для різних вихідних каталогів налагодження / випуску. Цей Makefile був успішно протестований на Ubuntu linux. Він повинен безперебійно працювати в Windows за умови правильного встановлення Mingw-w64.

ifeq ($(OS),Windows_NT)
    ObjExt=obj
    mkdir_CMD=mkdir
    rm_CMD=rmdir /S /Q
else
    ObjExt=o
    mkdir_CMD=mkdir -p
    rm_CMD=rm -rf
endif

CC     =gcc
CFLAGS =-Wall -ansi
LD     =gcc

OutRootDir=.
DebugDir  =Debug
ReleaseDir=Release


INSTDIR =./bin
INCLUDE =.

SrcFiles=$(wildcard *.c)
EXEC_main=myapp

OBJ_C_Debug   =$(patsubst %.c,  $(OutRootDir)/$(DebugDir)/%.$(ObjExt),$(SrcFiles))
OBJ_C_Release =$(patsubst %.c,  $(OutRootDir)/$(ReleaseDir)/%.$(ObjExt),$(SrcFiles))

.PHONY: Release Debug cleanDebug cleanRelease clean

# Target specific variables
release: CFLAGS += -O -DNDEBUG
debug:   CFLAGS += -g

################################################
#Callable Targets
release: $(OutRootDir)/$(ReleaseDir)/$(EXEC_main)
debug:   $(OutRootDir)/$(DebugDir)/$(EXEC_main)

cleanDebug:
    -$(rm_CMD) "$(OutRootDir)/$(DebugDir)"
    @echo cleanDebug done

cleanRelease:
    -$(rm_CMD) "$(OutRootDir)/$(ReleaseDir)"
    @echo cleanRelease done

clean: cleanDebug cleanRelease
################################################

# Pattern Rules
# Multiple targets cannot be used with pattern rules [https://www.gnu.org/software/make/manual/html_node/Multiple-Targets.html]
$(OutRootDir)/$(ReleaseDir)/%.$(ObjExt): %.c | $(OutRootDir)/$(ReleaseDir)
    $(CC) -I$(INCLUDE) $(CFLAGS) -c $< -o"$@"

$(OutRootDir)/$(DebugDir)/%.$(ObjExt):   %.c | $(OutRootDir)/$(DebugDir)
    $(CC) -I$(INCLUDE) $(CFLAGS) -c $< -o"$@"

# Create output directory
$(OutRootDir)/$(ReleaseDir) $(OutRootDir)/$(DebugDir) $(INSTDIR):
    -$(mkdir_CMD) $@

# Create the executable
# Multiple targets [https://www.gnu.org/software/make/manual/html_node/Multiple-Targets.html]
$(OutRootDir)/$(ReleaseDir)/$(EXEC_main): $(OBJ_C_Release)
$(OutRootDir)/$(DebugDir)/$(EXEC_main):   $(OBJ_C_Debug)
$(OutRootDir)/$(ReleaseDir)/$(EXEC_main) $(OutRootDir)/$(DebugDir)/$(EXEC_main):
    $(LD) $^ -o$@