Як повернути результат від функції VBA

Як повернути результат від функції?

Наприклад:

Public Function test() As Integer
    return 1
End Function

Це дає помилку компіляції.

Як змусити цю функцію повернути ціле число?

Для необ'єктних типів повернення потрібно призначити значення імені вашої функції, наприклад:

Public Function test() As Integer
    test = 1
End Function

Приклад використання:

Dim i As Integer
i = test()

Якщо функція повертає тип об'єкта, вам потрібно використовувати таке Setключове слово:

Public Function testRange() As Range
    Set testRange = Range("A1")
End Function

Приклад використання:

Dim r As Range
Set r = testRange()

Зауважте, що призначення присвоєного значення імені функції не припиняє виконання вашої функції. Якщо ви хочете вийти з функції, то вам потрібно прямо сказати Exit Function. Наприклад:

Function test(ByVal justReturnOne As Boolean) As Integer
    If justReturnOne Then
        test = 1
        Exit Function
    End If
    'more code...
    test = 2
End Function

Документація: http://msdn.microsoft.com/en-us/library/office/gg264233%28v=office.14%29.aspx

Функції VBA трактують саме ім’я функції як своєрідну змінну. Отже, замість використання returnзаяви, ви просто скажете:

test = 1

Зауважте, що це не виходить з функції. Будь-який код після цього твердження також буде виконаний. Таким чином, у вас може бути безліч операторів присвоєння, яким присвоюються різні значення test, і яке б значення не було, коли ви досягнете кінця функції, значення буде поверненим.

Просто встановлення значення, що повертається на ім’я функції, все ще не зовсім те саме, що returnоператор Java (або інший) , оскільки в java returnвиходить з функції, як це:

public int test(int x) {
    if (x == 1) {
        return 1; // exits immediately
    }

    // still here? return 0 as default.
    return 0;
}

У VB точний еквівалент займає два рядки, якщо ви не встановлюєте значення повернення в кінці функції . Отже, у VB точний слід буде виглядати так:

Public Function test(ByVal x As Integer) As Integer
    If x = 1 Then
        test = 1 ' does not exit immediately. You must manually terminate...
        Exit Function ' to exit
    End If

    ' Still here? return 0 as default.
    test = 0
    ' no need for an Exit Function because we're about to exit anyway.
End Function 

Оскільки це так, також приємно знати, що ви можете використовувати змінну return, як і будь-яку іншу змінну в методі. Подобається це:

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test <> 1 Then ' Test the currently set return value
        test = 0 ' Reset the return value to a *new* value
    End If

End Function 

Або крайній приклад того, як працює змінна повернення (але не обов'язково - хороший приклад того, як ви насправді повинні кодувати) - той, який буде підтримувати вас вночі:

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test > 0 Then

        ' RECURSIVE CALL...WITH THE RETURN VALUE AS AN ARGUMENT,
        ' AND THE RESULT RESETTING THE RETURN VALUE.
        test = test(test - 1)

    End If

End Function

Наведений нижче код зберігає повернене значення у змінну, retValа потім MsgBoxможе бути використаний для відображення значення:

Dim retVal As Integer
retVal = test()
Msgbox retVal