Vim: Створення батьківських каталогів при збереженні

Якщо я посилаюсь, vim foo/bar/somefileале її foo/barще не існує, Vim відмовляється зберігати.

Я знаю, що я міг би перейти на оболонку або зробити :!mkdir foo/barз Vim, але я лінивий :) Чи є спосіб зробити так, щоб Vim робив це автоматично, коли він зберігає буфер?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

Зверніть увагу на умови: expand("<afile>")!~#'^\w\+:/'заважатиме vim створювати каталоги для таких файлів, як ftp://*і !isdirectoryзапобігає дорогому виклику mkdir.

Оновлення : плавно краще рішення, яке також перевіряє наявність непустого типу та використовує mkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

На основі пропозицій до мого запитання, ось що я закінчив:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

Це визначає :Wкоманду. В ідеалі я хотів би мати все :w!, :wq, :wq!, і :wallт.д. працюю так само, але я не впевнений , якщо це можливо без в основному реалізувавши їх всі призначені для користувача функції.

Я додав це до свого ~ / .vimrc

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

Якщо мені потрібно створити каталог, в якому я вписую, :mk.він замінює його на "! Mkdir -p / path / to / my / file /" і дозволяє мені переглянути команду перед тим, як викликати її.

Я змусив :saveas!створити каталог, якщо його немає: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

Цей код запропонує вам створити каталог :wабо просто зробити це за допомогою :w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

Я думаю, що мені вдалося це зробити в три рядки, поєднуючи те, що інші говорять у цій відповіді.

Це, здається, робить трюк:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

Він намагається створити папку автоматично під час збереження буфера. Якщо трапиться щось погане (тобто проблеми з дозволом), воно просто закриється і не дозволить записати файл.

Якщо хтось бачить явні недоліки, будь ласка, опублікуйте коментар. Я не дуже розбираюся в vimscript.

EDIT: Примітки завдяки ZyX

• Це не спрацює, якщо у ваших папках є пробіли (мабуть, вони неправильно відображені чи щось)
• Або якщо ви робите псевдофайли.
• Або якщо ви шукаєте свій vimrc.
• Але сину, це коротко.