Назва таблиці як змінної

Я намагаюся виконати цей запит:

declare @tablename varchar(50)
set @tablename = 'test'
select * from @tablename

Це спричиняє таку помилку:

1087 р., Рівень 16, стан 1, рядок 5

Потрібно оголосити табличну змінною "@tablename".

Який правильний спосіб динамічно заповнювати назву таблиці?

Для статичних запитів, таких як ваш запитання, назви таблиць та назви стовпців повинні бути статичними.

Для динамічних запитів ви повинні динамічно генерувати повний SQL, і використовувати sp_executesql для його виконання.

Ось приклад сценарію, який використовується для порівняння даних між одними і тими ж таблицями різних баз даних:

статичний запит:

SELECT * FROM [DB_ONE].[dbo].[ACTY]
EXCEPT
SELECT * FROM [DB_TWO].[dbo].[ACTY]

оскільки я хочу легко змінити ім'я, tableі schemaя створив цей динамічний запит:

declare @schema varchar(50)
declare @table varchar(50)
declare @query nvarchar(500)

set @schema = 'dbo'
set @table = 'ACTY'

set @query = 'SELECT * FROM [DB_ONE].['+ @schema +'].[' + @table + '] EXCEPT SELECT * FROM [DB_TWO].['+ @schema +'].[' + @table + ']'

EXEC sp_executesql @query

Оскільки в динамічних запитах є багато деталей, які потрібно враховувати, і їх важко дотримуватися, рекомендую прочитати: Прокляття та благословення динамічного SQL

Змініть останнє твердження на це:

EXEC('SELECT * FROM ' + @tablename)

Ось так я виконую свою процедуру, що зберігається. Перший блок оголосить змінну та встановить ім'я таблиці, виходячи з назви поточного року та місяця, у цьому випадку TEST_2012OCTOBER. Потім я перевіряю, чи він уже існує в БД, і видаляю, якщо він є. Потім наступний блок буде використовувати SELECT INTO Statement для створення таблиці та заповнення її записами з іншої таблиці з параметрами.

--DECLARE TABLE NAME VARIABLE DYNAMICALLY
DECLARE @table_name varchar(max)
SET @table_name = 
    (SELECT 'TEST_'
            + DATENAME(YEAR,GETDATE())
            + UPPER(DATENAME(MONTH,GETDATE())) )

--DROP THE TABLE IF IT ALREADY EXISTS
IF EXISTS(SELECT name 
          FROM sysobjects 
          WHERE name = @table_name AND xtype = 'U')

BEGIN
    EXEC('drop table ' +  @table_name)
END

--CREATES TABLE FROM DYNAMIC VARIABLE AND INSERTS ROWS FROM ANOTHER TABLE
EXEC('SELECT * INTO ' + @table_name + ' FROM dbo.MASTER WHERE STATUS_CD = ''A''')

Трохи запізнюйтесь на відповідь, але має допомогти хтось інший:

CREATE PROCEDURE [dbo].[GetByName]
    @TableName NVARCHAR(100)
    AS
BEGIN
    -- SET NOCOUNT ON added to prevent extra result sets from
    -- interfering with SELECT statements.
    SET NOCOUNT ON;
    DECLARE @sSQL nvarchar(500);

    SELECT @sSQL = N'SELECT * FROM' + QUOTENAME(@TableName);

    EXEC sp_executesql @sSQL



END

Ви не можете використовувати ім’я таблиці для змінної, вам доведеться це зробити замість цього:

DECLARE @sqlCommand varchar(1000)
SET @sqlCommand = 'SELECT * from yourtable'
EXEC (@sqlCommand)

Вам потрібно буде генерувати sql динамічно:

declare @tablename varchar(50) 

set @tablename = 'test' 

declare @sql varchar(500)

set @sql = 'select * from ' + @tablename 

exec (@sql)

Використовуйте sp_executesqlдля виконання будь-якого SQL, наприклад

DECLARE @tbl    sysname,
        @sql    nvarchar(4000),
        @params nvarchar(4000),
        @count  int

DECLARE tblcur CURSOR STATIC LOCAL FOR
   SELECT object_name(id) FROM syscolumns WHERE name = 'LastUpdated'
   ORDER  BY 1
OPEN tblcur

WHILE 1 = 1
BEGIN
   FETCH tblcur INTO @tbl
   IF @@fetch_status <> 0
      BREAK

   SELECT @sql =
   N' SELECT @cnt = COUNT(*) FROM dbo.' + quotename(@tbl) +
   N' WHERE LastUpdated BETWEEN @fromdate AND ' +
   N'                           coalesce(@todate, ''99991231'')'
   SELECT @params = N'@fromdate datetime, ' +
                    N'@todate   datetime = NULL, ' +
                    N'@cnt      int      OUTPUT'
   EXEC sp_executesql @sql, @params, '20060101', @cnt = @count OUTPUT

   PRINT @tbl + ': ' + convert(varchar(10), @count) + ' modified rows.'
END

DEALLOCATE tblcur

Також ви можете використовувати це ...

DECLARE @SeqID varchar(150);
DECLARE @TableName varchar(150);  
SET @TableName = (Select TableName from Table);
SET @SeqID = 'SELECT NEXT VALUE FOR '+ @TableName + '_Data'
exec (@SeqID)

Declare  @tablename varchar(50) 
set @tablename = 'Your table Name' 
EXEC('select * from ' + @tablename)

вам потрібно використовувати динамічний SQL сервер SQL Server

DECLARE @table     NVARCHAR(128),
        @sql       NVARCHAR(MAX);

SET @table = N'tableName';

SET @sql = N'SELECT * FROM ' + @table;

Використовуйте EXEC для виконання будь-якого SQL

EXEC (@sql)

Використовуйте EXEC sp_executesql для виконання будь-якого SQL

EXEC sp_executesql @sql;

Використовуйте EXECUTE sp_executesql для виконання будь-якого SQL

EXECUTE sp_executesql @sql

Declare @fs_e int, @C_Tables CURSOR, @Table varchar(50)

SET @C_Tables = CURSOR FOR
        select name from sysobjects where OBJECTPROPERTY(id, N'IsUserTable') = 1 AND name like 'TR_%'
OPEN @C_Tables
FETCH @C_Tables INTO @Table
    SELECT @fs_e = sdec.fetch_Status FROM sys.dm_exec_cursors(0) as sdec where sdec.name = '@C_Tables'

WHILE ( @fs_e <> -1)
    BEGIN
        exec('Select * from '+ @Table)
        FETCH @C_Tables INTO @Table
        SELECT @fs_e = sdec.fetch_Status FROM sys.dm_exec_cursors(0) as sdec where sdec.name = '@C_Tables'
    END