Заміна рядка XSLT

Я насправді не знаю XSL, але мені потрібно виправити цей код, я зменшив його, щоб спростити.
Я отримую цю помилку

Недійсна функція XSLT / XPath

на цій лінії

<xsl:variable name="text" select="replace($text,'a','b')"/>

Це XSL

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:inm="http://www.inmagic.com/webpublisher/query" version="1.0">
    <xsl:output method="text" encoding="UTF-8" />

    <xsl:preserve-space elements="*" />
    <xsl:template match="text()" />

    <xsl:template match="mos">
        <xsl:apply-templates />

        <xsl:for-each select="mosObj">
          'Notes or subject' 
           <xsl:call-template
                name="rem-html">
                <xsl:with-param name="text" select="SBS_ABSTRACT" />
            </xsl:call-template>
        </xsl:for-each>
    </xsl:template>

    <xsl:template name="rem-html">
        <xsl:param name="text" />
        <xsl:variable name="text" select="replace($text, 'a', 'b')" />
    </xsl:template>
</xsl:stylesheet>

Хто-небудь може сказати мені, що з цим не так?

replace недоступний для XSLT 1.0.

Codesling має шаблон для заміни рядків, який ви можете використовувати як заміну функції:

<xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
        <xsl:when test="$text = '' or $replace = ''or not($replace)" >
            <!-- Prevent this routine from hanging -->
            <xsl:value-of select="$text" />
        </xsl:when>
        <xsl:when test="contains($text, $replace)">
            <xsl:value-of select="substring-before($text,$replace)" />
            <xsl:value-of select="$by" />
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="substring-after($text,$replace)" />
                <xsl:with-param name="replace" select="$replace" />
                <xsl:with-param name="by" select="$by" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

викликається як:

<xsl:variable name="newtext">
    <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="$text" />
        <xsl:with-param name="replace" select="a" />
        <xsl:with-param name="by" select="b" />
    </xsl:call-template>
</xsl:variable>

З іншого боку, якщо вам буквально потрібно лише замінити один символ іншим, ви можете зателефонувати, translateякий має подібний підпис. Щось на зразок цього має працювати нормально:

<xsl:variable name="newtext" select="translate($text,'a','b')"/>

Крім того, зауважте, у цьому прикладі я змінив ім'я змінної на "newtext", у XSLT змінні незмінні, тому ви не можете зробити еквівалент, $foo = $fooяк у вашому вихідному коді.

Ось функція XSLT, яка працюватиме подібно до функції String.Replace () у C #.

Цей шаблон має 3 параметри, як показано нижче

text : - ваш основний рядок

replace : - рядок, який ви хочете замінити

by : - рядок, який відповість новим рядком

Нижче наведено шаблон

<xsl:template name="string-replace-all">
  <xsl:param name="text" />
  <xsl:param name="replace" />
  <xsl:param name="by" />
  <xsl:choose>
    <xsl:when test="contains($text, $replace)">
      <xsl:value-of select="substring-before($text,$replace)" />
      <xsl:value-of select="$by" />
      <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="substring-after($text,$replace)" />
        <xsl:with-param name="replace" select="$replace" />
        <xsl:with-param name="by" select="$by" />
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$text" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Нижче на зразку показано, як це назвати

<xsl:variable name="myVariable ">
  <xsl:call-template name="string-replace-all">
    <xsl:with-param name="text" select="'This is a {old} text'" />
    <xsl:with-param name="replace" select="'{old}'" />
    <xsl:with-param name="by" select="'New'" />
  </xsl:call-template>
</xsl:variable>

Ви також можете ознайомитися з наведеною нижче URL-адресою для отримання детальної інформації.

Примітка: Якщо ви хочете використовувати вже згаданий алгоритм для випадків, коли вам потрібно замінити величезну кількість екземплярів у вихідному рядку (наприклад, нові рядки в довгому тексті), існує велика ймовірність, що ви опинитеся StackOverflowExceptionвнаслідок рекурсивного дзвінок.

Я усунув цю проблему завдяки Xalan «s (не дивився , як зробити це в Saxon ) вбудований типу Java вкладення:

<xsl:stylesheet version="1.0" exclude-result-prefixes="xalan str"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xalan="http://xml.apache.org/xalan"
                xmlns:str="xalan://java.lang.String"
        >
...
<xsl:value-of select="str:replaceAll(
    str:new(text()),
    $search_string,
    $replace_string)"/>
...
</xsl:stylesheet>

Ви можете використовувати наступний код, коли ваш процесор працює на .NET або використовує MSXML (на відміну від процесорів на базі Java або інших власних процесорів). Він використовує msxsl:script.

Не забудьте додати простір імен xmlns:msxsl="urn:schemas-microsoft-com:xslt"до свого кореня xsl:stylesheetабо xsl:transformелемента.

Крім того, прив’яжіть outletдо будь-якого простору імен, який вам подобається, наприклад xmlns:outlet = "http://my.functions".

<msxsl:script implements-prefix="outlet" language="javascript">
function replace_str(str_text,str_replace,str_by)
{
     return str_text.replace(str_replace,str_by);
}
</msxsl:script>


<xsl:variable name="newtext" select="outlet:replace_str(string(@oldstring),'me','you')" />

Я продовжую бити цю відповідь. Але жоден з них не перелічує найпростішого рішення для xsltproc (і, мабуть, більшості процесорів XSLT 1.0):

1. Додайте ім'я рядків exslt до таблиці стилів, тобто:

<xsl:stylesheet
  version="1.0"
  xmlns:str="http://exslt.org/strings"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

2. Тоді використовуйте його як:

<xsl:value-of select="str:replace(., ' ', '')"/>

Рутина досить гарна, однак це спричиняє зависання мого додатка, тому мені потрібно було додати справу:

  <xsl:when test="$text = '' or $replace = ''or not($replace)" >
    <xsl:value-of select="$text" />
    <!-- Prevent thsi routine from hanging -->
  </xsl:when>

перед викликом функції рекурсивно.

Я отримав відповідь звідси: Коли тест висить у нескінченній петлі

Дякую!