Перемістити всю лінію вгору та вниз по Vim

У Блокноті ++ я можу використовувати Ctrl+ Shift+ Up/ Downдля переміщення поточної лінії вгору та вниз. Чи схожа команда на цю у Vim? Я переглянув нескінченні посібники, але нічого не знайшов.

Якщо цього немає, як я можу прив’язати дію до цієї комбінації клавіш?

Редагувати: Відповідь Миколи працює для всіх рядків, окрім тих на початку та в кінці буфера. Переміщення першого рядка вгору або нижнього рядка вниз видаляє лінію, а при переміщенні нижньої лінії вгору вона стрибає два пробіли спочатку, як пішак! Чи може хтось запропонувати якісь уточнення?

Поставте наступне у своєму .vimrc, щоб виконати роботу

noremap <c-s-up> :call feedkeys( line('.')==1 ? '' : 'ddkP' )<CR>
noremap <c-s-down> ddp

Зникнення лінії виглядає як помилка Vim. Я ставлю хак, щоб уникнути цього. Напевно, є якесь більш точне рішення.

Оновлення

Існує багато незрозумілих труднощів із просто використанням комбінацій Vim. Це відсутні лінії та додаткові стрибки на лінії.

Тож ось сценарійне рішення, яке можна розмістити всередині .vimrc або ~ / .vim / plugin / swap_lines.vim

function! s:swap_lines(n1, n2)
    let line1 = getline(a:n1)
    let line2 = getline(a:n2)
    call setline(a:n1, line2)
    call setline(a:n2, line1)
endfunction

function! s:swap_up()
    let n = line('.')
    if n == 1
        return
    endif

    call s:swap_lines(n, n - 1)
    exec n - 1
endfunction

function! s:swap_down()
    let n = line('.')
    if n == line('$')
        return
    endif

    call s:swap_lines(n, n + 1)
    exec n + 1
endfunction

noremap <silent> <c-s-up> :call <SID>swap_up()<CR>
noremap <silent> <c-s-down> :call <SID>swap_down()<CR>

Якщо я хочу поміняти один рядок на рядок вище, зазвичай роблю наступне

ddkP

Пояснення

• dd видалить рядок і додасть її до реєстру за замовчуванням.
• k переміститься вгору по лінії (j переміститься вниз по лінії)
• P вставить над поточним рядком

Припускаючи, що курсор знаходиться на лінії, по якій ви хочете рухатись.

Рух вгору і вниз: :mдля руху

:m +1 - рухається вниз на 1 рядок

:m -2 - рухатися вгору на 1 рядок

(Зауважте, що ви можете замінити +1 будь-якими числами залежно від того, скільки рядків ви хочете перемістити вгору чи вниз, тобто +2 перемістить його вниз на 2 рядки, -3 перемістить його на 2 рядки)

Щоб перейти до певної лінії

:set number - відображати рядки з цифрами (простіше побачити, куди ви переміщуєте)

:m 3 - перемістити рядок після 3-го рядка (замініть 3 на будь-який рядок, який ви хочете)

Переміщення декількох ліній:

V(тобто Shift- V) і переміщуйте курсор вгору та вниз, щоб вибрати кілька рядків у VIM

після вибору натискання :та запуску команд вище, m +1тощо

Перемістити лінію вгору: ddkP

Перемістіть лінію вниз: ddp

Це працювало для мене:

http://vim.wikia.com/wiki/Moving_lines_up_or_down_in_a_file

BTW, якщо ви хочете використовувати ALT + some_key, і ваш термінал (urxvt робить це) відмовляється виконувати відповіді, вам слід ввести щось подібне у свій .vimrc:

" For moving lines (^] is a special character; use <M-k> and <M-j> if it works)
nnoremap ^]k mz:m-2<CR>`z==
inoremap ^]j <Esc>:m+<CR>==gi
inoremap ^]k <Esc>:m-2<CR>==gi
vnoremap ^]j :m'>+<CR>gv=`<my`>mzgv`yo`z
nnoremap ^]j mz:m+<CR>`z==
vnoremap ^]k :m'<-2<CR>gv=`>my`<mzgv`yo`z

де ^] - єдиний символ, який представляє ключ ALT. Щоб ввести цей символ, використовуйте C+v, EscVim ( C+q, Escу Windows).

додайте у файл ~ / .vimrc файл (переконайтесь, що у вас немає відображення для n, m)

nmap n :m +1<CR>
nmap m :m -2<CR>

тепер натискання nклавіші перемістить лінію вниз і mперемістить лінію вгору.

У командному режимі розташуйте курсор на лінії, яку потрібно рухати вниз, а потім

ddp

Пояснення: dd видаляє поточний рядок із загального буфера;

Існує деяка плутанина щодо команд p і P у багатьох документах. Насправді р вставляє ПІСЛЯ курсора, а P AT - курсор.

Просто додайте цей код у .vimrc (або .gvimrc)

nnoremap <A-j> :m+<CR>==
nnoremap <A-k> :m-2<CR>==
inoremap <A-j> <Esc>:m+<CR>==gi
inoremap <A-k> <Esc>:m-2<CR>==gi
vnoremap <A-j> :m'>+<CR>gv=gv
vnoremap <A-k> :m-2<CR>gv=gv

Саме те, що ви шукаєте в цьому дивовижному плагіні: https://github.com/vim-scripts/upAndDown

Просте рішення , щоб покласти в ваших .vimrcцих рядках:

nmap <C-UP> :m-2<CR>  
nmap <C-DOWN> :m+1<CR>

В кінці мого .vimrc-файлу я ставлю наступне:

noremap H ddkkp
noremap N ddp

Тож тепер "H" і "N" рухаються поточною лінією відповідно вгору та вниз.

Ось спрощена версія для MacVim, використовуючи приклади статті Wikia (див. Посилання з коментаря гармати ).

" Move selection up/down (add =gv to reindent after move)
:vmap <D-S-Up> :m-2<CR>gv
:vmap <D-S-Down> :m'>+<CR>gv

Я використовую лише варіант вибору блоку, оскільки потрібно лише Shift-V для вибору поточної лінії, і, за бажанням, курсор вгору / вниз, щоб вибрати ще кілька рядків.

Відповідно до наведених вище ярликів, натискання клавіш Cmd-Shift-Up / Down змістить вибір блоку вгору / вниз. "D" - це командна клавіша в MacVim, для Windows спробуйте "C" (Control) або "A" (Alt) (наприклад, <CAf> буде Control Alt f).

Стаття Wikia додає до них "= gv", що може коригувати відступ блоку після переміщення на основі оточуючого тексту. Це заплутано, тому я видалив його та додав ярлики для швидкого відступу вибору.

" Indent selection left/right (Cmd Shift Left/Right is used for Tab switching)
:vmap <D-A-Left> <gv
:vmap <D-A-Right> >gv

Майте на увазі, те ж саме можна зробити з << і >>, але виділення буде втрачено, тому ці ярлики вище дозволяють відступити кілька разів і все-таки перемістити блок навколо, оскільки вибір підтримується.

Мій MacVim налаштований для перемикання вкладок Cmd-Shift-Left / Right, тому я використовував Cmd-Alt-Left / Right.

Ось переключення Tab для MacVim (поставити .gvimrc з рештою вище):

:macm Window.Select\ Previous\ Tab key=<D-S-Left>
:macm Window.Select\ Next\ Tab key=<D-S-Right>

плагін vim unimpaired.vim [e і] e

Коли ви натискаєте команду :help moveв vim, ось результат:

:[range]m[ove] {address} *:m* *:mo* *:move* *E134* Move the lines given by [range] to below the line given by {address}.

Напр .: переміщення поточного рядка на один рядок вниз => :m+1 .

Напр .: перемістіть рядок цифрою 100 нижче рядка з цифрою 80 => :100 m 80 .

Напр .: перемістіть рядок цифрою 100 нижче рядка з номером 200 => :100 m 200 .

Напр .: перемістіть лінії з номером у межах [100, 120] нижче рядка з номером 200 => :100,120 m 200 .

Ось рішення, яке працює на моїй машині : MacBook Pro під управлінням VIM 8.1

Ці команди не видалять ваші рядки вгорі або внизу буфера.

Використання фактичних символів, які Alt-J і Alt-K виводить, є вирішенням для їх ключових кодів, які не відображаються належним чином у моєму середовищі.

Киньте це в старий .vimrc і подивіться, чи працює для вас.

" Maps Alt-J and Alt-K to macros for moving lines up and down
" Works for modes: Normal, Insert and Visual
nnoremap ∆ :m .+1<CR>==
nnoremap ˚ :m .-2<CR>==
inoremap ∆ <Esc>:m .+1<CR>==gi
inoremap ˚ <Esc>:m .-2<CR>==gi
vnoremap ∆ :m '>+1<CR>gv=gv
vnoremap ˚ :m '<-2<CR>gv=gv

Для мене ddkkpце зробили (замість великого ddkPрегістру P, який теж працював).

: m. + 1 або: m.-2 зробить, якщо ви рухаєтесь однією лінією. Ось мій сценарій для переміщення декількох рядків. У візуальному режимі Alt-Up / Alt-Down буде переміщувати лінії, що містять візуальний вибір, вгору / вниз по одному рядку. У режимі вставки або звичайному режимі Alt-вгору / Alt-вниз перемістить поточний рядок, якщо не вказаний префікс підрахунку. Якщо є префікс підрахунку, Alt-вгору / Alt-вниз перемістить стільки рядків, починаючи з поточного рядка вгору / вниз по одному рядку.

function! MoveLines(offset) range
    let l:col = virtcol('.')
    let l:offset = str2nr(a:offset)
    exe 'silent! :' . a:firstline . ',' . a:lastline . 'm'
        \ . (l:offset > 0 ? a:lastline + l:offset : a:firstline + l:offset)
    exe 'normal ' . l:col . '|'
endf

imap <silent> <M-up> <C-O>:call MoveLines('-2')<CR>
imap <silent> <M-down> <C-O>:call MoveLines('+1')<CR>
nmap <silent> <M-up> :call MoveLines('-2')<CR>
nmap <silent> <M-down> :call MoveLines('+1')<CR>
vmap <silent> <M-up> :call MoveLines('-2')<CR>gv
vmap <silent> <M-down> :call MoveLines('+1')<CR>gv

Якщо ви хочете зробити це в декількох рядках, які відповідають певному пошуку:

• Вгору: :g/Your query/ normal ddpабо:g/Your query/ m -1
• Вниз :g/Your query/ normal ddpабо:g/Your query/ m +1