Як написати сценарій очікування для встановлення mariadb?

Навколишнє середовище: centos7 + mariadb5.5.64.
Дозвольте мені показати інформацію про встановлення на екрані, коли потрібно запустити mysql_secure_installation.

# mysql_secure_installation

NOTE: RUNNING ALL PARTS OF THIS SCRIPT IS RECOMMENDED FOR ALL MariaDB
      SERVERS IN PRODUCTION USE!  PLEASE READ EACH STEP CAREFULLY!

In order to log into MariaDB to secure it, we'll need the current
password for the root user.  If you've just installed MariaDB, and
you haven't set the root password yet, the password will be blank,
so you should just press enter here.

Enter current password for root (enter for none): 
OK, successfully used password, moving on...

Setting the root password ensures that nobody can log into the MariaDB
root user without the proper authorisation.

Set root password? [Y/n] y
New password: 
Re-enter new password: 
Password updated successfully!
Reloading privilege tables..
 ... Success!


By default, a MariaDB installation has an anonymous user, allowing anyone
to log into MariaDB without having to have a user account created for
them.  This is intended only for testing, and to make the installation
go a bit smoother.  You should remove them before moving into a
production environment.

Remove anonymous users? [Y/n] y
 ... Success!

Normally, root should only be allowed to connect from 'localhost'.  This
ensures that someone cannot guess at the root password from the network.

Disallow root login remotely? [Y/n] y
 ... Success!

By default, MariaDB comes with a database named 'test' that anyone can
access.  This is also intended only for testing, and should be removed
before moving into a production environment.

Remove test database and access to it? [Y/n] y
 - Dropping test database...
 ... Success!
 - Removing privileges on test database...
 ... Success!

Reloading the privilege tables will ensure that all changes made so far
will take effect immediately.

Reload privilege tables now? [Y/n] y
 ... Success!

Cleaning up...

All done!  If you've completed all of the above steps, your MariaDB
installation should now be secure.

Thanks for using MariaDB!

Я пишу сценарій очікування автоматизації для встановлення mariadb.

  vim secure.exp
  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? [Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? [Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? [Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? [Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? [Y/n]" {send "y\r";exp_continue}
  }

Для виконання /usr/bin/expect secure.expя зіткнувся з помилкою:

spawn mysql_secure_installation
invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
          "Enter current password for root (enter for none): " {send "\r";exp_continue}
          "Set root password? [Y/n] " {send "y\r";exp..."
    (file "secure.exp" line 3)

Немає сенсу писати як нижче:

  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? \\[Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? \\[Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? \\[Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? \\[Y/n]" {send "y\r";exp_continue}
  }

Та ж помилка:

invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_conti..."
    (file "secure.exp" line 3)

Як виправити мій сценарій exp тоді?

Ці сценарії чекають отримання необов'язкового виводу ( timeout -1означає "немає часу очікування"), і вони можуть розрізняти різні відповіді, як цього вимагає yum installі mysql_secure_installation. З #!/bin/expect -fshebang, сценарії можуть бути виконані, коли вони були встановлені chmod +x.

А) Для початку mariadb_yum.exp(потрібно suабо sudo):

#!/bin/expect -f
set timeout 30
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_yum.exp \[linux sudo password\]\n"
    exit 1
}
set USERNAME "[exec whoami]"
set PASSWORD [lindex $argv 0];

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/$USERNAME/mariadb_install.log"

spawn sudo yum -y install MariaDB-server
set yum_spawn_id $spawn_id

# On GCE it will never ask for a sudo password:
expect -ex "\[sudo\] password for $USERNAME: " {
   exp_send "$PASSWORD\r"
}

expect {
    # when the package was already installed
    -ex "Nothing to do" {
        send_user "package was already installed\n"
    }
    # when the package had been installed
    -ex "Complete!" {
        send_user "package had been installed\n"
    }
}

expect eof
close $yum_spawn_id
exit 0

В) А потім mariadb_sec.exp(не вимагає sudo):

#!/bin/expect -f
set timeout 1
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_sec.exp \[mysql root password\]\n"
    exit 1
}
set PASSWORD [lindex $argv 0];

spawn mysql_secure_installation
set mysql_spawn_id $spawn_id

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/[exec whoami]/mariadb_install.log"

# when there is no password set, this probably should be "\r"
expect -ex "Enter current password for root (enter for none): "
exp_send "$PASSWORD\r"

expect {
    # await an eventual error message
    -ex "ERROR 1045" {
        send_user "\nMariaDB > An invalid root password had been provided.\n"
        close $mysql_spawn_id
        exit 1
    }
    # when there is a root password set
    -ex "Change the root password? \[Y/n\] " {
        exp_send "n\r"
    }
    # when there is no root password set (could not test this branch).
    -ex "Set root password? \[Y/n\] " {
        exp_send "Y\r"
        expect -ex "New password: "
        exp_send "$PASSWORD\r"
        expect -ex "Re-enter new password: "
        exp_send "$PASSWORD\r"
    }
}
expect -ex "Remove anonymous users? \[Y/n\] "
exp_send "Y\r"
expect -ex "Disallow root login remotely? \[Y/n\] "
exp_send "Y\r"
expect -ex "Remove test database and access to it? \[Y/n\] "
exp_send "Y\r"
expect -ex "Reload privilege tables now? \[Y/n\] "
exp_send "Y\r"

expect eof
close $mysql_spawn_id
exit 0

Для налагодження - або для підтвердження відповіді можна працювати expectз рівнем журналу strace 4. Це, напевно, так само поважно, як і джерело, що стосується написання expectсценаріїв, оскільки воно добре відображає те, що відбувається, і найголовніше, в якому порядку відбуваються речі:

expect -c "strace 4" ./mariadb_yum.exp [linux sudo password]
expect -c "strace 4" ./mariadb_sec.exp [mysql root password]

Інструкція set exp_internal 1може бути використана для отримання результатів для збігу регулярних виразів.

Можливим джерелом плутанини може бути те, коли можна породжувати процеси - так як можна породити кілька процесів на різних хостах, наприклад. sshлокально, а потім yumі mysql_secure_installationвіддалено. Додано $spawn_idдо сценарію; нижній closeвиклик може бути зайвим, оскільки він вже є EOF(просто показати, як spawnі як close):

Thanks for using MariaDB!
 1  close $mysql_spawn_id
 1  exit 0
 2  rename _close.pre_expect close

Висновок: mariadb_sec.expсценарій, ймовірно, міг би бути вдосконалений далі, наприклад. коли спочатку не надсилаєш пароль і бачиш, що трапиться, - потім надсилаєш пароль ERROR 1045(коли вже був встановлений пароль). Можна припустити, що потрібно встановити пароль після встановлення сервера (за винятком того, що він yum reinstallдає такий же результат). Просто не було порожнього контейнера CentOS для перевірки всіх справ. Якщо не працювати в rootоболонці, для автоматизації цього процесу від встановлення до пост-інсталяції потрібно буде передавати обидва види паролів в один сценарій.

Мабуть, варто зазначити, що на GCE sudoне запитували пароль; дійсно є незначні відмінності залежно від середовища, оскільки ці зображення контейнерів CentOS поводяться по-різному. У такому випадку (оскільки немає suмісця виявлення або образу контейнера), mariadb_yum.expсценарій може застрягнути на 30секунди, а потім продовжити.

expectНайповажніші джерела, які я можу запропонувати, - це посібник, написаний Don Libes @ NIST, і посібник TCL / TK для expect, разом із проектом SourceForge expect.

Квадратні дужки використовуються не тільки для заміни команд, але й спеціальні для глобальних моделей .

Ви можете використовувати -exactперемикач, уникаючи квадратних дужок у лапках:

spawn mysql_secure_installation
expect {
    ...
    -exact "Set root password? \[Y/n\] " {send "y\r";exp_continue}
    ...
}

Або використовуйте дужки замість лапок:

spawn mysql_secure_installation
expect {
    ...
    {Set root password? \[Y/n\] } {send "y\r";exp_continue}
    ...
}

FYI, ви можете створити сценарій очікування для вас, використовуючи autoexpect:

autoexpect ./mysql_secure_installation

Це створить сценарій очікування, викликаний script.expу вашому поточному робочому каталозі.