Ви додали кнопку до свого DataGridViewі хочете запустити якийсь код при натисканні на нього.
Легкий горошок - просто виконайте наступні дії:
Не потрібно:
По-перше, ось що НЕ робити:
Я б уникнув пропозицій у деяких інших відповідях тут і навіть наданих документацією на MSDN для жорсткого кодування індексу чи назви стовпців, щоб визначити, чи натиснули кнопку. Подія натискання реєструється для всієї сітки, тож якимось чином потрібно визначити, що була натиснута кнопка, але цього не слід робити, вважаючи, що ваша кнопка живе у певній назві або індексі стовпця ... є простіший спосіб ...
Крім того, будьте уважні, з якою подією ви хочете вчинити. Знову ж таки, документація та багато прикладів помиляються. Більшість прикладів стосується CellClickподії, яка спричинить пожежу:
коли клацніть будь-яку частину комірки.
... але також запускатиметься кожного разу, коли натискається заголовок рядка . Це вимагає додавання додаткового коду, щоб просто визначити, чи є e.RowIndexзначення менше 0
Замість цього обробіть те, CellContentClickщо відбувається лише:
при натисканні на вміст у комірці
З будь-якої причини заголовок стовпця також вважається "вмістом" всередині комірки, тому нам все одно доведеться перевірити це нижче.
Дос:
Отже, ось що вам потрібно зробити:
По-перше, відправте відправника типу, DataGridViewщоб відкрити його внутрішні властивості під час проектування. Ви можете змінити тип параметра, але це може часом зробити додавання або видалення обробників складним.
Далі, щоб побачити, чи натиснули кнопку, просто перевірте, чи відповідає тип стовпця, що піднімає подію DataGridViewButtonColumn. Оскільки ми вже передали відправника для введення DataGridView, ми можемо отримати Columnsколекцію та вибрати поточний стовпець за допомогою e.ColumnIndex. Потім перевірте, чи є цей об’єкт типу DataGridViewButtonColumn.
Звичайно, якщо вам потрібно розрізняти кілька кнопок на сітці, ви можете вибрати їх на основі назви стовпця чи індексу, але це не має бути вашою першою перевіркою. Завжди переконайтеся, що спочатку було натиснуто кнопку, а потім належним чином обробляйте будь-що інше. У більшості випадків, коли у вас є лише одна кнопка на сітці, ви можете стрибати прямо на перегони.
Збираємо все це разом:
C # :
private void dataGridView1_CellContentClick(object sender, DataGridViewCellEventArgs e)
{
var senderGrid = (DataGridView)sender;
if (senderGrid.Columns[e.ColumnIndex] is DataGridViewButtonColumn &&
e.RowIndex >= 0)
{
//TODO - Button Clicked - Execute Code Here
}
}
VB :
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso
e.RowIndex >= 0 Then
'TODO - Button Clicked - Execute Code Here
End If
End Sub
Оновлення 1 - Спеціальна подія
Якщо ви хотіли трохи повеселитися, ви можете додати свою власну подію, коли потрібно підняти кожен раз, коли натиснути кнопку на DataGrid. Ви не можете додати його до самої DataGrid, не заплутавшись у спадщині тощо, але ви можете додати спеціальну подію до своєї форми та запустити її, коли це доречно. Це трохи більше коду, але перевершення полягає в тому, що ви виділили те, що хочете зробити, коли натискаєте кнопку, і як визначити, чи натиснула кнопку.
Просто оголосіть подію, підніміть її, коли це доречно, і поводьтеся з нею. Це буде виглядати приблизно так:
Event DataGridView1ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent DataGridView1ButtonClick(senderGrid, e)
End If
End Sub
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) Handles Me.DataGridView1ButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
Оновлення 2 - Розширена сітка
Що було б чудово, якби ми працювали з сіткою, яка тільки робила ці речі для нас. Ми могли б відповісти на перше питання легко: you've added a button to your DataGridView and you want to run some code when it's clicked. Ось підхід, який поширює стратегію DataGridView. Можливо, не варто мати клопоту над тим, щоб доставляти користувальницький контроль з кожною бібліотекою, але принаймні це максимально повторно використовує код, який використовується для визначення того, чи було натиснуто кнопку.
Просто додайте це до своєї збірки:
Public Class DataGridViewExt : Inherits DataGridView
Event CellButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub CellContentClicked(sender As System.Object, e As DataGridViewCellEventArgs) Handles Me.CellContentClick
If TypeOf Me.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent CellButtonClick(Me, e)
End If
End Sub
End Class
Це воно. Ніколи не торкайтеся його знову. Переконайтеся, що ваш DataGrid має тип, DataGridViewExtякий повинен працювати точно так само, як DataGridView. Крім того, це також призведе до додаткової події, з якою ви можете впоратися так:
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
