Коментування декількох рядків у командному файлі DOS

Я написав величезний пакетний файл MS DOS. Щоб протестувати цей пакетний файл, мені потрібно виконати лише деякі рядки і хочу приховати / залишити коментар, що залишився.

У мене є деякі існуючі рядки коментарів, починаючи з, ::отже, я більше не можу їх використовувати, ::оскільки вони будуть шифрувати всі коментарі.

Як я можу вирішити цю проблему?

Ви можете використовувати a, gotoщоб пропустити код.

goto comment
...skip this...
:comment

Якщо ви хочете додати REM на початку кожного рядка, а не використовувати GOTO, ви можете використовувати Notepad ++, щоб зробити це легко, виконавши наступні дії:

1. Виділіть блок рядків
2. натисніть Ctrl-Q

Повторіть кроки, щоб розкоментувати

break||(
 code that cannot contain non paired closing bracket
)

Хоча gotoрішення є хорошим варіантом, воно не буде працювати в дужках (включаючи команди FOR та IF). Але це буде. Хоча ви повинні бути обережними щодо закриття дужок та неприпустимого синтаксису команд FORі IFкоманд, оскільки вони будуть проаналізовані.

Оновлення

Оновлення у відповіді dbenham дало мені кілька ідей. По-перше - є два різні випадки, коли нам потрібні багаторядкові коментарі - в дужці, коли GOTO не може бути використаний і поза ним. Усередині дужок контексту ми можемо використовувати інші дужки , якщо є умова , яке запобігає код буде executed.Though код thede по- , як і раніше буде проаналізований і будуть виявлені деякі синтаксичні помилки ( FOR, IF, неправильно закриті дужки, неправильне розширення параметра ..). Таким чином , якщо можливо, краще скористатися GOTO.

Хоча створити макрос / змінну, що використовується як мітка, неможливо - але можна використовувати макроси для коментарів дужок. Ще можна використовувати дві хитрощі, щоб зробити коментарі GOTO більш симетричними та приємнішими (принаймні для мене). Для цього я скористаюся двома прийомами - 1) ви можете поставити один символ перед міткою, і goto все одно зможе його знайти (я не маю уявлення, чому це. Мої думки, він шукає диск). 2) ви можете поставити єдине : в кінці імені змінної, і функція заміни / підрядки не буде спрацьовувати (навіть при включених розширеннях). Що в поєднанні з макросами для коментарів у дужках може змусити обидва випадки виглядати майже однаково.

Ось ось приклади (у тому порядку, який мені найбільше подобається):

З прямокутними дужками :

@echo off

::GOTO comment macro
set "[:=goto :]%%"
::brackets comment macros
set "[=rem/||(" & set "]=)"

::testing
echo not commented 1

%[:%
  multi 
  line
  comment outside of brackets
%:]%

echo not commented 2

%[:%
  second multi 
  line
  comment outside of brackets
%:]%

::GOTO macro cannot be used inside for
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %[%
        multi line
        comment
    %]%
    echo second not commented line of the %%a execution
)

З фігурними дужками :

@echo off

::GOTO comment macro
set "{:=goto :}%%"
::brackets comment macros
set "{=rem/||(" & set "}=)"

::testing
echo not commented 1

%{:%
  multi 
  line
  comment outside of brackets
%:}%

echo not commented 2

%{:%
  second multi 
  line
  comment outside of brackets
%:}%

::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %{%
        multi line
        comment
    %}%
    echo second not commented line of the %%a execution
)

З дужками :

@echo off

::GOTO comment macro
set "(:=goto :)%%"
::brackets comment macros
set "(=rem/||(" & set ")=)"

::testing
echo not commented 1

%(:%
  multi 
  line
  comment outside of brackets
%:)%

echo not commented 2

%(:%
  second multi 
  line
  comment outside of brackets
%:)%

::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %(%
        multi line
        comment
    %)%
    echo second not commented line of the %%a execution
)

Суміш між стилями powerhell та C ( <не може бути використана, оскільки перенаправлення має вищий пріоритет. *Неможливо використовувати через %*):

@echo off

::GOTO comment macro
set "/#:=goto :#/%%"
::brackets comment macros
set "/#=rem/||(" & set "#/=)"

::testing
echo not commented 1

%/#:%
  multi 
  line
  comment outside of brackets
%:#/%

echo not commented 2

%/#:%
  second multi 
  line
  comment outside of brackets
%:#/%

::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %/#%
        multi line
        comment
    %#/%
    echo second not commented line of the %%a execution
)

Щоб підкреслити, що це коментар (думав, що він не такий короткий):

@echo off

::GOTO comment macro
set "REM{:=goto :}REM%%"
::brackets comment macros
set "REM{=rem/||(" & set "}REM=)"

::testing
echo not commented 1

%REM{:%
  multi 
  line
  comment outside of brackets
%:}REM%

echo not commented 2

%REM{:%
  second multi 
  line
  comment outside of brackets
%:}REM%

::GOTO macro cannot be used inside for
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %REM{%
        multi line
        comment
    %}REM%
    echo second not commented line of the %%a execution
)

Інший варіант - укласти непотрібні рядки в блок IF, який ніколи не може бути правдивим

if 1==0 (
...
)

Звичайно нічого в блоці if не буде виконано, але він буде проаналізований. Отже, у вас не може бути жодного невірного синтаксису. Також коментар не може містити, )якщо його не уникнути або процитувати. З цих причин прийняте рішення GOTO є більш надійним. (Рішення GOTO також може бути швидшим)

Оновлення 2017-09-19

Ось косметичне вдосконалення рішення GOTO pdub . Я визначаю просту змінну середовища "макрос", яка робить синтаксис коментарів GOTO трохи кращим для самостійного документування. Хоча, як правило, рекомендується: мітки унікальні в пакетному сценарії, дійсно добре вбудовувати кілька подібних коментарів в один і той же пакетний сценарій.

@echo off
setlocal

set "beginComment=goto :endComment"

%beginComment%
Multi-line comment 1
goes here
:endComment

echo This code executes

%beginComment%
Multi-line comment 2
goes here
:endComment

echo Done

Або ви можете використовувати один із цих варіантів рішення npocmaka . Використання REM замість BREAK робить намір трохи зрозумілішим.

rem.||(
   remarks
   go here
)

rem^ ||(
   The space after the caret
   is critical
)

Просто хочу зазначити, що рішення GDO pdub не є повністю правильним у випадку: мітка коментаря з’являється кілька разів. Я змінюю код із цього питання як приклад.

@ECHO OFF
SET FLAG=1
IF [%FLAG%]==[1] (
    ECHO IN THE FIRST IF...
    GOTO comment
    ECHO "COMMENT PART 1"
:comment
    ECHO HERE AT TD_NEXT IN THE FIRST BLOCK
)

IF [%FLAG%]==[1] (
    ECHO IN THE SECOND IF...
    GOTO comment
    ECHO "COMMENT PART"
:comment
    ECHO HERE AT TD_NEXT IN THE SECOND BLOCK
)

Вихід буде

IN THE FIRST IF...
HERE AT TD_NEXT IN THE SECOND BLOCK

Команда ECHO HERE AT TD_NEXT В ПЕРШОМ БЛОКУ пропущена.

@jeb

І після використання цього, stderr здається недоступним

Ні, спробуйте це:

@echo off 2>Nul 3>Nul 4>Nul

   ben ali  
   mubarak 2>&1
   gadeffi
   ..next ?

   echo hello Tunisia

  pause

Але чому це працює?

вибачте, я відповідаю на питання по-френш:

(la predirection par 3> est spécial car elle persiste; on l'utiliser pour capturer le flux des erreurs 2> est on va le transformer en un flux persistent à l'ade de 3> ceci va nous permettre d'avoir und gestion des erreur pour tout notre environement de script..par la suite si on veux recuperer le flux 'stderr' il faut faire une autre redirection du handle 2> au handle 1> qui n'est autre que la console ..)

спробуйте це:

   @echo off 2>Nul 3>Nul 4>Nul

   ben ali
   mubarak
   gadeffi
   ..next ?

   echo hello Tunisia

  pause