TSQL - Як використовувати GO всередині блоку BEGIN .. END?

Я створюю скрипт для автоматичного перенесення змін з декількох баз даних розробки в індексування / виробництво. В основному, для цього потрібна купа сценаріїв змін і об’єднується в один сценарій, обертаючи кожен сценарій у IF whatever BEGIN ... ENDвиписку.

Однак деякі сценарії вимагають GOоператора, щоб, наприклад, аналізатор SQL знав про новий стовпець після його створення.

ALTER TABLE dbo.EMPLOYEE 
ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO -- Necessary, or next line will generate "Unknown column:  EMP_IS_ADMIN"
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Однак, як тільки я загортаю це в IFблок:

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
    GO
    UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever
END

Це не вдається, тому що я надсилаю BEGINбез відповідності END. Однак, якщо я видалю це, GOвін знову скаржиться на невідому колонку.

Чи є спосіб створити та оновити один і той же стовпець у межах одного IFблоку?

У мене була та сама проблема, і нарешті вдалося її вирішити за допомогою SET NOEXEC .

IF not whatever
BEGIN
    SET NOEXEC ON; 
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

SET NOEXEC OFF; 

GO не є SQL - це просто пакетний роздільник, який використовується в деяких інструментах MS SQL.

Якщо ви цього не використовуєте, вам потрібно переконатися, що оператори виконуються окремо - або різними пакетами, або за допомогою динамічного SQL для популяції (спасибі @gbn):

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL;

    EXEC ('UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever')
END

Ви можете спробувати sp_executesql , розділивши вміст між кожним GOоператором на окремий рядок для виконання, як показано в прикладі нижче. Крім того, існує змінна @statementNo для відстеження того, який оператор виконується для легкого налагодження, де сталося виняток. Номери рядків будуть відносно початку відповідного номера виписки, що спричинив помилку.

BEGIN TRAN

DECLARE @statementNo INT
BEGIN TRY
    IF 1=1
    BEGIN
        SET @statementNo = 1
        EXEC sp_executesql
            N'  ALTER TABLE dbo.EMPLOYEE
                    ADD COLUMN EMP_IS_ADMIN BIT NOT NULL'

        SET @statementNo = 2
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1'

        SET @statementNo = 3
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1x'
    END
END TRY
BEGIN CATCH
    PRINT 'Error occurred on line ' + cast(ERROR_LINE() as varchar(10)) 
       + ' of ' + 'statement # ' + cast(@statementNo as varchar(10)) 
       + ': ' + ERROR_MESSAGE()
    -- error occurred, so rollback the transaction
    ROLLBACK
END CATCH
-- if we were successful, we should still have a transaction, so commit it
IF @@TRANCOUNT > 0
    COMMIT

Ви також можете легко виконати багаторядкові оператори, як продемонстровано у прикладі вище, просто обернувши їх в одинарні лапки ( '). Не забувайте уникати будь-яких одинарних лапок, що містяться всередині рядка, з подвійними одинарними лапками ( '') під час створення сценаріїв.

Зрештою, я змусив це працювати, замінивши кожен екземпляр у GOсвоєму рядку на

END
GO

---Automatic replacement of GO keyword, need to recheck IF conditional:
IF whatever
BEGIN

Це набагато краще, ніж обгортання кожної групи тверджень у рядок, але все ще далеке від ідеалу. Якщо хтось знайде краще рішення, опублікуйте його, і я натомість прийму його.

Ви можете вкласти заяви в BEGIN та END замість GO між ними

IF COL_LENGTH('Employees','EMP_IS_ADMIN') IS NULL --Column does not exist
BEGIN
    BEGIN
        ALTER TABLE dbo.Employees ADD EMP_IS_ADMIN BIT
    END

    BEGIN
        UPDATE EMPLOYEES SET EMP_IS_ADMIN = 0
    END
END

(Перевірено на базі даних Northwind)

Редагувати: (Можливо, перевірено на SQL2012)

Ви можете спробувати це рішення:

if exists(
SELECT...
)
BEGIN
PRINT 'NOT RUN'
RETURN
END

--if upper code not true

ALTER...
GO
UPDATE...
GO

Я використовував RAISERRORу минулому для цього

IF NOT whatever BEGIN
    RAISERROR('YOU''RE ALL SET, and sorry for the error!', 20, -1) WITH LOG
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Ви можете включити оператори a GOTOта LABELоператори, щоб пропустити код, таким чином залишаючи GOключові слова недоторканими.