CIL (власне ім'я для MSIL) і байт-код Java більш однакові, ніж різні. Однак є кілька важливих відмінностей:
1) CIL був розроблений з самого початку, щоб служити ціллю для багатьох мов. Таким чином, він підтримує набагато багатшу систему типів, що включає підписані та непідписані типи, типи значень, покажчики, властивості, делегати, події, узагальнюючі засоби, об'єктну систему з одним коренем тощо. CIL підтримує функції, не потрібні для початкових мов CLR (C # та VB.NET), такі як глобальні функції та оптимізація зворотних викликів . Для порівняння, байт-код Java був розроблений як цільовий для мови Java і відображає багато обмежень, виявлених у самій Java. Набагато складніше було б написати C або схему, використовуючи байт-код Java.
2) CIL був розроблений для легкої інтеграції у власні бібліотеки та некерований код
3) Байт-код Java був розроблений для інтерпретації або компіляції, тоді як CIL був розроблений, передбачаючи лише компіляцію JIT. Тим не менш, початкова реалізація Mono використовувала інтерпретатор замість JIT.
4) CIL був розроблений ( і вказаний ), щоб мати зручну для читання та записувану форму мови збірки, яка безпосередньо відображається у формі байт-коду. Я вважаю, що байт-код Java (як випливає з назви) мав бути призначений лише для машинного зчитування. Звичайно, байт-код Java порівняно легко декомпілюється до початкової Java, і, як показано нижче, його також можна "розібрати".
Слід зазначити, що JVM (більшість з них) є більш оптимізованою, ніж CLR (будь-яка з них). Отже, необроблена продуктивність може бути причиною віддавати перевагу націлюванню на байт-код Java. Однак це деталь реалізації.
Деякі люди кажуть, що байт-код Java був розроблений для мультиплатформності, тоді як CIL був розроблений лише для Windows. Це не так. У фреймворку .NET є кілька ісм "Windows", але в CIL таких немає.
Як приклад пункту 4) вище, я написав іграшкову Java для компілятора CIL деякий час тому. Якщо ви подаєте цей компілятор наступну програму Java:
class Factorial{
public static void main(String[] a){
System.out.println(new Fac().ComputeFac(10));
}
}
class Fac {
public int ComputeFac(int num){
int num_aux ;
if (num < 1)
num_aux = 1 ;
else
num_aux = num * (this.ComputeFac(num-1)) ;
return num_aux ;
}
}
мій компілятор виплюне наступний CIL:
.assembly extern mscorlib { }
.assembly 'Factorial' { .ver 0:0:0:0 }
.class private auto ansi beforefieldinit Factorial extends [mscorlib]System.Object
{
.method public static default void main (string[] a) cil managed
{
.entrypoint
.maxstack 16
newobj instance void class Fac::'.ctor'()
ldc.i4 3
callvirt instance int32 class Fac::ComputeFac (int32)
call void class [mscorlib]System.Console::WriteLine(int32)
ret
}
}
.class private Fac extends [mscorlib]System.Object
{
.method public instance default void '.ctor' () cil managed
{
ldarg.0
call instance void object::'.ctor'()
ret
}
.method public int32 ComputeFac(int32 num) cil managed
{
.locals init ( int32 num_aux )
ldarg num
ldc.i4 1
clt
brfalse L1
ldc.i4 1
stloc num_aux
br L2
L1:
ldarg num
ldarg.0
ldarg num
ldc.i4 1
sub
callvirt instance int32 class Fac::ComputeFac (int32)
mul
stloc num_aux
L2:
ldloc num_aux
ret
}
}
Це дійсна програма CIL, яку можна подати в асемблер CIL, наприклад, ilasm.exeщоб створити виконуваний файл. Як бачите, CIL - це повністю зрозуміла для читання та написання мова. Ви можете легко створити діючі програми CIL у будь-якому текстовому редакторі.
Ви також можете скомпілювати вищезгадану програму Java разом із javacкомпілятором, а потім запустити отримані файли класів за допомогою javap"дизасемблера", щоб отримати таке:
class Factorial extends java.lang.Object{
Factorial();
Code:
0: aload_0
1: invokespecial #1;
4: return
public static void main(java.lang.String[]);
Code:
0: getstatic #2;
3: new #3;
6: dup
7: invokespecial #4;
10: bipush 10
12: invokevirtual #5;
15: invokevirtual #6;
18: return
}
class Fac extends java.lang.Object{
Fac();
Code:
0: aload_0
1: invokespecial #1;
4: return
public int ComputeFac(int);
Code:
0: iload_1
1: iconst_1
2: if_icmpge 10
5: iconst_1
6: istore_2
7: goto 20
10: iload_1
11: aload_0
12: iload_1
13: iconst_1
14: isub
15: invokevirtual #2;
18: imul
19: istore_2
20: iload_2
21: ireturn
}
javapВиходу не компілюється (наскільки мені відомо) , але якщо порівняти його з виходом КСС вище ви можете бачити , що два дуже схожі.