Oracle PL / SQL - Як створити просту змінну масиву?

Я хотів би створити змінну масиву в пам'яті, яку можна використовувати в моєму коді PL / SQL. Я не можу знайти жодної колекції в Oracle PL / SQL, яка використовує чисту пам'ять, вони, схоже, пов'язані з таблицями. Я хочу зробити щось подібне в моєму PL / SQL (синтаксис C #):

string[] arrayvalues = new string[3] {"Matt", "Joanne", "Robert"};

Редагувати: Oracle: 9i

Ви можете використовувати VARRAY для масиву фіксованого розміру:

declare
   type array_t is varray(3) of varchar2(10);
   array array_t := array_t('Matt', 'Joanne', 'Robert');
begin
   for i in 1..array.count loop
       dbms_output.put_line(array(i));
   end loop;
end;

Або ТАБЛИЦЯ для безмежного масиву:

...
   type array_t is table of varchar2(10);
...

Слово "таблиця" тут не має нічого спільного з таблицями бази даних, заплутано. Обидва методи створюють масиви пам'яті.

За допомогою будь-якого з них вам потрібно ініціалізувати і розширити колекцію перед додаванням елементів:

declare
   type array_t is varray(3) of varchar2(10);
   array array_t := array_t(); -- Initialise it
begin
   for i in 1..3 loop
      array.extend(); -- Extend it
      array(i) := 'x';
   end loop;
end;

Перший показник - 1, а не 0.

Ви можете просто оголосити DBMS_SQL.VARCHAR2_TABLE для зберігання масиву змінної довжини в пам'яті, індексованого BINARY_INTEGER:

DECLARE
   name_array dbms_sql.varchar2_table;
BEGIN
   name_array(1) := 'Tim';
   name_array(2) := 'Daisy';
   name_array(3) := 'Mike';
   name_array(4) := 'Marsha';
   --
   FOR i IN name_array.FIRST .. name_array.LAST
   LOOP
      -- Do something
   END LOOP;
END;

Ви можете використовувати асоціативний масив (раніше його називали таблицями PL / SQL), оскільки вони є масивом в пам'яті.

DECLARE
   TYPE employee_arraytype IS TABLE OF employee%ROWTYPE
        INDEX BY PLS_INTEGER;
   employee_array employee_arraytype;
BEGIN
   SELECT *
     BULK COLLECT INTO employee_array
     FROM employee
    WHERE department = 10;
   --
   FOR i IN employee_array.FIRST .. employee_array.LAST
   LOOP
      -- Do something
   END LOOP;
END;

Асоціативний масив може містити будь-який тип записів.

Сподіваюся, це допоможе, Оллі.

Іншим рішенням є використання колекції Oracle в якості хешмапу:

declare 
-- create a type for your "Array" - it can be of any kind, record might be useful
  type hash_map is table of varchar2(1000) index by varchar2(30);
  my_hmap hash_map ;
-- i will be your iterator: it must be of the index's type
  i varchar2(30);
begin
  my_hmap('a') := 'apple';
  my_hmap('b') := 'box';
  my_hmap('c') := 'crow';
-- then how you use it:

  dbms_output.put_line (my_hmap('c')) ;

-- or to loop on every element - it's a "collection"
  i := my_hmap.FIRST;

  while (i is not null)  loop     
    dbms_output.put_line(my_hmap(i));      
    i := my_hmap.NEXT(i);
  end loop;

end;

Ви також можете використовувати oracle defined collection

DECLARE 
  arrayvalues sys.odcivarchar2list;
BEGIN
  arrayvalues := sys.odcivarchar2list('Matt','Joanne','Robert');
  FOR x IN ( SELECT m.column_value m_value
               FROM table(arrayvalues) m )
  LOOP
    dbms_output.put_line (x.m_value||' is a good pal');
  END LOOP;
END;

Я б використовував масив пам'яті. Але із .COUNTпокращенням, запропонованим узиберією:

DECLARE
  TYPE t_people IS TABLE OF varchar2(10) INDEX BY PLS_INTEGER;
  arrayvalues t_people;
BEGIN
  SELECT *
   BULK COLLECT INTO arrayvalues
   FROM (select 'Matt' m_value from dual union all
         select 'Joanne'       from dual union all
         select 'Robert'       from dual
    )
  ;
  --
  FOR i IN 1 .. arrayvalues.COUNT
  LOOP
    dbms_output.put_line(arrayvalues(i)||' is my friend');
  END LOOP;
END;

Іншим рішенням буде використання Hashmap, як @Jchomel тут .

Примітка:

З Oracle 12c ви можете навіть зараз запитувати масиви прямо зараз !

Зразкові програми наведені нижче та надаються також за посиланням https://oracle-concepts-learning.blogspot.com/

таблиця plsql або пов'язаний масив.

        DECLARE 
            TYPE salary IS TABLE OF NUMBER INDEX BY VARCHAR2(20); 
            salary_list salary; 
            name VARCHAR2(20); 
        BEGIN 
           -- adding elements to the table 
           salary_list('Rajnish') := 62000; salary_list('Minakshi') := 75000; 
           salary_list('Martin') := 100000; salary_list('James') := 78000; 
           -- printing the table name := salary_list.FIRST; WHILE name IS NOT null 
            LOOP 
               dbms_output.put_line ('Salary of ' || name || ' is ' || 
               TO_CHAR(salary_list(name))); 
               name := salary_list.NEXT(name); 
            END LOOP; 
        END; 
        /