Як я можу передати аргументи до пакетного файлу?

Мені потрібно передати ідентифікатор та пароль до пакетного файлу під час запуску, а не жорсткого кодування їх у файл.

Ось як виглядає командний рядок:

test.cmd admin P@55w0rd > test-log.txt

Ще одна корисна порада - використовувати, %*щоб означати «все». Наприклад:

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

Під час запуску:

test-command admin password foo bar

наведений вище пакетний файл буде працювати:

fake-command /u admin /p password admin password foo bar

У мене може бути синтаксис трохи неправильним, але це загальна ідея.

Ось як я це зробив:

@fake-command /u %1 /p %2

Ось як виглядає команда:

test.cmd admin P@55w0rd > test-log.txt

%1Відноситься до першого параметру в %2(а ось хитра частина) відноситься до другого. Ви можете мати до 9 параметрів, переданих таким чином.

Якщо ви хочете інтелектуально обробити відсутні параметри, ви можете зробити щось на кшталт:

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

Доступ до пакетних параметрів може бути простим з% 1,% 2, ...% 9 або також% *,
але лише якщо вміст простий.

Не існує простого способу для складного вмісту, наприклад "&"^&, оскільки неможливо отримати доступ до% 1 без помилки.

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

Лінії розширюються до

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

І кожен рядок виходить з ладу, оскільки один із знаків &знаходиться поза лапок.

Це можна вирішити, прочитавши з тимчасового файлу зауважену версію параметра.

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

Трюк полягає в тому, щоб увімкнути echo onі розширити% 1 після remзаяви (працює також з %2 .. %*).
Таким чином, навіть "&"&можна повторити, не помиляючись, як це зазначається.

Але щоб мати можливість перенаправляти висновок echo on, потрібні дві for-петлі.

Додаткові символи * #використовуються для захисту від вмісту типу /?(показав би допомогу для REM).
Або карета ^ в кінці рядка може працювати як багаторядковий символ, навіть якщо після arem .

Потім читайте параметр rem, виведений з файлу, але уважно.
FOR / F повинен працювати з відстроченим розширенням, інакше вміст "!" буде знищено.
Після видалення зайвих символів вparam1 , ви отримали його.

І використовувати param1безпечним способом, увімкнути затримку розширення.

Так, і просто не забудьте використовувати такі змінні, як %%1при використанні ifта forбанді.

Якщо ви забудете подвійний %, то ви будете замінювати (можливо, нульові) аргументи командного рядка, і ви отримаєте кілька заплутаних повідомлень про помилки.

Не потрібно ускладнювати це. Це просто команда% 1% 2 параметрів, наприклад,

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

"Пауза" відображає те, що зробив пакетний файл, і чекає, коли ви натиснете будь-яку клавішу. Збережіть це як xx.bat у папці Windows.

Щоб використовувати його, введіть, наприклад:

xx c:\f\30\*.* f:\sites\30

Цей пакетний файл піклується про всі необхідні параметри, як, наприклад, копіювання лише тих файлів, які новіші, і т. Д. Я використовував його ще з Windows. Якщо вам подобається бачити імена файлів під час їх копіювання, залиште Qпараметр.

Нещодавно друг розпитував мене про цю тему, тому я думав, що опублікую, як я обробляю аргументи командного рядка в пакетних файлах.

Ця методика має невеликі накладні витрати, як ви побачите, але це робить мої пакетні файли дуже простими для розуміння та швидкою реалізацією. А також підтримка наступних структур:

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

Тек в ньому , мають :init, :parseі :mainфункції.

Приклад використання

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof

@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue

Примітка. Якщо ІФ "%1"==""викличе проблеми, якщо %1він укладений у самі лапки.

У цьому випадку замість цього використовуйте IF [%1]==[]або в NT 4 (SP6) та пізніше IF "%~1"=="".

Давайте так просто.

Ось файл .cmd.

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

Ось 3 виклики з командного рядка.

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

Це циклі за пакетними параметрами (% *) або вони цитуються, або ні, потім повторюється кожен параметр.

Я написав простий скрипт read_params, який можна викликати як функцію (або зовнішню .bat) і помістять усі змінні в поточне середовище. Він не змінює вихідні параметри, оскільки функція виконуєтьсяcall редагується з копією вихідних параметрів.

Наприклад, дано таку команду:

myscript.bat some -random=43 extra -greeting="hello world" fluff

myscript.bat зможе використовувати змінні після виклику функції:

call :read_params %*

echo %random%
echo %greeting%

Ось функція:

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

Обмеження

• Неможливо завантажити аргументи без значень, таких як -force. Ви можете використовувати, -force=trueале я не можу придумати спосіб дозволити порожні значення, не знаючи список параметрів достроково, який не буде мати значення.

Журнал змін

• 18.02.2016
  • Більше не вимагає затримки розширення
  • Тепер працює з іншими аргументами командного рядка, шукаючи -параметри.

У пакетному файлі

set argument1=%1
set argument2=%2
echo %argument1%
echo %argument2%

% 1 і% 2 повертають значення першого та другого аргументів відповідно.

І в командному рядку передайте arguemt

Directory> batchFileName admin P@55w0rd 

Вихід буде

admin
P@55w0rd

Щоб звернутися до набірної змінної в командному рядку, вам потрібно використовувати %a%так, наприклад:

set a=100 
echo %a%  
rem output = 100 

Примітка. Це працює для Windows 7 pro.

Натхненний відповіддю іншим @Jon, я створив більш загальний алгоритм вилучення названих параметрів, необов'язкових значень та комутаторів.

Скажімо, що ми хочемо реалізувати утиліту foobar. Це вимагає початкової команди. Він має необов'язковий параметр, --fooякий приймає необов'язкове значення (що, звичайно, не може бути іншим параметром); якщо значення відсутнє, воно за замовчуванням default. Він також має необов'язковий параметр, --barякий приймає необхідне значення. Нарешті, він може приймати прапор --bazбез дозволеного значення. О, і ці параметри можуть прийти в будь-якому порядку.

Іншими словами, це виглядає приблизно так:

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

Ось рішення:

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

• Використовуйте SETLOCALтак, щоб змінні не виходили в середовище виклику.
• Не забувайте ініціалізувати змінні SET FOO=тощо, якщо хтось їх визначив у середовищі виклику.
• Використовуйте %~1для видалення лапок.
• Використовуйте, IF "%ARG%" == ""а не IF [%ARG%] == []тому, що [і] не грають волі на все зі значеннями , що закінчуються в просторі.
• Навіть якщо ви SHIFTзнаходитесь у IFблоці, поточні аргументи, такі як %~1не оновлюються, оскільки вони визначаються при IFсинтаксичному аналізі. Ви можете використовувати %~1і %~2всередині IFблоку, але це буде заплутано, оскільки у вас є SHIFT. Ви можете поставити SHIFTкінець блоку для наочності, але це також може загубитися та / або заплутати людей. Тож "захоплення" %~1та %~1поза блоком здається найкращим.
• Ви не хочете використовувати параметр замість необов'язкового значення іншого параметра, тому вам доведеться перевірити IF NOT "%ARG:~0,2%" == "--".
• Будьте обережні лише SHIFTпід час використання один з параметрів.
• Дублікат коду SET FOO=%DEFAULT_FOO%шкодує, але альтернативою було б додати IF "%FOO%" == "" SET FOO=%DEFAULT_FOO%зовнішній IF NOT "%ARG%" == ""блок. Однак , оскільки це все ще всередині IF "%PARAM%" == "--foo"блоку, то %FOO%вартість була б оцінена і встановити , перш ніж ви коли - небудь увійшов в блок, так що ви ніколи не виявити , що і--foo параметр присутній , а також про те , що %FOO%значення НЕ було.
• Зауважте, що ECHO Missing bar value. 1>&2надсилає повідомлення про помилку на stderr.
• Хочете порожній рядок у пакетному файлі Windows? Ви повинні використовувати ECHO:або одну з варіацій.

Створіть новий пакетний файл (приклад: openclass.bat) і запишіть цей рядок у файл:

java %~n1

Потім помістіть пакетний файл, скажімо, в папку system32, перейдіть до файлу класу Java, клацніть правою кнопкою миші, Властивості, Відкрийте з ..., потім знайдіть свій пакетний файл, виберіть його і ось це ...

Це працює для мене.

PS: Я не можу знайти спосіб закрити вікно cmd, коли закриваю клас Java. Зараз...

Просте рішення (навіть якщо питання старе)

Test1.bat

echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause

CallTest1.bat

call "C:\Temp\Test1.bat" pass123

вихід

YourLocalPath>call "C:\Temp\test.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .

Там, де YourLocalPath - поточний шлях до каталогу.

Щоб просто не зберігати речі, зберігайте параметр команди у змінній та використовуйте змінну для порівняння.

Писати його не просто, а просто прості в обслуговуванні, тому якщо пізніше хтось інший або ви прочитаєте свій сценарій через тривалий проміжок часу, це буде легко зрозуміти і підтримувати.

Щоб написати код вбудований: див. Інші відповіді.

Для використання циклу отримуйте всі аргументи та в чистому пакеті:

Obs: для використання без:?*&<>

@echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && (
     call set "_arg_[!_cnt!]=!_arg_!" && for /l %%l in (!_cnt! 1 !_cnt!
     )do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof 

Ваш код готовий зробити щось із номером аргументу там, де це потрібно, наприклад ...

 @echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"
 )

 fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt