У Perl, як мені створити хеш, ключі якого надходять із заданого масиву?

Скажімо, у мене є масив, і я знаю, що буду робити багато "Чи містить масив X?" перевірки. Ефективний спосіб зробити це - перетворити цей масив на хеш, де ключі є елементами масиву, і тоді ви можете просто сказати

if ($ хеш {X}) {...}

Чи є простий спосіб зробити це перетворення масиву в хеш? В ідеалі він повинен бути досить універсальним, щоб взяти анонімний масив і повернути анонімний хеш.

%hash = map { $_ => 1 } @array;

Це не так коротко, як рішення "@hash {@array} = ...", але для них потрібні хеш і масив, які вже визначені де-небудь ще, тоді як цей може взяти анонімний масив і повернути анонімний хеш.

Для цього потрібно взяти кожен елемент масиву та об’єднати його в пару з «1». Коли цей список пар (ключ, 1, ключ, 1, ключ 1) призначається хешу, непарні з них стають ключами хешу, а парні - відповідними значеннями.

 @hash{@array} = (1) x @array;

Це хеш-фрагмент, список значень з хешу, тому він отримує list-y @ попереду.

З документів :

Якщо вас бентежить, чому ви використовуєте "@" там на зрізі хешу замість "%", подумайте про це так. Тип дужки (квадратний або фігурний) визначає, чи буде це масив чи хеш, який розглядається. З іншого боку, провідний символ ('$' або '@') на масиві чи хеші вказує, чи повертаєте ви сингулярне значення (скаляр) чи множину (список).

@hash{@keys} = undef;

Синтаксис тут, де ви посилаєтесь на хеш за допомогою, @є фрагментом хешу. В основному ми говоримо $hash{$keys[0]}І $hash{$keys[1]}І $hash{$keys[2]}... це список у лівій частині значення =, значення l, і ми присвоюємо цьому списку, який фактично переходить у хеш і встановлює значення для всіх названих ключів. У цьому випадку я вказав лише одне значення, так що це значення переходить $hash{$keys[0]}, а в інших хеш-записах все автовівіфікується (оживає) з невизначеними значеннями. [Моєю початковою пропозицією тут було встановити вираз = 1, який би встановив для однієї клавіші 1, а для інших - undef. Я змінив його для узгодженості, але, як ми побачимо нижче, точні значення не мають значення.]

Коли ви зрозумієте, що lvalue, вираз ліворуч від =, є списком, побудованим з хешу, тоді це почне мати певний сенс, чому ми використовуємо це @. [Якщо я не думаю, що це зміниться в Perl 6.]

Ідея тут полягає в тому, що ви використовуєте хеш як набір. Важливим є не значення, яке я присвоюю; це просто існування ключів. Отже, те, що ви хочете зробити, це не щось на зразок:

if ($hash{$key} == 1) # then key is in the hash

замість цього:

if (exists $hash{$key}) # then key is in the set

Насправді ефективніше просто запустити existsперевірку, ніж турбуватися про значення в хеші, хоча для мене найголовнішим є лише концепція того, що ви представляєте набір лише клавішами хешу. Крім того, хтось зазначив, що використовуючи undefяк значення тут, ми споживатимемо менше місця для зберігання, ніж присвоювали значення. (А також генерує менше плутанини, оскільки значення не має значення, і моє рішення призначить значення лише першому елементу в хеші, а інші залишить undef, а деякі інші рішення обертають колеса, щоб створити масив значень, на які слід входити хеш; повністю витрачені зусилля).

Зверніть увагу, що якщо набір тексту if ( exists $hash{ key } )для вас не надто багато роботи (яку я віддаю перевагу використовувати, оскільки питання, що цікавить, насправді є присутністю ключа, а не правдивістю його значення), тоді ви можете використовувати коротке та солодке

@hash{@key} = ();

Я завжди так думав

foreach my $item (@array) { $hash{$item} = 1 }

було принаймні приємним та читабельним / ремонтопридатним.

Тут існує припущення, що найефективніший спосіб зробити багато "Чи містить масив X?" перевірки полягає у перетворенні масиву в хеш. Ефективність залежить від обмежених ресурсів, часто часу, але іноді місця, а іноді зусиль програміста. Ви принаймні подвоюєте споживану пам'ять, одночасно зберігаючи список і хеш списку. До того ж ви пишете більш оригінальний код, який вам потрібно буде протестувати, задокументувати тощо.

В якості альтернативи, зверніть увагу на модуль Список :: MoreUtils, в зокрема , функції any(), none(), true()і false(). Усі вони беруть блок як умовний, а список як аргумент, подібний до map()та grep():

print "At least one value undefined" if any { !defined($_) } @list;

Я провів швидкий тест, завантаживши половину / usr / share / dict / слів до масиву (25000 слів), потім шукав одинадцять слів, вибраних із цілого словника (кожне 5000-те слово) у масиві, використовуючи обидва масиву -to-хеш-метод та any()функція з List :: MoreUtils.

У Perl 5.8.8, побудованому з вихідного коду, метод масиву до хешу працює майже в 1100 разів швидше, ніж any()метод (на 1300 разів швидший за пакету Perl 5.8.7 Ubuntu 6.06).

Однак це не вся історія - перетворення масиву в хеш займає близько 0,04 секунди, що в цьому випадку знижує ефективність часу методу масиву в хеш в 1,5 рази швидше, ніж any()метод. Все ще добре, але не настільки зоряне.

Мені здається, що метод масиву до хешу буде перемагати any()в більшості випадків, але я відчував би себе набагато краще, якби мав кілька твердіших показників (багато тестових випадків, гідний статистичний аналіз, можливо, якийсь великий O алгоритмічний аналіз кожного методу тощо.) Залежно від ваших потреб, List :: MoreUtils може бути кращим рішенням; це, звичайно, більш гнучко і вимагає менше кодування. Пам’ятайте, передчасна оптимізація - це гріх ... :)

У perl 5.10 є оператор ~~, близький до магії:

sub invite_in {
    my $vampires = [ qw(Angel Darla Spike Drusilla) ];
    return ($_[0] ~~ $vampires) ? 0 : 1 ;
}

Дивіться тут: http://dev.perl.org/perl5/news/2007/perl-5.10.0.html

Також варто звернути увагу на повноту, мій звичайний метод для цього з 2 масивами однакової довжини, @keysі @valsякі ви б віддали перевагу хешу ...

my %hash = map { $keys[$_] => $vals[$_] } (0..@keys-1);

Рішення Ральді можна посилити до цього ("=>" з оригіналу не потрібно):

my %hash = map { $_,1 } @array;

Цей прийом можна також використовувати для перетворення текстових списків у хеші:

my %hash = map { $_,1 } split(",",$line)

Крім того, якщо у вас є рядок таких значень: "foo = 1, bar = 2, baz = 3", ви можете зробити це:

my %hash = map { split("=",$_) } split(",",$line);

[РЕДАКТУВАТИ]

Іншим запропонованим рішенням (яке займає два рядки) є:

my %hash;
#The values in %hash can only be accessed by doing exists($hash{$key})
#The assignment only works with '= undef;' and will not work properly with '= 1;'
#if you do '= 1;' only the hash key of $array[0] will be set to 1;
@hash{@array} = undef;

Ви також можете використовувати Perl6 :: Junction .

use Perl6::Junction qw'any';

my @arr = ( 1, 2, 3 );

if( any(@arr) == 1 ){ ... }

Якщо ви робите багато теоретичних операцій з наборами - ви також можете використовувати Set :: Scalar або подібний модуль. Потім $s = Set::Scalar->new( @array )буде будувати Набір для вас - і ви можете запросити його: $s->contains($m).

Ви можете розмістити код у підпрограмі, якщо не хочете забруднювати свій простір імен.

my $hash_ref =
  sub{
    my %hash;
    @hash{ @{[ qw'one two three' ]} } = undef;
    return \%hash;
  }->();

Або ще краще:

sub keylist(@){
  my %hash;
  @hash{@_} = undef;
  return \%hash;
}

my $hash_ref = keylist qw'one two three';

# or

my @key_list = qw'one two three';
my $hash_ref = keylist @key_list;

Якщо ви дійсно хотіли передати посилання на масив:

sub keylist(\@){
  my %hash;
  @hash{ @{$_[0]} } = undef if @_;
  return \%hash;
}

my @key_list = qw'one two three';
my $hash_ref = keylist @key_list;

#!/usr/bin/perl -w

use strict;
use Data::Dumper;

my @a = qw(5 8 2 5 4 8 9);
my @b = qw(7 6 5 4 3 2 1);
my $h = {};

@{$h}{@a} = @b;

print Dumper($h);

дає (примітка, повторні клавіші отримують значення в найбільшій позиції в масиві - тобто 8-> 2, а не 6)

$VAR1 = {
          '8' => '2',
          '4' => '3',
          '9' => '1',
          '2' => '5',
          '5' => '4'
        };

Ви також можете перевірити Tie :: IxHash , який реалізує впорядковані асоціативні масиви. Це дозволить вам виконувати обидва типи пошуку (хеш та індекс) на одній копії ваших даних.