Простий спосіб друку масиву Perl? (з невеликим форматуванням)

Чи є простий спосіб роздрукувати масив Perl з комами між кожним елементом?

Написати цикл for для цього досить просто, але не зовсім елегантно .... якщо це має сенс.

Просто використовуйте join():

# assuming @array is your array:
print join(", ", @array);

Ви можете використовувати Data::Dump:

use Data::Dump qw(dump);
my @a = (1, [2, 3], {4 => 5});
dump(@a);

Виробляє:

"(1, [2, 3], { 4 => 5 })"

Якщо ви кодуєте для такої ясності, яку зрозумів би той, хто тільки починає з Perl, традиційна ця конструкція з високим ступенем чіткості та читабельності говорить, що це означає:

$string = join ', ', @array;
print "$string\n";

Ця конструкція задокументована у perldoc -fjoin.

Однак мені завжди подобалося, як просто $,це робить. Спеціальна змінна $"призначена для інтерполяції, а спеціальна змінна $,- для списків. Поєднуйте будь-яку з динамічних обмежень обсягу ' local', щоб уникнути ефектів пульсацій у всьому сценарії:

use 5.012_002;
use strict;
use warnings;

my @array = qw/ 1 2 3 4 5 /;

{
    local $" = ', ';
    print "@array\n"; # Interpolation.
}

АБО з $ ,:

use feature q(say);
use strict;
use warnings;

my @array = qw/ 1 2 3 4 5 /;
{
    local $, = ', ';
    say @array; # List
}

Спеціальні змінні $,і $"задокументовані в perlvar . localКлючові слова, і як його можна використовувати , щоб обмежити вплив зміни значення глобальної змінної пунктуації є , ймовірно , найкраще описані в perlsub .

Насолоджуйтесь!

Крім того, ви можете спробувати Data :: Dumper . Приклад:

use Data::Dumper;

# simple procedural interface
print Dumper($foo, $bar);

Для перевірки / налагодження перевірте Data::Printerмодуль. Це означає робити одне і лише одне:

відображати на екрані змінні та об'єкти Perl, правильно відформатовані (для перевірки людиною)

Приклад використання:

use Data::Printer;  
p @array;  # no need to pass references

У наведеному вище коді може бути виведено щось подібне (з кольорами!):

   [
       [0] "a",
       [1] "b",
       [2] undef,
       [3] "c",
   ]

Ви можете просто printце.

@a = qw(abc def hij);

print "@a";

Ви отримаєте:

abc def hij

# better than Dumper --you're ready for the WWW....

use JSON::XS;
print encode_json \@some_array

Використання Data::Dumper:

use strict;
use Data::Dumper;

my $GRANTstr = 'SELECT, INSERT, UPDATE, DELETE, LOCK TABLES, EXECUTE, TRIGGER';
$GRANTstr    =~ s/, /,/g;
my @GRANTs   = split /,/ , $GRANTstr;

print Dumper(@GRANTs) . "===\n\n";

print Dumper(\@GRANTs) . "===\n\n";

print Data::Dumper->Dump([\@GRANTs], [qw(GRANTs)]);

Генерує три різні стилі виводу:

$VAR1 = 'SELECT';
$VAR2 = 'INSERT';
$VAR3 = 'UPDATE';
$VAR4 = 'DELETE';
$VAR5 = 'LOCK TABLES';
$VAR6 = 'EXECUTE';
$VAR7 = 'TRIGGER';
===

$VAR1 = [
          'SELECT',
          'INSERT',
          'UPDATE',
          'DELETE',
          'LOCK TABLES',
          'EXECUTE',
          'TRIGGER'
        ];
===

$GRANTs = [
            'SELECT',
            'INSERT',
            'UPDATE',
            'DELETE',
            'LOCK TABLES',
            'EXECUTE',
            'TRIGGER'
          ];

Це може бути не те, що ви шукаєте, але ось щось я зробив для завдання:

$" = ", ";
print "@ArrayName\n";

Карту також можна використовувати, але іноді важко читати, коли у вас багато справ.

map{ print "element $_\n" }   @array; 

Однак я не намагався пробігти нижче. Я думаю, це хитрий спосіб.

map{print $_;} @array;