Перевірте, чи рядок є нульовим чи порожнім у XSLT

Як я можу перевірити, чи значення XSL є нульовим чи порожнім ?

Наприклад, якщо categoryNameпорожній? Я використовую при виборі конструкції.

Наприклад:

<xsl:choose>
    <xsl:when test="categoryName !=null">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

test="categoryName != ''"

Редагувати : Це стосується найбільш вірогідної інтерпретації "[not] null or empty", як випливає з запитання, включаючи псевдокод та власний ранній досвід роботи з XSLT. Тобто, "Який еквівалент наступної Java?":

!(categoryName == null || categoryName.equals(""))

Детальніше, наприклад, чітко визначивши нуль проти порожнього, дивіться відповідь Джонві нижче та / або "скрипку" XSLT яку я адаптував із цього відповіді, що включає можливість коментаря Майкла Кей, а також шосту можливу інтерпретацію.

Відсутня будь-яка інша інформація, я припускаю наступний XML:

<group>
    <item>
        <id>item 1</id>
        <CategoryName>blue</CategoryName>
    </item>
    <item>
        <id>item 2</id>
        <CategoryName></CategoryName>
    </item>
    <item>
        <id>item 3</id>
    </item>
    ...
</group>

Приклад використання зразка виглядатиме так:

<xsl:for-each select="/group/item">
    <xsl:if test="CategoryName">
        <!-- will be instantiated for item #1 and item #2 -->
    </xsl:if>
    <xsl:if test="not(CategoryName)">
        <!-- will be instantiated for item #3 -->
    </xsl:if>
    <xsl:if test="CategoryName != ''">
        <!-- will be instantiated for item #1 -->
    </xsl:if>
    <xsl:if test="CategoryName = ''">
        <!-- will be instantiated for item #2 -->
    </xsl:if>
</xsl:for-each>

Від Порожнього елемента :

Щоб перевірити, чи значення певного вузла порожнє

Це залежить від того, що ви маєте на увазі під порожнім.

• Не містить дочірніх вузлів: not(node())
• Не містить текстового вмісту: not(string(.))
• Не містить тексту, окрім пробілу: not(normalize-space(.))
• Не містить нічого, крім коментарів: not(node()[not(self::comment())])

А як на рахунок?

test="not(normalize-space(categoryName)='')"

Перші два мають значення з нульовим значенням і другі два мають порожній рядок.

<xsl:if test="USER/FIRSTNAME">
    USERNAME is not null
</xsl:if>
<xsl:if test="not(USER/FIRSTNAME)">
    USERNAME is null
 </xsl:if>
 <xsl:if test="USER/FIRSTNAME=''">
     USERNAME is empty string
 </xsl:if>
 <xsl:if test="USER/FIRSTNAME!=''">
     USERNAME is not empty string
 </xsl:if>

У деяких випадках, можливо, ви хочете дізнатися, коли значення конкретно є нульовим, що особливо необхідно при використанні XML, серіалізованого з .NET-об'єктів. Хоча прийнята відповідь для цього працює, вона також повертає той самий результат, коли рядок порожній або порожній, тобто "", тому ви не можете розмежувати.

<group>
    <item>
        <id>item 1</id>
        <CategoryName xsi:nil="true" />
    </item>
</group>

Таким чином, ви можете просто протестувати атрибут.

<xsl:if test="CategoryName/@xsi:nil='true'">
   Hello World.
</xsl:if>

Іноді потрібно знати точний стан, і ви не можете просто перевірити, чи CategoryName є екземпляром, тому що на відміну від Javascript

<xsl:if test="CategoryName">
   Hello World.
</xsl:if>

Поверне значення true для нульового елемента.

Я знаю, що це питання давнє, але між усіма відповідями я пропускаю один, який є загальним підходом до цього випадку використання в розробці XSLT.

Я уявляю, що пропущений код з ОП виглядає приблизно так:

<xsl:template match="category">
    <xsl:choose>
        <xsl:when test="categoryName !=null">
            <xsl:value-of select="categoryName " />
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="other" />
        </xsl:otherwise>
    </xsl:choose>
</category>

І що вхід виглядає приблизно так:

<categories>
    <category>
       <categoryName>Books</categoryName>
    </category>
    <category>
       <categoryName>Magazines</categoryName>
       <categoryName>Periodicals</categoryName>
       <categoryName>Journals</categoryName>
    </category>
    <category>
        <categoryName><!-- please fill in category --></categoryName>
    </category>
    <category>
        <categoryName />
    </category>
    <category />
</categories>

Тобто, я припускаю, що може бути нульовий, порожній, одинарний або кілька categoryNameелементів. Впоратися з усіма цими випадками за допомогою xsl:chooseконструкцій -style, або іншими словами, обов'язково, швидко стає безладним (тим більше, якщо елементи можуть бути на різних рівнях!). Типова ідіома програмування в XSLT - це використання шаблонів (отже, T у XSLT), що є декларативним програмуванням, а не обов'язковим (ви не говорите процесору, що робити, ви просто повідомте, що ви хочете вивести, якщо будуть виконані певні умови). У цьому випадку використання може виглядати приблизно так:

<!-- positive test, any category with a valid categoryName -->
<xsl:template match="category[categoryName[text()]]">
    <xsl:apply-templates />
</xsl:template>

<!-- any other category (without categoryName, "null", with comments etc) -->
<xsl:template match="category">
    <xsl:text>Category: Other</xsl:text>
</xsl:template>

<!-- matching the categoryName itself for easy handling of multiple names -->
<xsl:template match="categoryName">
    <xsl:text>Category: </xsl:text>
    <xsl:value-of select="." />
</xsl:template>

Це працює (з будь-якою версією XSLT), оскільки перша вище має перевагу (має присудок). Шаблон відповідності "пропускний", другий, вловлює все, що недійсне. Потім третій піклується про вихідcategoryName значення належним чином.

Зауважте, що в цьому сценарії немає необхідності в точній відповідності categoriesабо category, оскільки процесор автоматично обробляє всіх дітей, якщо ми не скажемо це інакше (у цьому прикладі другий і третій шаблони не обробляють дітей далі, оскільки немаєxsl:apply-templates в їх).

Цей підхід легше розширити, ніж імперативний підхід, оскільки він автоматично обробляє декілька категорій і його можна розширити для інших елементів або винятків, просто додавши ще один узгоджений шаблон. Програмування без if-філій .

Примітка. Немає такого поняття, як nullу XML. Є xsi: nil , але це рідко використовується, особливо рідко в нетипових сценаріях без якоїсь схеми.

Як я можу перевірити, чи значення XSL є нульовим чи порожнім?

Наприклад, якщо categoryNameпорожній?

Це, мабуть, найпростіший вираз XPath (те, що у прийнятій відповіді дає тест на протилежне, і було б довше, якщо було б заперечено):

not(string(categoryName))

Пояснення :

Аргумент not()вищевказаної функції полягає false()саме в тому випадку, коли categoryNameв контексті елемента немає дочірнього ("null") або categoryNameдочірнє (одиночне таке) має значення рядка - порожній рядок.

Я використовую при виборі конструкції.

Наприклад:

<xsl:choose>
    <xsl:when test="categoryName !=null">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

У XSLT 2.0 використовуйте :

<xsl:copy-of select="concat(categoryName,  $vOther[not(string(current()/categoryName))])"/>

Ось повний приклад :

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vOther" select="'Other'"/>

 <xsl:template match="/">
  <xsl:copy-of select="concat(categoryName,$vOther[not(string(current()/categoryName))])"/>
 </xsl:template>
</xsl:stylesheet>

Коли це перетворення застосовується до наступного XML-документа:

<categoryName>X</categoryName>

шукається правильний результат :

X

Якщо застосовується до цього XML-документа :

<categoryName></categoryName>

або на цьому:

<categoryName/>

або на цьому

<somethingElse>Y</somethingElse>

правильний результат виробляється :

Other

Аналогічно використовуйте це перетворення XSLT 1.0 :

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vOther" select="'Other'"/>

  <xsl:template match="/">
    <xsl:copy-of select=
    "concat(categoryName,  substring($vOther, 1 div not(string(categoryName))))"/>
  </xsl:template>
</xsl:stylesheet>

Зверніть увагу : умовні умови взагалі не використовуються. Дізнайтеся більше про важливість уникнення умовних конструкцій у цьому приємному курсі Pluralsight:

" Шаблони тактичного дизайну в .NET: Control Flow "

Якщо є можливість, що елемента не існує в XML, я би перевірив і наявність елемента, і довжина рядка більше нуля:

<xsl:choose>
    <xsl:when test="categoryName and string-length(categoryName) &gt; 0">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

Якщо вузол не має значення у вхідному xml, як нижче xpath,

<node>
    <ErrorCode/>
</node>

Функція string () перетворюється в порожнє значення. Отже, це добре працює:

string(/Node/ErrorCode) =''

Щось подібне працює для мене:

<xsl:choose>
  <xsl:when test="string(number(categoryName)) = 'NaN'"> - </xsl:when> 
  <xsl:otherwise> 
    <xsl:number value="categoryName" />
  </xsl:otherwise>
</xsl:choose>

Або навпаки:

<xsl:choose>
  <xsl:when test="string(number(categoryName)) != 'NaN'">
    <xsl:number value="categoryName" />
  </xsl:when> 
  <xsl:otherwise> - </xsl:otherwise>
</xsl:choose>

Примітка: Якщо ви не перевіряєте нульові значення або не обробляєте нульові значення, IE7 повертає -2147483648 замість NaN.

Я фактично вважаю, що краще просто перевірити довжину рядка, оскільки багато разів поле не є нульовим, просто порожнім

<xsl: when test = "string-length (поле, яке ви хочете перевірити) <1">

На мій досвід найкращий спосіб:

<xsl:when test="not(string(categoryName))">
    <xsl:value-of select="other" />
</xsl:when>
<otherwise>
    <xsl:value-of select="categoryName" />
</otherwise>

Використовуйте просту категоріюName / text () Такий тест добре працює <categoryName/>і також <categoryName></categoryName>.

<xsl:choose>
    <xsl:when test="categoryName/text()">
        <xsl:value-of select="categoryName" />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>