Я намагаюся з'ясувати спосіб перевірки наявності значення в масиві без ітерації через масив.

Я читаю файл для параметра. У мене довгий список параметрів, з якими я не хочу мати справу. Я розмістив ці небажані параметри в масиві @badparams.

Я хочу прочитати новий параметр, і якщо його немає в @badparams, обробіть його. Якщо він існує @badparams, перейдіть до наступного читання.

Просто перетворіть масив у хеш:

my %params = map { $_ => 1 } @badparams;

if(exists($params{$someparam})) { ... }

Ви також можете додати до списку більше (унікальних) параметрів:

$params{$newparam} = 1;

А пізніше поверніть список (унікальних) парамів:

@badparams = keys %params;

Найкраще загальне призначення - особливо короткі масиви (1000 предметів або менше) та кодери, які не знають, які оптимізації найкраще відповідають їх потребам.

# $value can be any regex. be safe
if ( grep( /^$value$/, @array ) ) {
  print "found it";
}

Згадано, що grep проходить через усі значення, навіть якщо перше значення в масиві відповідає. Це правда, однак греп все ще надзвичайно швидкий у більшості випадків . Якщо ви говорите про короткі масиви (менше 1000 елементів), то в більшості випадків більшість алгоритмів будуть досить швидкими. Якщо ви говорите про дуже довгі масиви (1 000 000 елементів), grep прийнятно швидкий, незалежно від того, елемент є першим чи середнім чи останнім у масиві.

Випадки оптимізації для довших масивів:

Якщо ваш масив відсортований , використовуйте "двійковий пошук".

Якщо один і той же масив багато разів шукають , скопіюйте його спочатку в хеш, а потім перевірте хеш. Якщо пам'ять викликає занепокоєння, то перемістіть кожен елемент з масиву в хеш. Більш ефективна пам'ять, але знищує вихідний масив.

Якщо одні і ті ж значення повторно шукаються в масиві, лінь будуйте кеш. (як кожен елемент пошуку, спочатку перевірте, чи зберігався результат пошуку в збереженому хеші. Якщо результат пошуку не знайдено в хеші, тоді шукайте масив і вкладайте результат у збережений хеш, щоб наступного разу ми знайдіть його в хеші та пропустіть пошук).

Зауважте: ці оптимізації будуть швидшими лише при роботі з довгими масивами. Не надмірно оптимізуйте.

Ви можете використовувати функцію smartmatch в Perl 5.10 таким чином:

Для буквального пошуку значень, які виконуються нижче, буде зроблено трюк.

if ( "value" ~~ @array ) 

Для скалярного пошуку робота нижче буде працювати, як вище.

if ($val ~~ @array)

Для вбудованого масиву, який працює внизу, буде працювати як вище.

if ( $var ~~ ['bar', 'value', 'foo'] ) 

У Perl 5.18 smartmatch позначений як експериментальний, тому потрібно вимкнути попередження, увімкнувши експериментальну прагму, додавши нижче до свого сценарію / модуля:

use experimental 'smartmatch';

Якщо ви хочете уникнути використання smartmatch - тоді, як сказав Аарон, використовуйте:

if ( grep( /^$value$/, @array ) ) {
  #TODO:
}

Це повідомлення в блозі обговорюються найкращі відповіді на це питання.

Якщо короткий підсумок, якщо ви можете встановити модулі CPAN, найбільш читабельними рішеннями є:

any(@ingredients) eq 'flour';

або

@ingredients->contains('flour');

Однак більш поширеною фразою є:

any { $_ eq 'flour' } @ingredients

Але, будь ласка, не використовуйте цю first()функцію! Це зовсім не виражає наміру вашого коду. Не використовуйте ~~оператора "Smart match": він порушений. І не використовуйте grep()ні рішення з хешем: вони повторюються через увесь список.

any() припиниться, як тільки знайде вашу цінність.

Перегляньте повідомлення в блозі для отримання більш детальної інформації.

Спосіб 1: grep (може бути обережним, тоді як значення, як очікується, буде регулярним вираженням).

Намагайтеся уникати використання grep, якщо дивитесь на ресурси.

if ( grep( /^$value$/, @badparams ) ) {
  print "found";
}

Спосіб 2: Лінійний пошук

for (@badparams) {
    if ($_ eq $value) {
       print "found";
       last;
    }
}

Спосіб 3: Використовуйте хеш

my %hash = map {$_ => 1} @badparams;
print "found" if (exists $hash{$value});

Спосіб 4: smartmatch

(додано в Perl 5.10, позначено експериментально в Perl 5.18).

use experimental 'smartmatch';  # for perl 5.18
print "found" if ($value ~~ @badparams);

Спосіб 5: Використовуйте модуль List::MoreUtils

use List::MoreUtils qw(any);
@badparams = (1,2,3);
$value = 1;
print "found" if any {$_ == $value} @badparams;

Базовий показник @ eakssjo порушений - вимірює створення хешей у циклі проти створення регулярних виразів у циклі. Виправлена ​​версія (плюс я додав List::Util::firstі List::MoreUtils::any):

use List::Util qw(first);
use List::MoreUtils qw(any);
use Benchmark;

my @list = ( 1..10_000 );
my $hit = 5_000;
my $hit_regex = qr/^$hit$/; # precompute regex
my %params;
$params{$_} = 1 for @list;  # precompute hash
timethese(
    100_000, {
        'any' => sub {
            die unless ( any { $hit_regex } @list );
        },
        'first' => sub {
            die unless ( first { $hit_regex } @list );
        },
        'grep' => sub {
            die unless ( grep { $hit_regex } @list );
        },
        'hash' => sub {
            die unless ( $params{$hit} );
        },
    });

І результат (це на 100_000 ітерацій, в десять разів більше, ніж у відповіді @ eakssjo):

Benchmark: timing 100000 iterations of any, first, grep, hash...
       any:  0 wallclock secs ( 0.67 usr +  0.00 sys =  0.67 CPU) @ 149253.73/s (n=100000)
     first:  1 wallclock secs ( 0.63 usr +  0.01 sys =  0.64 CPU) @ 156250.00/s (n=100000)
      grep: 42 wallclock secs (41.95 usr +  0.08 sys = 42.03 CPU) @ 2379.25/s (n=100000)
      hash:  0 wallclock secs ( 0.01 usr +  0.00 sys =  0.01 CPU) @ 10000000.00/s (n=100000)
            (warning: too few iterations for a reliable count)

Незважаючи на те, що це зручно у використанні, здається, що рішення конвертувати в хеш коштує досить багато продуктивності, що було проблемою для мене.

#!/usr/bin/perl
use Benchmark;
my @list;
for (1..10_000) {
    push @list, $_;
}

timethese(10000, {
  'grep'    => sub {
            if ( grep(/^5000$/o, @list) ) {
                # code
            }
        },
  'hash'    => sub {
            my %params = map { $_ => 1 } @list;
            if ( exists($params{5000}) ) {
                # code
            }
        },
});

Вихід контрольного тесту:

Benchmark: timing 10000 iterations of grep, hash...
          grep:  8 wallclock secs ( 7.95 usr +  0.00 sys =  7.95 CPU) @ 1257.86/s (n=10000)
          hash: 50 wallclock secs (49.68 usr +  0.01 sys = 49.69 CPU) @ 201.25/s (n=10000)

@files - це наявний масив

my @new_values =  grep(/^2[\d].[\d][A-za-z]?/,@files);

print join("\n", @new_values);

print "\n";

/^2 evidence\d снимки. evidence\d обвинуваченоA-za-z снимки?/ = vaues, починаючи з 2, ви можете ввести будь-який регулярний вираз

Ви звичайно хочете хеш-сюди. Помістіть у хеші погані параметри як ключі, а потім вирішіть, чи існує певний параметр у хеші.

our %bad_params = map { $_ => 1 } qw(badparam1 badparam2 badparam3)

if ($bad_params{$new_param}) {
  print "That is a bad parameter\n";
}

Якщо вам дійсно цікаво робити це з масивом, подивіться на List::UtilабоList::MoreUtils

Є два способи зробити це. Ви можете використовувати значення кидання в хеш для таблиці пошуку, як це запропоновано в інших публікаціях. (Я додам ще одну ідіому.)

my %bad_param_lookup;
@bad_param_lookup{ @bad_params } = ( 1 ) x @bad_params;

Але якщо це дані здебільшого символьних слів і не надто багато мета, ви можете скинути їх на чергування регулярних виразів:

use English qw<$LIST_SEPARATOR>;

my $regex_str = do { 
    local $LIST_SEPARATOR = '|';
    "(?:@bad_params)";
 };

 # $front_delim and $back_delim being any characters that come before and after. 
 my $regex = qr/$front_delim$regex_str$back_delim/;

Це рішення повинно бути налаштоване на типи "поганих значень", які ви шукаєте. Знову ж таки, це може бути абсолютно невідповідно для певних типів струн, тому застереження емптор .

my @badparams = (1,2,5,7,'a','zzz');

my $badparams = join('|',@badparams);   # '|' or any other character not present in params

foreach my $par (4,5,6,7,'a','z','zzz')
{
    if ($badparams =~ /\b$par\b/)
    {
        print "$par is present\n";
    }
    else
    {
        print "$par is not present\n";
    }
}

Ви можете перевірити сталість провідних просторів