Замініть вкладки пробілами в vim

Я хотів би перетворити вкладку в пробіли в gVim. Я додав наступний рядок до свого _vimrc:

set tabstop=2

Він працює, щоб зупинитися на двох пробілах, але все ще виглядає як одна клавіша вкладки (я намагався використовувати клавішу h для підрахунку пробілів після цього).

Я не впевнений, що мені робити, щоб gVim конвертував вкладки в пробіли?

IIRC, щось на кшталт:

set tabstop=2 shiftwidth=2 expandtab

повинен зробити трюк. Якщо у вас вже є вкладки, то слідкуйте за цим приємним глобальним RE, щоб замінити їх подвійними пробілами.

Як тільки ви отримаєте розширення вкладки відповідно до інших відповідей, надзвичайно зручним способом перетворення існуючих файлів відповідно до ваших нових налаштувань є:

:retab

Він буде працювати над поточним буфером.

Спробуйте

set expandtab

для м'яких вкладок.

Щоб виправити наявні вкладки:

:%s/\t/  /g

Я використав два пробіли, оскільки ви вже встановили свій пробіл на 2 пробіли.

Це працювало для мене:

ви можете побачити вкладки, спочатку зробивши це:

:set list

потім, щоб зробити можливою заміну вкладок, зробіть це:

:set expandtab

тоді

:retab

тепер усі вкладки були замінені пробілами, після чого можна повернутися до звичайного перегляду таким чином:

:set nolist

gg=G буде повторно весь файл і видаляє більшість, якщо не всі вкладки, які я отримую у файлах від колег.

Додайте наступні рядки до .vimrc

set expandtab
set tabstop=4
set shiftwidth=4
map <F2> :retab <CR> :wq! <CR>

Відкрийте файл in vim та натисніть F2. Вкладки будуть перетворені на 4 пробіли, а файл буде збережено автоматично.

Якщо ви хочете зберегти свої \t8 пробілів, тоді подумайте про налаштування:

   set softtabstop=2 tabstop=8 shiftwidth=2

Це дасть вам два пробіли на <TAB>прес, але фактичний \tу вашому коді все ще буде розглядатися як 8 символів.

Це працює для мене:

:set tabstop=2 shiftwidth=2 expandtab | retab

Перший пошук вкладок у вашому файлі: / ^ I: set extensiontab: retab

буду працювати.

У цій статті є відмінний сценарій vimrc для обробки вкладок + пробілів та перетворення між ними.

Ці команди надаються:

Space2Tab Перетворення пробілів у вкладки, лише в відступах.

Tab2Space Перетворення вкладок у пробіли, лише в відступи.

RetabIndent Виконати Space2Tab (якщо встановлено 'extensiontab') або Tab2Space (інакше).

Кожна команда приймає аргумент, який визначає кількість пробілів у стовпці вкладки. За замовчуванням використовується настройка «табустоп».

Джерело: http://vim.wikia.com/wiki/Super_retab#Script

" Return indent (all whitespace at start of a line), converted from
" tabs to spaces if what = 1, or from spaces to tabs otherwise.
" When converting to tabs, result has no redundant spaces.
function! Indenting(indent, what, cols)
  let spccol = repeat(' ', a:cols)
  let result = substitute(a:indent, spccol, '\t', 'g')
  let result = substitute(result, ' \+\ze\t', '', 'g')
  if a:what == 1
    let result = substitute(result, '\t', spccol, 'g')
  endif
  return result
endfunction

" Convert whitespace used for indenting (before first non-whitespace).
" what = 0 (convert spaces to tabs), or 1 (convert tabs to spaces).
" cols = string with number of columns per tab, or empty to use 'tabstop'.
" The cursor position is restored, but the cursor will be in a different
" column when the number of characters in the indent of the line is changed.
function! IndentConvert(line1, line2, what, cols)
  let savepos = getpos('.')
  let cols = empty(a:cols) ? &tabstop : a:cols
  execute a:line1 . ',' . a:line2 . 's/^\s\+/\=Indenting(submatch(0), a:what, cols)/e'
  call histdel('search', -1)
  call setpos('.', savepos)
endfunction

command! -nargs=? -range=% Space2Tab call IndentConvert(<line1>,<line2>,0,<q-args>)
command! -nargs=? -range=% Tab2Space call IndentConvert(<line1>,<line2>,1,<q-args>)
command! -nargs=? -range=% RetabIndent call IndentConvert(<line1>,<line2>,&et,<q-args>)

Це допомогло мені трохи більше, ніж відповіді тут, коли я вперше пішов шукати рішення.

expandце утиліта Unix для перетворення вкладок у пробіли. Якщо ви не хочете setнічого в vim, ви можете скористатися командою shell від vim:

:!% expand -t8