Отримати список переданих аргументів у пакетному скрипті Windows (.bat)

Я хотів би знайти колегу Batch для Windows, $@який містить список усіх аргументів, переданих у сценарій.

Або я маю турбуватися shift?

dancavallaro має право %*для всіх параметрів командного рядка (за винятком самої назви сценарію). Також вам можуть бути корисні такі:

%0- команда використовується для виклику пакетного файлу (може бути foo, ..\foo, c:\bats\foo.batі т.д.)
%1є першою параметр командного рядка,
%2є другим параметром командного рядка,
і так далі , поки %9(і SHIFTможе бути використаний для тих , хто після 9 - го).

%~nx0 - власне ім'я batch-файлу, незалежно від способу виклику (some-batch.bat)
%~dp0 - диск та шлях до скрипту (d: \ script)
%~dpnx0- це повністю кваліфікована назва сценарію (d: \ scriptpts \ some -batch.bat)

Більше інформації про приклади https://www.ss64.com/nt/syntax-args.html та https://www.robvanderwoude.com/parameters.html

%* Схоже, утримує всі аргументи, передані сценарію.

%1... %nі %*має аргументи, але отримати доступ до них може бути складним, оскільки вміст буде інтерпретовано.
Тому неможливо впоратись із чимось подібним із звичайними твердженнями

myBatch.bat "&"^&

Кожен рядок не вдається, оскільки cmd.exe намагається виконати один з амперсандів (вміст% 1 - це "&"&)

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

Але існує вирішення тимчасового файлу

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

Потрібність полягає в тому, щоб увімкнути echo onта розгорнути оператор %1after rem(працює також з% 2 ..% *).
Але щоб мати можливість перенаправляти вихід echo on, вам потрібні два FOR-LOOPS.

Додаткові символи * #використовуються для захисту від вмісту типу /?(показав би допомогу для REM).
Або карета ^ в кінці рядка може працювати як багаторядковий символ.

FOR / F має працювати з відстроченим розширенням, інакше вміст "!" буде знищено.
Після видалення зайвих символів у param1вас це і ви отримали.

І використовувати param1безпечним способом, увімкнути затримку розширення.

Редагувати: одне зауваження до% 0

%0містить команду, використовувану для виклику партії, також зберігаючи випадок, як у " FoO.BaT
Але після виклику функції", %0а також %~0містить ім'я функції (а краще строку, яка використовувалася для виклику функції).
Але з %~f0вами все-таки можна згадати ім’я файлу.

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

Вихідні дані

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

Я виявив, що наступного разу, коли вам потрібно буде знайти цю інформацію. Замість того, щоб відкривати браузер і google, ви можете просто ввести call /?cmd, і ви отримаєте його:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

Спосіб отримання всіх аргументів до сценарію є тут:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

Ось досить простий спосіб отримати аргументи та встановити їх як env vars. У цьому прикладі я просто позначаю їх як Ключі та Значення.

Збережіть такий приклад коду як "args.bat". Потім викличте пакетний файл, який ви зберегли з командного рядка. приклад: arg.bat --x 90 --y 120

Я надав кілька команд ехо, щоб перейти до вас через процес. Але кінцевий результат полягає в тому, що --x матиме значення 90, а --y матиме значення 120 (тобто якщо ви запустите приклад, як зазначено вище ;-)).

Потім ви можете використовувати умовний вислів "якщо визначено", щоб визначити, чи слід запускати блок коду. Тож скажімо запустити: "arg.bat --x hello-world", то я міг би використати вислів "ЯКЩО ВИЗНАЧЕНО --x echo% - x%", і результати будуть "привіт-світ". Це має мати більше сенсу, якщо ви запустите пакет.

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done

Для використання циклу, щоб отримати всі аргументи та в чистому пакеті:

Obs: для використання без:?*&<>

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!")

:: write/test these arguments/parameters ::
for /l %%l in (1 1 !_cnt!)do echo/ The argument n:%%l is: !_arg_[%%l]!

goto :eof 

Ваш код готовий зробити щось із номером аргументу там, де це потрібно, наприклад ...

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"

echo= !_arg_[1]! !_arg_[2]! !_arg_[2]!> log.txt

Наступний код імітує масив (' params') - приймає параметри, отримані сценарієм, і зберігає їх у змінних params_1.. params_n, де n= params_0= кількість елементів масиву:

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof

Якщо у цитатах є параметри, що містять пробіли, %*вони не працюватимуть правильно. Найкраще рішення, яке я знайшов, - це цикл, який поєднує всі аргументи: https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

Ви можете використовувати ForCommad, щоб отримати список Arg.

Довідка: For /? Довідка:Setlocal /?

Ось мій шлях =

@echo off
::For Run Use This = cmd /c ""Args.cmd" Hello USER Scientist etc"
setlocal EnableDelayedExpansion
set /a Count=0
for %%I IN (%*) DO (
 Echo Arg_!Count! = %%I
 set /a Count+=1 
)
Echo Count Of Args = !Count!
Endlocal

Не потрібна команда Shift.

@echo off
: старт

:: Вставте тут свій код
ехо. %% 1 зараз:% ~ 1
:: Кінець вставити тут свій код

якщо "% ~ 2" NEQ "" (
    зрушення
    goto: почати
)

Багато вищезгаданої інформації привело мене до подальших досліджень, і в кінцевому підсумку, до моєї відповіді, тому я хотів зробити свій внесок у те, що я закінчив робити, сподіваючись, що це допоможе комусь іншому:

• Я також хотів передати різноманітну кількість змінних у пакетний файл, щоб вони могли бути оброблені у файлі.

• Я був у порядку з передачею їх у пакетний файл, використовуючи лапки

• Я хотів би, щоб вони оброблялися аналогічно наведеному нижче, але використовуючи цикл, а не виписувати вручну:

Тому я хотів виконати це:

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

І за допомогою магії для циклів зробіть це в пакетному файлі:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

Проблема, яку я мав, полягає в тому, що всі мої спроби використовувати цикл не спрацювали. Приклад нижче:

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

просто зробив би:

set "_appPath=C:\Services\Logs\PCAP"

і ні:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

навіть після встановлення

SETLOCAL EnableDelayedExpansion

Причина полягала в тому, що цикл for читав весь рядок і присвоював мені другий параметр %% B під час першої ітерації циклу. Оскільки% * представляє всі аргументи, обробляється лише один рядок - трапляється лише один прохід циклу for. Це за задумом виявляється, і моя логіка була помилковою.

Тож я перестав намагатися використовувати цикл for і спростив те, що намагався зробити, використовуючи оператор if, shift та goto. Погодився його трохи зламати, але він більше відповідає моїм потребам. Я можу переглядати всі аргументи, а потім використовувати оператор if для виходу з циклу, коли я оброблю їх усі.

Виграшне твердження за те, що я намагався виконати:

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

ОНОВЛЕННЯ - Натомість мені довелося змінити наведене нижче, я виявляв усі змінні середовища, коли намагався посилатись на% 1 та використовуючи зсув таким чином:

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)

Іноді мені потрібно витягти кілька параметрів командного рядка, але не всі з них і не з першого. Припустимо наступний виклик:

Test.bat uno dos tres cuatro cinco seis siete

Звичайно, розширення ".bat" не потрібно, принаймні у вас є test.exe в одній папці. Ми хочемо отримати вихід "tres cuatro cinco" (незалежно від того, один чи три). Мета полягає в тому, що мені потрібні лише три параметри, починаючи з третього. Для того, щоб мати простий приклад, дія для кожного з них просто "відлуння", але ви можете подумати над іншими складнішими діями над обраними параметрами.

Я підготував декілька прикладів (варіанти), щоб ви могли бачити, який з них вважаєте кращим. На жаль, не існує приємного (або я не знаю про це) способу, заснованого на циклі for для діапазону, наприклад "for %% i in (% 3, 1,% 5)".

@echo off 
setlocal EnableDelayedExpansion

echo Option 1: one by one (same line)
echo %3, %4, %5
echo.

echo Option 2: Loop For one by one
for %%a in (%3, %4, %5) do echo %%a
echo.

echo Option 3: Loop For with check of limits
set i=0
for %%a in (%*) do (
    set /A i=i+1
    If !i! GTR 2 if !i! LSS 6 echo %%a
)
echo.

echo Option 4: Loop For with auxiliary list
for /l %%i in (3,1,5) do  (
    set a=%%i
    set b=echo %%
    set b=!b!!a!
    call !b!
)
echo.

echo Option 5: Assigning to an array of elements previously
set e[0]=%0
set i=0 
for %%a in (%*) do (
    set /A i=i+1
    set e[!i!]=%%a
)
for  /l %%i in (3,1,5) do (
    echo !e[%%i]!
)
echo.

echo Option 6: using shift and goto loop. It doesn't work with for loop
set i=2
:loop6
    set /A i=i+1
    echo %3
    shift
    If %i% LSS 5 goto :loop6

Напевно, ви можете знайти більше варіантів або комбінувати кілька. Насолоджуйтесь ними.

Версія Windows (хоча потрібен socat)

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

налаштування:

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd