Пакетний файл. Видаліть усі файли та папки в каталозі

Я хочу мати пакетний файл, який видалить усі папки та файли в папці кешу для мого бездротового набору інструментів.

На даний момент у мене є:

cd "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS"
del *.db

Це видалить усі .db файли в моєму каталозі RMS , проте я хочу видалити кожну річ з цього каталогу. Як я можу це зробити?

del *.*замість del *.db. Це прибере все.

Використання:

• Створіть пакетний файл

• Скопіюйте нижченаведений текст у пакетний файл

  set folder="C:\test"
  cd /d %folder%
  for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
  

Це видалить усі файли та папки.

IF EXIST "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" (
    rmdir "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" /s /q
)

Це видалить усе з папки (і самої папки).

del *.*буде видалено лише файли, але не підкаталоги. Для видалення вмісту каталогу ви можете використовувати цей сценарій:

@echo off
setlocal enableextensions
if {%1}=={} goto :HELP
if {%1}=={/?} goto :HELP
goto :START

:HELP
echo Usage: %~n0 directory-name
echo.
echo Empties the contents of the specified directory,
echo WITHOUT CONFIRMATION. USE EXTREME CAUTION!
goto :DONE

:START
pushd %1 || goto :DONE
rd /q /s . 2> NUL
popd

:DONE
endlocal

У pushdзмінах в каталог якого ви хочете видалити дитина. Тоді, коли rdзапитується видалити поточний каталог та всі підкаталоги, видалення підкаталогів успішно, але видалення поточного каталогу не вдається - тому що ми знаходимося в ньому. Це призводить до помилки, яка 2> NULпроковтує. (2 - потік помилок).

Я просто склав це з того, що розмістив morty346:

set folder="C:\test"
IF EXIST "%folder%" (
    cd /d %folder%
    for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
)

Це додає швидку перевірку того, що папка, визначена у змінній, існує спочатку, змінює каталог у папку та видаляє вміст.

Ви можете зробити це з допомогою delі на /Sпрапор (щоб сказати йому рекурсию всі файли з усіх підкаталогів):

del /S C:\Path\to\directory\*

Команда RD також може бути використана. Рекурсивно видаляйте тихо, без підказки:

@RD /S /Q %VAR_PATH%

Rmdir (rd)

set "DIR_TO_DELETE=your_path_to_the_folder"

IF EXIST %DIR_TO_DELETE% (
    FOR /D %%p IN ("%DIR_TO_DELETE%\*.*") DO rmdir "%%p" /S /Q
    del %DIR_TO_DELETE%\*.* /F /Q
)

Спробуйте наступне; це працює для мене.

У мене є додаток, який скидає дані в папку "C: \ tmp", і наступне працює найкраще для мене. Він навіть не вимагає " Так" або " Ні" для видалення даних. Я склав графік, щоб він працював через кожні 5 хвилин

cd "C:\tmp"

del *.* /Q

Ще краще, скажімо, я хочу видалити все з C:\windows\tempпапки.

@echo off
rd C:\windows\temp /s /q

Ви можете використовувати робокопію, щоб відобразити порожню папку в папці, яку ви очищаєте.

robocopy "C:\temp\empty" "C:\temp\target" /E /MIR

Він також працює, якщо ви не можете видалити або відтворити фактичну папку.

Тут потрібен порожній каталог.

Використовуйте

set dir="Your Folder Path Here"
rmdir /s %dir%
mkdir %dir%

Ця версія видаляється, не запитуючи:

set dir="Your Folder Here"
rmdir /s /q %dir%
mkdir %dir%

Приклад:

set dir="C:\foo1\foo\foo\foo3"
rmdir /s /q %dir%
mkdir %dir%

Це зрозуміє C:\foo1\foo\foo\foo3.

_{(Я хотів би згадати відповідь Абдулла Сабуїна . Про те, що я копіював його, виник мікс. Я його не помітив. Я хотів би подякувати вам мельпомени за вказівку на помилки!)}

Ви не можете видалити все за допомогою одного rmdirабо delодного:

• rmdir /s /qне приймає символи підстановки. Так rmdir /s /q *буде помилка.
• del /s /f /q видалить усі файли, але порожні підкаталоги залишаться.

Моє бажане рішення (як я використовував у багатьох інших пакетних файлах):

rmdir /s /q . 2>NUL

Просто модифікована версія відповіді GregM :

set folder="C:\test"
cd /D %folder%
if NOT %errorlevel% == 0 (exit /b 1)
echo Entire content of %cd% will be deleted. Press Ctrl-C to abort
pause

REM First the directories /ad option of dir
for /F "delims=" %%i in ('dir /b /ad') do (echo rmdir "%%i" /s/q)

REM Now the files /a-d option of dir
for /F "delims=" %%i in ('dir /b /a-d') do (echo del "%%i" /q)

REM To deactivate simulation mode remove the word 'echo' before 'rmdir' and 'del'.

@echo off
@color 0A

echo Deleting logs

rmdir /S/Q c:\log\

ping 1.1.1.1 -n 5 -w 1000 > nul

echo Adding log folder back

md c:\log\

Ви були на правильному шляху. Просто додайте код, щоб додати папку, яку знову видалено.

Ви повинні запустити цю команду, щоб видалити всі файли:

del*.*