CMake & CTest: тест make не створює тести

Я намагаюся CTest в CMake для того, щоб автоматично запускати деякі свої тести за допомогою make testtarget. Проблема в тому, що CMake не "розуміє", що тест, який я готовий провести, повинен бути побудований, оскільки він є частиною проекту.

Тому я шукаю спосіб явно вказати цю залежність.

Це , можливо , в помилку в CMake (раніше гусеничний тут ) , що це не працює з коробки. Обхідним шляхом є наступне:

add_test(TestName ExeName)
add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND}
                  DEPENDS ExeName)

Тоді ви можете запустити, make checkі він скомпілює та запустить тест. Якщо у вас є кілька тестів, то вам доведеться скористатися DEPENDS exe1 exe2 exe3 ...у наведеному вище рядку.

Насправді є спосіб використовувати make test. Вам потрібно визначити збірку тестового виконуваного файлу як один з тестів, а потім додати залежності між тестами. Це є:

ADD_TEST(ctest_build_test_code
         "${CMAKE_COMMAND}" --build ${CMAKE_BINARY_DIR} --target test_code)
ADD_TEST(ctest_run_test_code test_code)
SET_TESTS_PROPERTIES(ctest_run_test_code
                     PROPERTIES DEPENDS ctest_build_test_code)

Я використовую варіант відповіді richq. На верхньому рівні CMakeLists.txtя додаю власну ціль build_and_test, для побудови та запуску всіх тестів:

find_package(GTest)
if (GTEST_FOUND)
    enable_testing()
    add_custom_target(build_and_test ${CMAKE_CTEST_COMMAND} -V)
    add_subdirectory(test)
endif()

У різні CMakeLists.txtфайли підпроектів під test/, я додаю кожен тестовий виконуваний файл як залежність build_and_test:

include_directories(${CMAKE_SOURCE_DIR}/src/proj1)
include_directories(${GTEST_INCLUDE_DIRS})
add_executable(proj1_test proj1_test.cpp)
target_link_libraries(proj1_test ${GTEST_BOTH_LIBRARIES} pthread)
add_test(proj1_test proj1_test)
add_dependencies(build_and_test proj1_test)

При такому підході мені просто потрібно make build_and_testзамість make test(або make all test), і він має перевагу лише у побудові тестового коду (та його залежностей). Шкода, що я не можу використовувати цільове ім’я test. У моєму випадку це не так погано, тому що у мене є скрипт верхнього рівня, який виконує налагодження поза деревом і випускає (і перехресно компілюється) збірки, викликаючи cmakeта потім make, і це перекладається testв build_and_test.

Очевидно, що речі GTest не потрібні. Я випадково використовую / подобається Google Test, і я хочу поділитися повним прикладом його використання з CMake / CTest. IMHO, цей підхід також має перевагу, що дозволяє мені використовувати ctest -V, що показує результати випробувань Google під час запуску тестів:

1: Running main() from gtest_main.cc
1: [==========] Running 1 test from 1 test case.
1: [----------] Global test environment set-up.
1: [----------] 1 test from proj1
1: [ RUN      ] proj1.dummy
1: [       OK ] proj1.dummy (0 ms)
1: [----------] 1 test from proj1 (1 ms total)
1:
1: [----------] Global test environment tear-down
1: [==========] 1 test from 1 test case ran. (1 ms total)
1: [  PASSED  ] 1 test.
1/2 Test #1: proj1_test .......................   Passed    0.03 sec

Якщо ви намагаєтеся наслідувати make check, вам може здатися , що цей запис у вікі корисний:

http://www.cmake.org/Wiki/CMakeEmulateMakeCheck

Я щойно перевірив, що робить те, що він каже, з успіхом (CMake 2.8.10).

Збережіть собі головний біль:

make all test

Для мене це працює нестандартно і будує залежності перед запуском тесту. Враховуючи, наскільки це просто, це майже робить рідну make testфункціональність зручною, оскільки вона дає можливість запускати останні компіляційні тести, навіть якщо ваш код зламаний.

Якщо ви використовуєте CMake> = 3,7, то рекомендованим підходом є використання світильників :

add_executable(test test.cpp)
add_test(test_build
  "${CMAKE_COMMAND}"
  --build "${CMAKE_BINARY_DIR}"
  --config "$<CONFIG>"
  --target test
)
set_tests_properties(test_build PROPERTIES FIXTURES_SETUP    test_fixture)
add_test(test test)
set_tests_properties(test       PROPERTIES FIXTURES_REQUIRED test_fixture)

Це робить наступне:

• Додає testвиконувану ціль, побудовану зtest.cpp
• Додає test_build"тест", який запускає Cmake для побудови ціліtest
• Позначає test_buildтест як завдання налаштування приладуtest_fixture
• Додайте testтест, який просто запускає testвиконуваний файл
• Позначає, що testтест потребує кріплення test_fixture.

Отже, кожен раз test, коли потрібно запускати тест test_build, він спочатку запускає тест , який створює необхідний виконуваний файл.

Це те, що я вибив і використовував:

set(${PROJECT_NAME}_TESTS a b c)

enable_testing()
add_custom_target(all_tests)
foreach(test ${${PROJECT_NAME}_TESTS})
        add_executable(${test} EXCLUDE_FROM_ALL ${test}.cc)
        add_test(NAME ${test} COMMAND $<TARGET_FILE:${test}>)
        add_dependencies(all_tests ${test})
endforeach(test)

build_command(CTEST_CUSTOM_PRE_TEST TARGET all_tests)
string(CONFIGURE \"@CTEST_CUSTOM_PRE_TEST@\" CTEST_CUSTOM_PRE_TEST_QUOTED ESCAPE_QUOTES)
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake" "set(CTEST_CUSTOM_PRE_TEST ${CTEST_CUSTOM_PRE_TEST_QUOTED})" "\n")

YMMV

Відповідь Дерріка, спрощена та прокоментована:

# It is impossible to make target "test" depend on "all":
# https://gitlab.kitware.com/cmake/cmake/-/issues/8774
# Set a magic variable in a magic file that tells ctest
# to invoke the generator once before running the tests:
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake"
    "set(CTEST_CUSTOM_PRE_TEST ${CMAKE_MAKE_PROGRAM})\n"
)

Це не зовсім правильно, оскільки це не вирішує проблему паралельності запуску ninja all test, якщо хтось це зробить. Навпаки, адже зараз у вас є два процеси ніндзя.

(Ftr, я також поділився цим рішенням тут .)

Усі наведені вище відповіді ідеальні. Але насправді CMake використовує CTest як інструмент тестування, тому стандартним методом (я думаю, що він є) є місія:

enable_testing ()
add_test (TestName TestCommand)
add_test (TestName2 AnotherTestCommand)

Потім запустіть cmake і make для побудови цілей. Після цього ви можете або запустити make test , або просто запустити

ctest

ви отримаєте результат. Це перевірено в CMake 2.8.

Перевірте деталі на: http://cmake.org/Wiki/CMake/Testing_With_CTest#Simple_Testing

Усі відповіді хороші, але вони означають порушення традиції проводити тест за командою make test. Я зробив цей трюк:

add_test(NAME <mytest>
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
COMMAND sh -c "make <mytarget>; $<TARGET_FILE:<mytarget>>")

Це означає, що тест складається з побудови (за бажанням) та запуску виконуваної цілі.