Згладжування команди в vim

Vim є моїм кращим текстовим редактором, коли я програмую, і тому я завжди стикаюся з особливо прикрою проблемою.

Часто, коли мені швидко потрібно зберегти буфер і продовжувати виконувати інші завдання, я виконую типове

:w

Однак мені - як здається, більше 50% часу - завжди вдається скористатися цим :w. Природно, vim кричить на мене, тому що Wце недійсна команда

E492: Not an editor command: W

Моє запитання - як можна створювати псевдоніми двокрапкових команд у vim . В Зокрема, ви могли б служити прикладом , як псевдонім Wдля w.

Мені відомо про процес відображення ключів до певних команд . На жаль, це не те, що я шукаю.

Щоб залишити незавершене завершення, спробуйте скористатися

cnoreabbrev W w

, він замінить Wу командному рядку на w, але лише у тому випадку, якщо за ним не дотримується і не передує символ слова, тому :W<CR>він буде замінений :w<CR>, але :Writeне буде. (Зверніть увагу, що це впливає на будь-які команди, які відповідають, включаючи ті, яких ви можете не очікувати. Наприклад, команду :saveas W Zбуде замінено :saveas w Z, тому будьте обережні з цим.)

Оновлення

Ось як я б написати його прямо зараз :

cnoreabbrev <expr> W ((getcmdtype() is# ':' && getcmdline() is# 'W')?('w'):('W'))

Як функція:

fun! SetupCommandAlias(from, to)
  exec 'cnoreabbrev <expr> '.a:from
        \ .' ((getcmdtype() is# ":" && getcmdline() is# "'.a:from.'")'
        \ .'? ("'.a:to.'") : ("'.a:from.'"))'
endfun
call SetupCommandAlias("W","w")

Це перевіряє, що тип команди є, :а команда - Wце безпечніше, ніж просто cnoreabbrev W w.

За допомогою додаткового пошуку я виявив, що хтось задав майже те саме питання, що і я.

:command <AliasName> <string of command to be aliased>

зробить трюк.

Зауважте, що, як вказує Річо , команда користувача повинна починатися з великої літери.

Я вважаю, що відображення ;ключа для :було б кращим рішенням, і зробило б вас більш продуктивними для введення інших команд.

nnoremap ; :
vnoremap ; :

Найкраще рішення передбачає написання спеціальної функції для обробки скорочень, які мають місце лише на початку командної панелі.

Для цього додайте наступний файл vimrc або деінде.

" cabs - less stupidity                                                      {{{
fu! Single_quote(str)
  return "'" . substitute(copy(a:str), "'", "''", 'g') . "'"
endfu
fu! Cabbrev(key, value)
  exe printf('cabbrev <expr> %s (getcmdtype() == ":" && getcmdpos() <= %d) ? %s : %s',
    \ a:key, 1+len(a:key), Single_quote(a:value), Single_quote(a:key))
endfu
"}}}

" use this custom function for cabbrevations. This makes sure that they only
" apply in the beginning of a command. Else we might end up with stuff like
"   :%s/\vfoo/\v/\vbar/
" if we happen to move backwards in the pattern.

" For example:
call Cabbrev('W', 'w')

Кілька корисних скорочень із вихідного матеріалу, де я знайшов цей матеріал:

call Cabbrev('/',   '/\v')
call Cabbrev('?',   '?\v')

call Cabbrev('s/',  's/\v')
call Cabbrev('%s/', '%s/\v')

call Cabbrev('s#',  's#\v')
call Cabbrev('%s#', '%s#\v')

call Cabbrev('s@',  's@\v')
call Cabbrev('%s@', '%s@\v')

call Cabbrev('s!',  's!\v')
call Cabbrev('%s!', '%s!\v')

call Cabbrev('s%',  's%\v')
call Cabbrev('%s%', '%s%\v')

call Cabbrev("'<,'>s/", "'<,'>s/\v")
call Cabbrev("'<,'>s#", "'<,'>s#\v")
call Cabbrev("'<,'>s@", "'<,'>s@\v")
call Cabbrev("'<,'>s!", "'<,'>s!\v")

Можливо, ви хочете зіставити одну зі своїх функціональних клавіш (F1..F12) на: w? Потім вставте це у свій .vimrc:

noremap  <f1> :w<return>
inoremap <f1> <c-o>:w<return>

(ctrl-o в режимі вставки тимчасово переходить у звичайний режим).

Припустимо, ви хочете додати псевдонім для команди tabnew в gvim. ви можете просто ввести таку команду у вашому файлі .vimrc (якщо не в домашній папці, ніж створити)

cabbrev t tabnew

Найбезпечнішим і найпростішим є плагін, такий як cmdalias.vim або моє недавнє оновлення vim-alias його, яке враховує

• попередні заготовки або модифікаторів , такі як :sil(ent)(!)або :redi(r),
• модифікатори діапазону, такі як '<,'>для поточного візуального вибору,
• уникати спеціальних символів, таких як цитати та
• перевірте, чи вибраний псевдонім є дійсною абревіатурою командного рядка.