Як перевірити, чи запущена служба через пакетний файл, і запустити її, якщо вона не запущена?

Я хочу написати командний файл, який виконує такі операції:

• Перевірте, чи працює служба
  • Якщо він запущений, закрийте пакет
  • Якщо він не запущений, запустіть службу

Зразки коду, які я досі загуглив, виявилися непрацюючими, тому я вирішив їх не розміщувати.

Запуск послуги виконується:

net start "SERVICENAME"

1. Як я можу перевірити, чи запущена послуга, і як зробити оператор if у файлі команд?
2. Я трохи розгублений. Який аргумент я маю передати для початку мережі? Назва послуги чи її відображувана назва?

Щоб перевірити стан послуги, скористайтеся sc query <SERVICE_NAME>. Якщо блоки в командних файлах, перевірте документацію .

Наступний код перевірить стан служби MyServiceNameта запустить її, якщо вона не запущена (блок if буде виконаний, якщо служба не запущена):

for /F "tokens=3 delims=: " %%H in ('sc query "MyServiceName" ^| findstr "        STATE"') do (
  if /I "%%H" NEQ "RUNNING" (
   REM Put your code you want to execute here
   REM For example, the following line
   net start "MyServiceName"
  )
)

Пояснення того, що він робить:

1. Запитує властивості служби.
2. Шукає рядок, що містить текст "STATE"
3. Токенізує цей рядок і витягує 3-й маркер, який містить стан служби.
4. Тестує результуючий стан щодо рядка "RUNNING"

Що стосується Вашого другого питання, аргументом, який Ви хочете передати, net startє ім'я послуги, а не відображуване ім'я.

Для перемикання послуги використовуйте наступне;

NET START "Координатор розподілених транзакцій" || NET STOP "Координатор розподілених транзакцій"

Ви можете скористатися наступною командою, щоб побачити, запущена служба чи ні:

sc query [ServiceName] | findstr /i "STATE"

Коли я запускаю його для свого антивіруса NOD32, я отримую:

STATE                       : 4 RUNNING

Якби це було зупинено, я б отримав:

STATE                       : 1 STOPPED

Ви можете використовувати це у змінній, щоб потім визначити, чи використовуєте ви NET START чи ні.

Назва послуги повинна бути назвою послуги, а не відображуваною назвою.

Це має зробити це:

FOR %%a IN (%Svcs%) DO (SC query %%a | FIND /i "RUNNING"
IF ERRORLEVEL 1 SC start %%a)

Мовна незалежна версія.

@Echo Off
Set ServiceName=Jenkins


SC queryex "%ServiceName%"|Find "STATE"|Find /v "RUNNING">Nul&&(
    echo %ServiceName% not running 
    echo Start %ServiceName%

    Net start "%ServiceName%">nul||(
        Echo "%ServiceName%" wont start 
        exit /b 1
    )
    echo "%ServiceName%" started
    exit /b 0
)||(
    echo "%ServiceName%" working
    exit /b 0
)

Я просто знайшов цю тему і хотів додати до обговорення, якщо особа не хоче використовувати пакетний файл для перезапуску служб. У Windows є можливість, якщо ви перейдете до Служб, властивостей служби, а потім відновлення. Тут ви можете встановити параметри для послуги. Хочете перезапустити службу, якщо вона припиняється. Крім того, ви можете навіть повторно спробувати зробити щось інше, як при перезавантаженні комп’ютера.

Використовуйте Windows en Español, el código debe quedar asi (при використанні Windows іспанською мовою код):

for /F "tokens=3 delims=: " %%H in ('sc query MYSERVICE ^| findstr "        ESTADO"') do (
  if /I "%%H" NEQ "RUNNING" (
    REM Put your code you want to execute here
    REM For example, the following line
    net start MYSERVICE
  )
)

Reemplazar MYSERVICE con el nombre del servicio que se desea procesar. Puedes ver el nombre del servicio viendo las propiedades del servicio. (Замініть MYSERVICE на ім'я послуги, що підлягає обробці. Ви можете побачити назву служби у властивостях служби.)

@echo off

color 1F


@sc query >%COMPUTERNAME%_START.TXT


find /I "AcPrfMgrSvc" %COMPUTERNAME%_START.TXT >nul

IF ERRORLEVEL 0 EXIT

IF ERRORLEVEL 1 NET START "AcPrfMgrSvc"

Для Windows Server 2012 нижче це те, що мені вдалося. Замінити лише "SERVICENAME" на фактичну назву послуги:

@ECHO OFF
SET SvcName=SERVICENAME

SC QUERYEX "%SvcName%" | FIND "STATE" | FIND /v "RUNNING" > NUL && (
    ECHO %SvcName% is not running 
    ECHO START %SvcName%

    NET START "%SvcName%" > NUL || (
        ECHO "%SvcName%" wont start 
        EXIT /B 1
    )
    ECHO "%SvcName%" is started
    EXIT /B 0
) || (
    ECHO "%SvcName%" is running
    EXIT /B 0
)

Я також хотів надіслати електронний лист, якщо послугу було запущено таким чином, тому додав трохи до коду @Ic, просто думав, що розміщу його на випадок, якщо це комусь допоможе. Я використовував SendMail, але є й інші варіанти командного рядка Як надіслати просте повідомлення електронної пошти з командного файлу Windows?

set service=MyServiceName

for /F "tokens=3 delims=: " %%H in ('sc query %service% ^| findstr "        STATE"') do (
  if /I "%%H" NEQ "RUNNING" (

    net start %service%

    for /F "tokens=3 delims=: " %%H in ('sc query %service% ^| findstr "        STATE"') do (
      if /I "%%H" EQ "RUNNING" (
        SendMail /smtpserver localhost /to me@mydomain.com /from watchdog@mydomain.com /subject Service Autostart Notification /body Autostart on service %service% succeded.
      ) else (
        SendMail /smtpserver localhost /to me@mydomain.com /from watchdog@mydomain.com /subject Service Autostart Notification /body Autostart on service %service% failed.
      )
    )

  )
)

Запуск служби за допомогою сценарію Powershell. Ви можете пов’язати це з планувальником завдань і запускати його з інтервалом або за потреби. Створіть це як файл PS1, тобто файл із розширенням PS1, а потім нехай цей файл запускається із планувальника завдань.

Для початку зупинки служби

у планувальнику завдань, якщо ви використовуєте його на сервері, використовуйте це в аргументах

-noprofile -executionpolicy bypass -file "C: \ Сценарії перезапуску служби \ StopService.PS1"

перевірити, запустивши те ж саме на cmd, якщо це працює, це також повинно працювати на планувальнику завдань

$Password = "Enter_Your_Password"
$UserAccount = "Enter_Your_AccountInfor"
$MachineName = "Enter_Your_Machine_Name"
$ServiceList = @("test.SocketService","test.WcfServices","testDesktopService","testService")
$PasswordSecure = $Password | ConvertTo-SecureString -AsPlainText -Force
$Credential = new-object -typename System.Management.Automation.PSCredential -argumentlist $UserAccount, $PasswordSecure 

$LogStartTime = Get-Date -Format "MM-dd-yyyy hh:mm:ss tt"
$FileDateTimeStamp = Get-Date -Format "MM-dd-yyyy_hh"
$LogFileName = "C:\Users\krakhil\Desktop\Powershell\Logs\StartService_$FileDateTimeStamp.txt" 


#code to start the service

"`n####################################################################" > $LogFileName
"####################################################################" >> $LogFileName
"######################  STARTING SERVICE  ##########################" >> $LogFileName

for($i=0;$i -le 3; $i++)
{
"`n`n" >> $LogFileName
$ServiceName = $ServiceList[$i]
"$LogStartTime => Service Name: $ServiceName" >> $LogFileName

Write-Output "`n####################################"
Write-Output "Starting Service - " $ServiceList[$i]

"$LogStartTime => Starting Service: $ServiceName" >> $LogFileName
Start-Service $ServiceList[$i]

$ServiceState = Get-Service | Where-Object {$_.Name -eq $ServiceList[$i]}

if($ServiceState.Status -eq "Running")
{
"$LogStartTime => Started Service Successfully: $ServiceName" >> $LogFileName
Write-Host "`n Service " $ServiceList[$i] " Started Successfully"
}
else
{
"$LogStartTime => Unable to Stop Service: $ServiceName" >> $LogFileName
Write-Output "`n Service didn't Start. Current State is - "
Write-Host $ServiceState.Status
}
}

#code to stop the service

"`n####################################################################" > $LogFileName
"####################################################################" >> $LogFileName
"######################  STOPPING SERVICE  ##########################" >> $LogFileName

for($i=0;$i -le 3; $i++)
{
"`n`n" >> $LogFileName
$ServiceName = $ServiceList[$i]
"$LogStartTime => Service Name: $ServiceName" >> $LogFileName

Write-Output "`n####################################"
Write-Output "Stopping Service - " $ServiceList[$i]

"$LogStartTime => Stopping Service: $ServiceName" >> $LogFileName
Stop-Service $ServiceList[$i]

$ServiceState = Get-Service | Where-Object {$_.Name -eq $ServiceList[$i]}

if($ServiceState.Status -eq "Stopped")
{
"$LogStartTime => Stopped Service Successfully: $ServiceName" >> $LogFileName
Write-Host "`n Service " $ServiceList[$i] " Stopped Successfully"
}
else
{
"$LogStartTime => Unable to Stop Service: $ServiceName" >> $LogFileName
Write-Output "`nService didn't Stop. Current State is - "
Write-Host $ServiceState.Status
}
}

@Echo off

Set ServiceName=wampapache64

SC queryex "%ServiceName%"|Find "STATE"|Find /v "RUNNING">Nul&&(

echo %ServiceName% not running
echo  

Net start "%ServiceName%"


    SC queryex "%ServiceName%"|Find "STATE"|Find /v "RUNNING">Nul&&(
        Echo "%ServiceName%" wont start
    )
        echo "%ServiceName%" started

)||(
    echo "%ServiceName%" was working and stopping
    echo  

    Net stop "%ServiceName%"

)


pause

Пов’язано з відповіддю @DanielSerrano, нещодавно мене поцікавила локалізація sc.exeкоманди, а саме іспанською. Я пропоную визначити лінію та маркер, що містить числовий стан обслуговування, та інтерпретувати його, що має бути набагато надійнішим:

@echo off

rem TODO: change to the desired service name
set TARGET_SERVICE=w32time

set SERVICE_STATE=
rem Surgically target third line, as some locales (such as Spanish) translated the utility's output
for /F "skip=3 tokens=3" %%i in ('""%windir%\system32\sc.exe" query "%TARGET_SERVICE%" 2>nul"') do (
  if not defined SERVICE_STATE set SERVICE_STATE=%%i
)
rem Process result
if not defined SERVICE_STATE (
  echo ERROR: could not obtain service state!
) else (
  rem NOTE: values correspond to "SERVICE_STATUS.dwCurrentState"
  rem https://msdn.microsoft.com/en-us/library/windows/desktop/ms685996(v=vs.85).aspx
  if not %SERVICE_STATE%==4 (
    echo WARNING: service is not running
    rem TODO: perform desired operation
    rem net start "%TARGET_SERVICE%"
  ) else (
    echo INFORMATION: service is running
  )
)

Перевірено за допомогою:

• Windows XP (32-розрядна версія) Англійська
• Windows 10 (32-розрядна) іспанська
• Windows 10 (64-розрядна версія) англійська

Може, набагато простіший спосіб? Просто додавши до списку відповідей тут:

@for /f "tokens=1,* delims=: " %%a in ('sc queryex state=Inactive') do net start "%%b"