Як запустити пакетний файл із спільної мережі без повідомлення “Шлях UNC не підтримується”?

Я намагаюся запустити пакетний файл із мережевого ресурсу, але я постійно отримую таке повідомлення: "Шлях UNC не підтримується. За замовчуванням каталог Windows." Пакетний файл знаходиться на \\Server\Soft\WPX5\install.bat. Поки я ввійшов як адміністратор, з мого робочого столу Windows 7 я переходжу \\Server\Soft\WP15\та двічі клацну на install.bat, саме тоді я отримую "Шлях UNC не підтримується". повідомлення. Я знайшов в Інтернеті кілька пропозицій про те, що відображення накопичувача не буде працювати, але використання символічного посилання вирішить цю проблему, але символічне посилання для мене не спрацювало. Нижче мій вміст командного файлу, я був би вдячний за будь-яку допомогу, яка допоможе мені досягти того, що я намагаюся зробити. В основному, я хочу мати можливість запускати командний файл з \\Server\Soft\WP15\install.bat.

Зміст пакетного файлу

mklink /d %userprofile%\Desktop\WP15 \\server\soft\WP15
\\server\soft\WP15\setup.exe
robocopy.exe "\\server\soft\WP15\Custom" /copyall "C:\Program Files (x86)\WP\Custom Templates"
Regedit.exe /s \\server\soft\WPX5\Custom\Migrate.reg

Крім того, як мені видалити символічне посилання після завершення встановлення?

PUSHD та POPD повинні допомогти у вашому випадку.

@echo off
:: Create a temporary drive letter mapped to your UNC root location
:: and effectively CD to that location
pushd \\server\soft

:: Do your work
WP15\setup.exe
robocopy.exe "WP15\Custom" /copyall "C:\Program Files (x86)\WP\Custom Templates"
Regedit.exe /s WPX5\Custom\Migrate.reg

:: Remove the temporary drive letter and return to your original location
popd

Введіть PUSHD /?з командного рядка для отримання додаткової інформації.

Існує параметр реєстру, щоб уникнути цієї перевірки безпеки (однак використовуйте його на власний ризик):

Під шляхом реєстру

   HKEY_CURRENT_USER
     \ Software
       \ Microsoft
         \ Command Processor

додати значення DisableUNCCheck REG_DWORD і встановити значення 0 x 1 (Hex).

Примітка: У Windows 10 версії 1803, схоже, параметр знаходиться під HKLM: HKEY_LOCAL_MACHINE \ SOFTWARE \ Microsoft \ Command Processor

Я вважаю, що clsце найкраща відповідь. Він приховує повідомлення UNC, перш ніж хтось зможе його побачити. Я поєднав його з @pushd %~dp0відразу після того, щоб здавалося, що відкриваю сценарій і складаю карту розташування за один крок, тим самим запобігаючи подальшим проблемам UNC.

cls
@pushd %~dp0
:::::::::::::::::::
:: your script code here
:::::::::::::::::::
@popd

Примітки:

pushd змінить ваш робочий каталог на місце скриптів на новому відображеному диску.

popd в кінці, щоб очистити відображений привід.

В основному, ви не можете запустити його із шляху UNC, не побачивши цього повідомлення.

Що я зазвичай роблю, це просто кладу символ CLSу верхній частині сценарію, щоб мені не потрібно було бачити це повідомлення. Потім вкажіть повний шлях до файлів у спільній мережі, які потрібно використовувати.

Мені потрібно було мати можливість просто переглядати Провідник Windows через спільний доступ до сервера, а потім двічі клацнути запустити пакетний файл. @dbenham привів мене до більш простого рішення для мого сценарію (без popdтурбот):

:: Capture UNC or mapped-drive path script was launched from
set NetPath=%~dp0

:: Assumes that setup.exe is in the same UNC path
%NetPath%setup.exe

:: Note that NetPath has a trailing backslash ("\")
robocopy.exe "%NetPath%Custom" /copyall "C:\Program Files (x86)\WP\Custom Templates"
Regedit.exe /s %NetPath%..\WPX5\Custom\Migrate.reg

:: I am not sure if WPX5 was typo, so use ".." for parent directory
set NetPath=
pause

Замість того, щоб запускати пакет безпосередньо з провідника - створіть ярлик до пакета та встановіть початковий каталог у властивостях ярлика на локальний шлях, наприклад% TEMP% або щось інше.

Щоб видалити символічне посилання, використовуйте команду rmdir.

Нещодавно я зіткнувся з тим же питанням, працюючи з командним файлом на мережевому спільному диску в Windows 7.

Ще один спосіб, який працював для мене, - це зіставити сервер із диском через Провідник Windows: Інструменти -> Зіставити мережевий диск. Дайте йому букву диска та шлях до папки до \ yourserver. Оскільки я працюю з мережевим ресурсом, часто його відображення робить його більш зручним, і воно вирішило помилку „Шлях UNC не підтримується”.

Моя ситуація лише трохи інша. Я запускаю пакетний файл під час запуску, щоб розповсюджувати останню версію внутрішніх бізнес-додатків.

У цій ситуації я використовую ключ запуску реєстру Windows із таким рядком

cmd /c copy \\serverName\SharedFolder\startup7.bat %USERPROFILE% & %USERPROFILE%\startup7.bat

Це запускає дві команди під час запуску у правильній послідовності. Спочатку локально скопіюйте пакетний файл в каталог, на який користувач має дозвіл. Потім виконується той самий пакетний файл. Я можу створити локальний каталог c: \ InternalApps і скопіювати всі файли з мережі.

Це, мабуть, занадто пізно, щоб вирішити питання оригінального плаката, але це може допомогти комусь іншому.

Це RegKey, який я використовував:

Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command Processor]
"DisableUNCCheck"=dword:00000001

Моя версія env windows10 2019 lts, ​​і я додаю ці два дані binray, виправте цю помилку

Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command ProcessorDisableUNCCheck значення 1 Computer\HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Command Processor DisableUNCCheck значення 1

Це дуже стара тема, але я все ще використовую Windows 7. :-)

Є один момент, який, здається, ніхто не врахував, що, ймовірно, також допомогло б користувачам Windows 10.

Якщо ввімкнено розширення команд, команда PUSHD приймає мережеві шляхи на додаток до звичайної букви та шляху диска.

Тож очевидною і найпростішою відповіддю може бути ввімкнення розширень команд у пакетному сценарії, якщо ви маєте намір використовувати PUSHD. Принаймні, це повинно зменшити проблеми, які можуть виникнути у вас при використанні PUSHD з мережевим шляхом.

Редагувати реєстри Windows не варто і не безпечно, використовуйте Map network driveта завантажуйте мережевий ресурс так, ніби він завантажений з одного з ваших локальних дисків.