Як скинути послідовність в Oracle?

У PostgreSQL я можу зробити щось подібне:

ALTER SEQUENCE serial RESTART WITH 0;

Чи є еквівалент Oracle?

Ось хороша процедура скидання будь-якої послідовності до 0 від гуру Oracle Тома Кайта . Відмінна дискусія щодо плюсів і мінусів у посиланнях нижче.

tkyte@TKYTE901.US.ORACLE.COM> 
create or replace
procedure reset_seq( p_seq_name in varchar2 )
is
    l_val number;
begin
    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by -' || l_val || 
                                                          ' minvalue 0';

    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue 0';
end;
/

З цієї сторінки: Динамічний SQL для скидання значення послідовності
Ще одна гарна дискусія тут: Як скинути послідовності?

Істинний перезапуск НЕ представляється можливим AFAIK . (Будь ласка, виправте мене, якщо я помиляюся!).

Однак якщо ви хочете встановити його на 0, ви можете просто видалити та відтворити його.

Якщо ви хочете встановити його на певне значення, ви можете встановити ВПРОВАДЖЕННЯ на негативне значення і отримати наступне значення.

Тобто, якщо ваша послідовність становить 500, ви можете встановити її на 100 via

ALTER SEQUENCE serial INCREMENT BY -400;
SELECT serial.NEXTVAL FROM dual;
ALTER SEQUENCE serial INCREMENT BY 1;

Це мій підхід:

1. скинути послідовність
2. відтворити його

Приклад:

--Drop sequence

DROP SEQUENCE MY_SEQ;

-- Create sequence 

create sequence MY_SEQ
minvalue 1
maxvalue 999999999999999999999
start with 1
increment by 1
cache 20;

alter sequence serial restart start with 1;

Ця функція була офіційно додана в 18c, але неофіційно доступна в 12.1.

Безперечно безпечно використовувати цю недокументовану функцію в 12.1. Хоча синтаксис не входить в офіційну документацію , він генерується пакетом Oracle DBMS_METADATA_DIFF . Я кілька разів використовував його у виробничих системах. Однак я створив запит на службу Oracle, і вони підтвердили, що це не помилка в документації, функція справді не підтримується.

У 18c ця функція не з’являється в синтаксисі мови SQL, але включена в посібник адміністратора бази даних .

Мій підхід є підлітковим продовженням прикладу Дугмана .

Розширення ...

Передайте значення параметра насіння як параметр. Чому? Мені подобається називати річ скиданням послідовності до максимального ідентифікатора, який використовується в якійсь таблиці . Я в кінцевому підсумку викликаю цю програму з іншого скрипту, який виконує кілька викликів для цілого ряду послідовностей, скидає nextval назад вниз на деякий рівень, достатньо високий, щоб не викликати порушення первинного ключа, коли я використовую значення послідовності для унікального ідентифікатора.

Він також вшановує попереднє мінімальне значення . Фактично воно може підштовхнути наступне значення все вище, якщо бажане значення p_val або існуюче мінімальне значення перевищує поточне або обчислене наступне значення.

Найкраще, що його можна буде викликати для скидання до заданого значення та просто зачекайте, поки обгортка побачить процедуру "виправити всі мої послідовності" наприкінці.

create or replace
procedure Reset_Sequence( p_seq_name in varchar2, p_val in number default 0)
is
  l_current number := 0;
  l_difference number := 0;
  l_minvalue user_sequences.min_value%type := 0;

begin

  select min_value
  into l_minvalue
  from user_sequences
  where sequence_name = p_seq_name;

  execute immediate
  'select ' || p_seq_name || '.nextval from dual' INTO l_current;

  if p_Val < l_minvalue then
    l_difference := l_minvalue - l_current;
  else
    l_difference := p_Val - l_current;
  end if;

  if l_difference = 0 then
    return;
  end if;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by ' || l_difference || 
       ' minvalue ' || l_minvalue;

  execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_difference;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue ' || l_minvalue;
end Reset_Sequence;

Ця процедура корисна сама по собі, але тепер додамо ще одну, яка її викликає, і все програмно визначає з умовою іменування послідовностей і шукає максимальне значення, що використовується в існуючій таблиці / полі ...

create or replace
procedure Reset_Sequence_to_Data(
  p_TableName varchar2,
  p_FieldName varchar2
)
is
  l_MaxUsed NUMBER;
BEGIN

  execute immediate
    'select coalesce(max(' || p_FieldName || '),0) from '|| p_TableName into l_MaxUsed;

  Reset_Sequence( p_TableName || '_' || p_Fieldname || '_SEQ', l_MaxUsed );

END Reset_Sequence_to_Data;

Тепер ми готуємо з газом!

Вище описана процедура перевірить наявність максимального значення поля в таблиці, будує ім'я послідовності з пари таблиці / поля та викликає "Reset_Sequence" з цим почутим максимальним значенням.

Фінальна частина цієї головоломки та глазур на торті йде далі ...

create or replace
procedure Reset_All_Sequences
is
BEGIN

  Reset_Sequence_to_Data( 'ACTIVITYLOG', 'LOGID' );
  Reset_Sequence_to_Data( 'JOBSTATE', 'JOBID' );
  Reset_Sequence_to_Data( 'BATCH', 'BATCHID' );

END Reset_All_Sequences;

У моїй фактичній базі даних є приблизно сто інших послідовностей, що скидаються за допомогою цього механізму, тому в цій процедурі вище є 97 викликів на Reset_Sequence_to_Data .

Любите це? Ненавиджу це? Байдужий?

Наступний сценарій встановлює послідовність на потрібне значення:

Дано щойно створену послідовність під назвою PCS_PROJ_KEY_SEQ та таблицю PCS_PROJ:

BEGIN
   DECLARE
      PROJ_KEY_MAX       NUMBER := 0;
      PROJ_KEY_CURRVAL   NUMBER := 0;
   BEGIN

    SELECT MAX (PROJ_KEY) INTO PROJ_KEY_MAX FROM PCS_PROJ;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY ' || PROJ_KEY_MAX;
    SELECT PCS_PROJ_KEY_SEQ.NEXTVAL INTO PROJ_KEY_CURRVAL FROM DUAL;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY 1';

END;
END;
/

Ця збережена процедура перезавантажує мою послідовність:

Create or Replace Procedure Reset_Sequence  
  is
  SeqNbr Number;
begin
   /*  Reset Sequence 'seqXRef_RowID' to 0    */
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by - ' || TO_CHAR(SeqNbr) ;
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by 1';
END;

/

Існує ще один спосіб скидання послідовності в Oracle: встановіть maxvalueі cycleвластивості. Коли параметр nextvalпослідовності потрапить у maxvalue, якщо cycleвластивість встановлено, вона почнеться знову з minvalueпослідовності.

Перевага цього методу порівняно з встановленням негативу increment byполягає в тому, що послідовність може продовжувати використовуватися під час запуску процесу скидання, зменшуючи ймовірність, що вам потрібно скористатися певною формою відключення, щоб зробити скидання.

Значення для maxvalueмає бути більшим, ніж поточне nextval, тому нижче наведена процедура включає необов'язковий параметр, що дозволяє створювати буфер у випадку, коли повторний доступ до послідовності між вибором nextvalу процедурі та встановленням cycleвластивості.

create sequence s start with 1 increment by 1;

select s.nextval from dual
connect by level <= 20;

   NEXTVAL
----------
         1 
...
        20

create or replace procedure reset_sequence ( i_buffer in pls_integer default 0)
as
  maxval pls_integer;
begin

  maxval := s.nextval + greatest(i_buffer, 0); --ensure we don't go backwards!
  execute immediate 'alter sequence s cycle minvalue 0 maxvalue ' || maxval;
  maxval := s.nextval;
  execute immediate 'alter sequence s nocycle maxvalue 99999999999999';

end;
/
show errors

exec reset_sequence;

select s.nextval from dual;

   NEXTVAL
----------
         1 

Процедура як стенд все ще дозволяє можливість, що інший сеанс отримає значення 0, що може бути, а може і не бути проблемою для вас. Якщо це так, ви завжди можете:

• Встановити minvalue 1в першому альтері
• Виключіть другий nextvalзбір
• Перемістіть оператор, щоб встановити nocycleвластивість в іншу процедуру, яку слід запустити пізніше (при умові, що ви хочете це зробити).

Jezus, все це програмування лише для перезавантаження індексу ... Можливо, я ідіот, але для pre-oracle 12 (який має функцію перезавантаження), що не так з simpel:

drop sequence blah;
create sequence blah 

?

1) Припустимо, ви створили ПОСЛІДКУ, як показано нижче:

CREATE SEQUENCE TESTSEQ
INCREMENT BY 1
MINVALUE 1
MAXVALUE 500
NOCACHE
NOCYCLE
NOORDER

2) Тепер ви отримуєте значення з SEQUENCE. Скажімо, я зібрав чотири рази, як показано нижче.

SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual

3) Після виконання вище чотирьох команд значення SEQUENCE буде 4. Тепер припустимо, що я знову встановив значення SEQUENCE на 1. Виконайте наступні кроки. Виконайте всі дії в тому ж порядку, як показано нижче:

1. ALTER SEQUENCE TESTSEQ INCREMENT BY -3;
2. SELECT TESTSEQ.NEXTVAL FROM dual
3. ALTER SEQUENCE TESTSEQ INCREMENT BY 1;
4. SELECT TESTSEQ.NEXTVAL FROM dual

Змінення значення INCREMENT послідовності, збільшуючи її, а потім змінюючи її назад, є досить безболісним, плюс у вас є додаткова перевага від того, що вам не доведеться відновлювати всі гранти, як ви б відмовились / відтворили послідовність.

Я створюю блок для скидання всіх моїх послідовностей:

DECLARE
    I_val number;
BEGIN
    FOR US IN
        (SELECT US.SEQUENCE_NAME FROM USER_SEQUENCES US)
    LOOP
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by -' || l_val || ' minvalue 0';
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by 1 minvalue 0';
    END LOOP;
END;

Ось більш надійний порядок зміни наступного значення, поверненого послідовністю, плюс ще багато іншого.

• По-перше, він захищає від атак ін'єкцій SQL, оскільки жоден з переданих рядків не використовується для створення будь-якого динамічного оператора SQL,
• По-друге, це запобігає встановленню значення наступної послідовності поза межами значень min або max. next_valueБуде! = min_valueІ між min_valueіmax_value .
• По-третє, він приймає поточний (або запропонований) increment_by настройку, а також всі інші параметри послідовності при очищенні.
• По-четверте, всі параметри, крім першого, не є обов'язковими, і якщо не вказано, приймайте поточні параметри послідовності за замовчуванням. Якщо не вказані необов'язкові параметри, не вживаються дії.
• Нарешті, якщо ви спробуєте змінити послідовність, яка не існує (або не належить поточному користувачеві), це призведе до ORA-01403: no data foundпомилки.

Ось код:

CREATE OR REPLACE PROCEDURE alter_sequence(
    seq_name      user_sequences.sequence_name%TYPE
  , next_value    user_sequences.last_number%TYPE := null
  , increment_by  user_sequences.increment_by%TYPE := null
  , min_value     user_sequences.min_value%TYPE := null
  , max_value     user_sequences.max_value%TYPE := null
  , cycle_flag    user_sequences.cycle_flag%TYPE := null
  , cache_size    user_sequences.cache_size%TYPE := null
  , order_flag    user_sequences.order_flag%TYPE := null)
  AUTHID CURRENT_USER
AS
  l_seq user_sequences%rowtype;
  l_old_cache user_sequences.cache_size%TYPE;
  l_next user_sequences.min_value%TYPE;
BEGIN
  -- Get current sequence settings as defaults
  SELECT * INTO l_seq FROM user_sequences WHERE sequence_name = seq_name;

  -- Update target settings
  l_old_cache := l_seq.cache_size;
  l_seq.increment_by := nvl(increment_by, l_seq.increment_by);
  l_seq.min_value    := nvl(min_value, l_seq.min_value);
  l_seq.max_value    := nvl(max_value, l_seq.max_value);
  l_seq.cycle_flag   := nvl(cycle_flag, l_seq.cycle_flag);
  l_seq.cache_size   := nvl(cache_size, l_seq.cache_size);
  l_seq.order_flag   := nvl(order_flag, l_seq.order_flag);

  IF next_value is NOT NULL THEN
    -- Determine next value without exceeding limits
    l_next := LEAST(GREATEST(next_value, l_seq.min_value+1),l_seq.max_value);

    -- Grab the actual latest seq number
    EXECUTE IMMEDIATE
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY 1'
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number-l_old_cache)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
    EXECUTE IMMEDIATE 
      'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
    INTO l_seq.last_number;

    l_next := l_next-l_seq.last_number-1;

    -- Reset the sequence number
    IF l_next <> 0 THEN
      EXECUTE IMMEDIATE 
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY '||l_next
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
      EXECUTE IMMEDIATE 
        'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
      INTO l_next;
    END IF;
  END IF;

  -- Prepare Sequence for next use.
  IF COALESCE( cycle_flag
             , next_value
             , increment_by
             , min_value
             , max_value
             , cache_size
             , order_flag) IS NOT NULL
  THEN
    EXECUTE IMMEDIATE 
      'ALTER SEQUENCE '||l_seq.sequence_name
          || ' INCREMENT BY '||l_seq.increment_by
          || ' MINVALUE '||l_seq.min_value
          || ' MAXVALUE '||l_seq.max_value
          || CASE l_seq.cycle_flag
             WHEN 'Y' THEN ' CYCLE' ELSE ' NOCYCLE' END
          || CASE l_seq.cache_size
             WHEN 0 THEN ' NOCACHE'
             ELSE ' CACHE '||l_seq.cache_size END
          || CASE l_seq.order_flag
             WHEN 'Y' THEN ' ORDER' ELSE ' NOORDER' END;
  END IF;
END;

У моєму проекті, як тільки трапилося, що хтось вручну вводив записи, не використовуючи послідовність, отже, я повинен скинути значення послідовності вручну, для чого я написав нижче фрагмент коду sql:

declare
max_db_value number(10,0);
cur_seq_value number(10,0);
counter number(10,0);
difference number(10,0);
dummy_number number(10);

begin

-- enter table name here
select max(id) into max_db_value from persons;
-- enter sequence name here
select last_number into cur_seq_value from user_sequences where  sequence_name = 'SEQ_PERSONS';

difference  := max_db_value - cur_seq_value;

 for counter in 1..difference
 loop
    -- change sequence name here as well
    select SEQ_PERSONS.nextval into dummy_number from dual;
 end loop;
end;

Зверніть увагу, що наведений вище код буде працювати, якщо послідовність відстає.

Ви можете скористатися параметром CYCLE, показаним нижче:

CREATE SEQUENCE test_seq
MINVALUE 0
MAXVALUE 100
START WITH 0
INCREMENT BY 1
CYCLE;

У цьому випадку, коли послідовність досягне MAXVALUE (100), вона переробить у MINVALUE (0).

У випадку зменшеної послідовності послідовність буде повторно перетворена на MAXVALUE.

Ось як зробити так, щоб усі послідовності автоматичного збільшення збігалися з фактичними даними:

1. Створіть процедуру для застосування наступного значення, як уже було описано в цій темі:

   CREATE OR REPLACE PROCEDURE Reset_Sequence(
       P_Seq_Name IN VARCHAR2,
       P_Val      IN NUMBER DEFAULT 0)
   IS
     L_Current    NUMBER                      := 0;
     L_Difference NUMBER                      := 0;
     L_Minvalue User_Sequences.Min_Value%Type := 0;
   BEGIN
     SELECT Min_Value
     INTO L_Minvalue
     FROM User_Sequences
     WHERE Sequence_Name = P_Seq_Name;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Current;
     IF P_Val        < L_Minvalue THEN
       L_Difference := L_Minvalue - L_Current;
     ELSE
       L_Difference := P_Val - L_Current;
     END IF;
     IF L_Difference = 0 THEN
       RETURN;
     END IF;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by ' || L_Difference || ' minvalue ' || L_Minvalue;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Difference;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by 1 minvalue ' || L_Minvalue;
   END Reset_Sequence;

2. Створіть ще одну процедуру для узгодження всіх послідовностей з фактичним вмістом:

   CREATE OR REPLACE PROCEDURE RESET_USER_SEQUENCES_TO_DATA
   IS
     STMT CLOB;
   BEGIN
     SELECT 'select ''BEGIN'' || chr(10) || x || chr(10) || ''END;'' FROM (select listagg(x, chr(10)) within group (order by null) x FROM ('
       || X
       || '))'
     INTO STMT
     FROM
       (SELECT LISTAGG(X, ' union ') WITHIN GROUP (
       ORDER BY NULL) X
       FROM
         (SELECT CHR(10)
           || 'select ''Reset_Sequence('''''
           || SEQ_NAME
           || ''''','' || coalesce(max('
           || COL_NAME
           || '), 0) || '');'' x from '
           || TABLE_NAME X
         FROM
           (SELECT TABLE_NAME,
             REGEXP_SUBSTR(WTEXT, 'NEW\.(\S*) IS NULL',1,1,'i',1) COL_NAME,
             REGEXP_SUBSTR(BTEXT, '(\.|\s)([a-z_]*)\.nextval',1,1,'i',2) SEQ_NAME
           FROM USER_TRIGGERS
           LEFT JOIN
             (SELECT NAME BNAME,
               TEXT BTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%NEXTVAL%'
             )
           ON BNAME = TRIGGER_NAME
           LEFT JOIN
             (SELECT NAME WNAME,
               TEXT WTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%IS NULL%'
             )
           ON WNAME             = TRIGGER_NAME
           WHERE TRIGGER_TYPE   = 'BEFORE EACH ROW'
           AND TRIGGERING_EVENT = 'INSERT'
           )
         )
       ) ;
     EXECUTE IMMEDIATE STMT INTO STMT;
     --dbms_output.put_line(stmt);
     EXECUTE IMMEDIATE STMT;
   END RESET_USER_SEQUENCES_TO_DATA;

ПРИМІТКИ:

1. Процедура витягує імена з тригерного коду і не залежить від умов іменування
2. Щоб перевірити згенерований код перед виконанням, переключіть коментарі на останні два рядки

Я роблю альтернативу, що користувачеві не потрібно знати значення, система отримує і використовує змінні для оновлення.

--Atualizando sequence da tabela SIGA_TRANSACAO, pois está desatualizada
DECLARE
 actual_sequence_number INTEGER;
 max_number_from_table INTEGER;
 difference INTEGER;
BEGIN
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number FROM DUAL;
 SELECT MAX([nome_da_coluna]) INTO max_number_from_table FROM [nome_da_tabela];
 SELECT (max_number_from_table-actual_sequence_number) INTO difference FROM DUAL;
IF difference > 0 then
 EXECUTE IMMEDIATE CONCAT('alter sequence [nome_da_sequence] increment by ', difference);
 --aqui ele puxa o próximo valor usando o incremento necessário
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number from dual;
--aqui volta o incremento para 1, para que futuras inserções funcionem normalmente
 EXECUTE IMMEDIATE 'ALTER SEQUENCE [nome_da_sequence] INCREMENT by 1';
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] foi atualizada.');
ELSE
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] NÃO foi atualizada, já estava OK!');
END IF;
END;

Збережена процедура, яка працювала на мене

create or replace
procedure reset_sequence( p_seq_name in varchar2, tablename in varchar2 )
is
    l_val number;
    maxvalueid number;
begin
    execute immediate 'select ' || p_seq_name || '.nextval from dual' INTO l_val;
    execute immediate 'select max(id) from ' || tablename INTO maxvalueid;
    execute immediate 'alter sequence ' || p_seq_name || ' increment by -' || l_val || ' minvalue 0';
    execute immediate 'select ' || p_seq_name || '.nextval from dual' INTO l_val;
    execute immediate 'alter sequence ' || p_seq_name || ' increment by '|| maxvalueid ||' minvalue 0';  
    execute immediate 'select ' || p_seq_name || '.nextval from dual' INTO l_val;
    execute immediate 'alter sequence ' || p_seq_name || ' increment by 1 minvalue 0';
end;

Як використовувати збережену процедуру:

execute reset_sequence('company_sequence','company');