Як мені отримати вихід команди оболонки, виконану за допомогою змінної з Jenkinsfile (groovy)?

У мене є щось подібне на Jenkinsfile (Groovy), і я хочу записати stdout та вихідний код у змінну, щоб згодом використовувати інформацію.

sh "ls -l"

Як я можу це зробити, тим більше, що здається, що ти не можеш реально запустити будь-який загрозливий код всередині Jenkinsfile?

Остання версія shкроку трубопроводу дозволяє зробити наступне;

// Git committer email
GIT_COMMIT_EMAIL = sh (
    script: 'git --no-pager show -s --format=\'%ae\'',
    returnStdout: true
).trim()
echo "Git committer email: ${GIT_COMMIT_EMAIL}"

Ще одна особливість - це returnStatusваріант.

// Test commit message for flags
BUILD_FULL = sh (
    script: "git log -1 --pretty=%B | grep '\\[jenkins-full]'",
    returnStatus: true
) == 0
echo "Build full flag: ${BUILD_FULL}"

Ці параметри додаються на основі цього питання.

Дивіться офіційну документацію для shкоманди.

Поточна версія трубопроводу спочатку підтримує returnStdoutі returnStatus, що дає змогу отримати вихід / стан з sh/ batкроків.

Приклад:

def ret = sh(script: 'uname', returnStdout: true)
println ret

Офіційна документація .

швидка відповідь така:

sh "ls -l > commandResult"
result = readFile('commandResult').trim()

Я думаю, що існує запит на функцію, щоб мати змогу отримати результат sh step, але, наскільки я знаю, на даний момент іншого варіанту немає.

РЕДАКЦІЯ: JENKINS-26133

EDIT2: Не зовсім впевнений, з якої версії, але кроки sh / bat тепер можуть повернути висновок std, просто:

def output = sh returnStdout: true, script: 'ls -l'

Якщо ви хочете отримати stdout І знати, вдала команда чи ні, просто використовуйте returnStdoutта оберніть її в обробник винятків:

сценарій сценарію

try {
    // Fails with non-zero exit if dir1 does not exist
    def dir1 = sh(script:'ls -la dir1', returnStdout:true).trim()
} catch (Exception ex) {
    println("Unable to read dir1: ${ex}")
}

вихід :

[Pipeline] sh
[Test-Pipeline] Running shell script
+ ls -la dir1
ls: cannot access dir1: No such file or directory
[Pipeline] echo
unable to read dir1: hudson.AbortException: script returned exit code 2

На жаль, hudson.AbortException не вистачає жодного корисного методу для отримання цього статусу виходу, тому, якщо потрібне фактичне значення, вам знадобиться проаналізувати його з повідомлення (так!)

Всупереч Javadoc https://javadoc.jenkins-ci.org/hudson/AbortException.html збірка не виходить з ладу, коли цей виняток знайдено. Виходить з ладу, коли його не спіймали!

Оновлення: Якщо ви також хочете вивести STDERR з команди оболонки, Дженкінс, на жаль, не вдається належним чином підтримати цей звичайний варіант використання. Квиток на 2017 рік JENKINS-44930 застряг у стані самовпевненого пінг-понгу, не роблячи жодного прогресу на шляху до вирішення - будь ласка, подумайте про те, щоб додати його.

Щодо рішення зараз , можливо, існує кілька можливих підходів:

a) Перенаправляйте STDERR на STDOUT 2>&1 - однак тоді ви вирішите розібрати це з основного виводу, але ви не отримаєте висновок, якщо команда не вдалася - тому що ви є обробником винятку.

б) перенаправити STDERR на тимчасовий файл (назва якого ви підготували раніше) 2>filename(але не забудьте очистити файл згодом) - тобто. Основним кодом стає:

def stderrfile = 'stderr.out'
try {
    def dir1 = sh(script:"ls -la dir1 2>${stderrfile}", returnStdout:true).trim()
} catch (Exception ex) {
    def errmsg = readFile(stderrfile)
    println("Unable to read dir1: ${ex} - ${errmsg}")
}

c) Перейдіть в інший спосіб, встановіть returnStatus=trueзамість цього, не обробляйте обробник винятків і завжди фіксуйте вихід у файл, тобто:

def outfile = 'stdout.out'
def status = sh(script:"ls -la dir1 >${outfile} 2>&1", returnStatus:true)
def output = readFile(outfile).trim()
if (status == 0) {
    // output is directory listing from stdout
} else {
    // output is error message from stderr
}

Застереження: наведений вище код є специфічним для Unix / Linux - Windows вимагає зовсім інших команд оболонки.

це зразок справи, в який я маю сенс вважати!

node('master'){
    stage('stage1'){
    def commit = sh (returnStdout: true, script: '''echo hi
    echo bye | grep -o "e"
    date
    echo lol''').split()


    echo "${commit[-1]} "

    }
}

Для тих, кому потрібно використовувати вихід у наступних командах оболонки, а не groovy, щось подібне можна зробити:

    stage('Show Files') {
        environment {
          MY_FILES = sh(script: 'cd mydir && ls -l', returnStdout: true)
        }
        steps {
          sh '''
            echo "$MY_FILES"
          '''
        }
    }

Я знайшов приклади коду Maven дуже корисними.

Найпростішим способом є використання цього способу

my_var=`echo 2` echo $my_var вихід: 2

Зауважте, що не проста одинарна цитата - це зворотна цитата (`).