Висловлення подвійної послідовності підсумовування в Раку

Як виразити подвійну змінну послідовності подвійного підсумовування в Perl 6?

Для прикладу подвійної змінної послідовності подвійного підсумовування див

Він повинен бути виражений таким, який є, тобто без математичного зведення подвійного підсумовування в єдине підсумовування. Дякую.

X(Крос - оператор) і [+](зменшення metaoperator [ ]з адитивним оператором +) роблять це на подив легко:

Щоб представити ¹ подвійне підсумовування ∑³ _{x  = 1} ∑⁵ _{y  = 1} 2x + y , ви можете зробити наступне:

  [+] do for 1..3 X 1..5 -> ($x, $y) { 2 * $x + $y }
#        for 1..3 X 1..5                             # loop cross values
#                        -> ($x, $y)                 # plug into x/y
#                                    { 2 * $x + $y } # calculate each iteration
#     do                                             # collect loop return vals 
# [+]                                                # sum them all

Якщо ви хочете створити subдля цього, ви можете написати це як наступне ²

sub ΣΣ (
    Int $aₒ, Int $aₙ,     # to / from for the outer
    Int $bₒ, Int $bₙ,     # to / from for the inner
    &f where .arity = 2   # 'where' clause guarantees only two params
) {
  [+] do for $aₒ..$aₙ X $bₒ..$bₙ -> ($a, $b) { &f(a,b) }
}

say ΣΣ 1,3, 1,5, { 2 * $^x + $^y }

Або навіть ще більше спростити речі

sub ΣΣ (
    Iterable \a,            # outer values
    Iterable \b,            # inner values
    &f where .arity = 2) {  # ensure only two parameters
  [+] do f(|$_) for a X b
}

# All of the following are equivalent
say ΣΣ 1..3, 1..5, -> $x, $y { 2 * $x  + $y  }; # Anonymous block
say ΣΣ 1..3, 1..5,           { 2 * $^x + $^y }; # Alphabetic args
say ΣΣ 1..3, 1..5,             2 *  *  +  *   ; # Overkill, but Whatever ;-) 

Зауважимо, що, ввівши його, ми можемо забезпечити передачу діапазонів, але, ввівши його як Iterableшвидше, ніж Rangeми можемо дозволити більш цікаві послідовності підсумовування, як, скажімо, ΣΣ (1..∞).grep(*.is-prime)[^99], 1..10, { … }що дозволило б нам використовувати послідовність перших 100 простих чисел.

Насправді, якби ми насправді цього хотіли, ми могли б перейти за борт і дозволити довільний оператор підсумовування глибини, що найпростіше зробити, перемістивши функцію вліво:

sub ΣΣ (
    &function, 
    **@ranges where                # slurp in the ranges
        .all   ~~ Iterable &&      # make sure they're Iterables 
        .elems == &function.arity  # one per argument in the function
) {
  [+] do function(|$_) for [X] @ranges;
};

Так само, як [+]підсумовує всі значення нашої f()функції, [X]обчислює крос ітераційно, наприклад, [X] 0..1, 3..4, 5..6спочатку робить 0..1 X 3..4або (0,3),(0,4),(1,3),(1,4), а потім робить (0,3),(0,4),(1,3),(1,4) X 5..6, або (0,3,5),(0,4,5),(1,3,5),(1,4,5),(0,3,6),(0,4,6),(1,3,6),(1,4,6).

^{1. Вибачте, так що я не дозволяю мені робити LaTeX, але ви повинні отримати ідею. 2. Так, я знаю, що це підписний лист O не нуль, номери індексів не є дійсними ідентифікаторами, але ви можете використовувати Slang :: Subscripts для їх включення.}