Рекурсія візерунка
З рекурсивними візерунками ви маєте форму збігу рекурсивного спуску .
Це чудово для різних проблем, але як тільки ви хочете здійснити рекурсивний синтаксичний аналіз , вам потрібно вставити групи захоплення тут і там, і незручно відновлювати повну структуру синтаксичного аналізу таким чином. Модуль Regexp :: Grammars Даміана Конвея для Perl перетворює простий зразок в еквівалентний, який автоматично виконує все те, що іменовано, в рекурсивну структуру даних, що полегшує отримання аналізованої структури. У мене є зразок, що порівнює ці два підходи в кінці цієї публікації.
Обмеження на рекурсію
Питання полягало в тому, які типи граматик, яким можуть відповідати рекурсивні шаблони. Ну, це, звичайно, матчі типу рекурсивного спуску . Єдине, що спадає на думку, це те, що рекурсивні візерунки не можуть обробляти ліву рекурсію . Це обмежує види граматик, до яких ви можете їх застосувати. Іноді ви можете впорядкувати свої постановки, щоб усунути рекурсію ліворуч.
До речі, PCRE і Perl дещо відрізняються від того, як вам дозволено формулювати рекурсію. Див. Розділи «РЕКУРСИВНІ ШАБЛОНИ» та «Різниця рекурсії від Perl» на сторінці керівництва . наприклад: Perl може замість цього обробляти те, що ^(.|(.)(?1)\2)$вимагає PCRE ^((.)(?1)\2|.)$.
Демонстрація рекурсії
Потреба в рекурсивних моделях виникає напрочуд часто. Одним з добре відвідуваних прикладів є випадки, коли вам потрібно зіставити щось, що може вкластися, наприклад, збалансовані дужки, лапки або навіть теги HTML / XML. Ось відповідність для збалансованих панелей:
\((?:[^()]*+|(?0))*\)
Я вважаю, що це складніше читати через його компактність. Це легко вилікувати за допомогою /xрежиму, щоб зробити пробіли більше не значущими:
\( (?: [^()] *+ | (?0) )* \)
Знову ж таки, оскільки ми використовуємо parens для нашої рекурсії, то більш наочним прикладом буде відповідність вкладених одинарних лапок:
‘ (?: [^‘’] *+ | (?0) )* ’
Ще однією рекурсивно визначеною річчю, яку ви, можливо, захочете зіставити, був би паліндром. Цей простий шаблон працює в Perl:
^((.)(?1)\2|.?)$
які ви можете протестувати на більшості систем, використовуючи щось подібне:
$ perl -nle 'print if /^((.)(?1)\2|.?)$/i' /usr/share/dict/words
Зверніть увагу, що реалізація рекурсії PCRE вимагає більш докладної роботи
^(?:((.)(?1)\2|)|((.)(?3)\4|.))
Це пов’язано з обмеженнями щодо того, як працює рекурсія PCRE.
Правильний синтаксичний аналіз
На мій погляд , наведені вище приклади, в основному іграшка матчів, в повному обсязі , що цікаво, на самому ділі. Коли стає цікаво - це коли у вас є справжня граматика, яку ви намагаєтеся проаналізувати. Наприклад, RFC 5322 визначає поштову адресу досить детально. Ось “граматичний” шаблон, який відповідає цьому:
$rfc5322 = qr{
(?(DEFINE)
(?<address> (?&mailbox) | (?&group))
(?<mailbox> (?&name_addr) | (?&addr_spec))
(?<name_addr> (?&display_name)? (?&angle_addr))
(?<angle_addr> (?&CFWS)? < (?&addr_spec) > (?&CFWS)?)
(?<group> (?&display_name) : (?:(?&mailbox_list) | (?&CFWS))? ; (?&CFWS)?)
(?<display_name> (?&phrase))
(?<mailbox_list> (?&mailbox) (?: , (?&mailbox))*)
(?<addr_spec> (?&local_part) \@ (?&domain))
(?<local_part> (?&dot_atom) | (?"ed_string))
(?<domain> (?&dot_atom) | (?&domain_literal))
(?<domain_literal> (?&CFWS)? \[ (?: (?&FWS)? (?&dcontent))* (?&FWS)?
\] (?&CFWS)?)
(?<dcontent> (?&dtext) | (?"ed_pair))
(?<dtext> (?&NO_WS_CTL) | [\x21-\x5a\x5e-\x7e])
(?<atext> (?&ALPHA) | (?&DIGIT) | [!#\$%&'*+-/=?^_`{|}~])
(?<atom> (?&CFWS)? (?&atext)+ (?&CFWS)?)
(?<dot_atom> (?&CFWS)? (?&dot_atom_text) (?&CFWS)?)
(?<dot_atom_text> (?&atext)+ (?: \. (?&atext)+)*)
(?<text> [\x01-\x09\x0b\x0c\x0e-\x7f])
(?<quoted_pair> \\ (?&text))
(?<qtext> (?&NO_WS_CTL) | [\x21\x23-\x5b\x5d-\x7e])
(?<qcontent> (?&qtext) | (?"ed_pair))
(?<quoted_string> (?&CFWS)? (?&DQUOTE) (?:(?&FWS)? (?&qcontent))*
(?&FWS)? (?&DQUOTE) (?&CFWS)?)
(?<word> (?&atom) | (?"ed_string))
(?<phrase> (?&word)+)
(?<FWS> (?: (?&WSP)* (?&CRLF))? (?&WSP)+)
(?<ctext> (?&NO_WS_CTL) | [\x21-\x27\x2a-\x5b\x5d-\x7e])
(?<ccontent> (?&ctext) | (?"ed_pair) | (?&comment))
(?<comment> \( (?: (?&FWS)? (?&ccontent))* (?&FWS)? \) )
(?<CFWS> (?: (?&FWS)? (?&comment))*
(?: (?:(?&FWS)? (?&comment)) | (?&FWS)))
(?<NO_WS_CTL> [\x01-\x08\x0b\x0c\x0e-\x1f\x7f])
(?<ALPHA> [A-Za-z])
(?<DIGIT> [0-9])
(?<CRLF> \x0d \x0a)
(?<DQUOTE> ")
(?<WSP> [\x20\x09])
)
(?&address)
}x;
Як бачите, це дуже подобається БНФ. Проблема в тому, що це просто сірник, а не захоплення. І ви дійсно не хочете просто оточувати все це захопленням парен, тому що це не говорить вам, яке виробництво відповідало якій частині. Використовуючи згаданий раніше модуль Regexp :: Grammars, ми можемо.
use strict;
use warnings;
use 5.010;
use Data::Dumper "Dumper";
my $rfc5322 = do {
use Regexp::Grammars;
qr{
# Keep the big stick handy, just in case...
# <debug:on>
# Match this...
<address>
# As defined by these...
<token: address> <mailbox> | <group>
<token: mailbox> <name_addr> | <addr_spec>
<token: name_addr> <display_name>? <angle_addr>
<token: angle_addr> <CFWS>? \< <addr_spec> \> <CFWS>?
<token: group> <display_name> : (?:<mailbox_list> | <CFWS>)? ; <CFWS>?
<token: display_name> <phrase>
<token: mailbox_list> <[mailbox]> ** (,)
<token: addr_spec> <local_part> \@ <domain>
<token: local_part> <dot_atom> | <quoted_string>
<token: domain> <dot_atom> | <domain_literal>
<token: domain_literal> <CFWS>? \[ (?: <FWS>? <[dcontent]>)* <FWS>?
<token: dcontent> <dtext> | <quoted_pair>
<token: dtext> <.NO_WS_CTL> | [\x21-\x5a\x5e-\x7e]
<token: atext> <.ALPHA> | <.DIGIT> | [!#\$%&'*+-/=?^_`{|}~]
<token: atom> <.CFWS>? <.atext>+ <.CFWS>?
<token: dot_atom> <.CFWS>? <.dot_atom_text> <.CFWS>?
<token: dot_atom_text> <.atext>+ (?: \. <.atext>+)*
<token: text> [\x01-\x09\x0b\x0c\x0e-\x7f]
<token: quoted_pair> \\ <.text>
<token: qtext> <.NO_WS_CTL> | [\x21\x23-\x5b\x5d-\x7e]
<token: qcontent> <.qtext> | <.quoted_pair>
<token: quoted_string> <.CFWS>? <.DQUOTE> (?:<.FWS>? <.qcontent>)*
<.FWS>? <.DQUOTE> <.CFWS>?
<token: word> <.atom> | <.quoted_string>
<token: phrase> <.word>+
<token: FWS> (?: <.WSP>* <.CRLF>)? <.WSP>+
<token: ctext> <.NO_WS_CTL> | [\x21-\x27\x2a-\x5b\x5d-\x7e]
<token: ccontent> <.ctext> | <.quoted_pair> | <.comment>
<token: comment> \( (?: <.FWS>? <.ccontent>)* <.FWS>? \)
<token: CFWS> (?: <.FWS>? <.comment>)*
(?: (?:<.FWS>? <.comment>) | <.FWS>)
<token: NO_WS_CTL> [\x01-\x08\x0b\x0c\x0e-\x1f\x7f]
<token: ALPHA> [A-Za-z]
<token: DIGIT> [0-9]
<token: CRLF> \x0d \x0a
<token: DQUOTE> "
<token: WSP> [\x20\x09]
}x;
};
while (my $input = <>) {
if ($input =~ $rfc5322) {
say Dumper \%/; # ...the parse tree of any successful match
# appears in this punctuation variable
}
}
Як бачите, використовуючи зовсім трохи інші позначення в шаблоні, ви тепер отримуєте щось, що зберігає все дерево синтаксичного аналізу для вас у %/змінній зі всім акуратно позначеним. Результат перетворення все ще є шаблоном, як ви можете бачити за =~оператором. Це просто трохи чарівно.