Автоматично отримувати індекс циклу в циклі foreach у Perl

Якщо я маю такий масив у Perl:

@x = qw(a b c);

і я перебираю це за допомогою foreach, потім $_посилатимуться на поточний елемент у масиві:

foreach (@x) {
    print;
}

надрукує:

abc

Чи існує подібний спосіб отримати індекс поточного елемента без ручного оновлення лічильника? Щось на кшталт:

foreach (@x) {
    print $index;
}

де $indexоновлюється, як $_для отримання результату:

012

Як сказав codehead , вам доведеться перебирати індекси масиву замість його елементів. Я віддаю перевагу цьому варіанту перед forциклом C-стилю :

for my $i (0 .. $#x) {
    print "$i: $x[$i]\n";
}

У Perl до 5.10, можна сказати

#!/usr/bin/perl

use strict;
use warnings;

my @a = qw/a b c d e/;

my $index;
for my $elem (@a) {
    print "At index ", $index++, ", I saw $elem\n";
}

#or

for my $index (0 .. $#a) {
    print "At index $index I saw $a[$elem]\n";
}

У Perl 5.10 ви використовуєте state, щоб оголосити змінну, яка ніколи не переініціалізується (на відміну від створених за допомогою my ). Це дозволяє зберегти $indexзмінну в меншій області, але це може призвести до помилок (якщо ви введете цикл вдруге, він все одно матиме останнє значення):

#!/usr/bin/perl

use 5.010;
use strict;
use warnings;

my @a = qw/a b c d e/;

for my $elem (@a) {
    state $index;
    say "At index ", $index++, ", I saw $elem";
}

У Perl 5.12 можна сказати

#!/usr/bin/perl

use 5.012; # This enables strict
use warnings;

my @a = qw/a b c d e/;

while (my ($index, $elem) = each @a) {
    say "At index $index I saw $elem";
}

Але будьте застережені: у вас є обмеження щодо того, що вам дозволено робити @a, переглядаючи це each.

Зараз це вам не допоможе, але в Perl 6 ви зможете сказати

#!/usr/bin/perl6

my @a = <a b c d e>;
for @a Z 0 .. Inf -> $elem, $index {
    say "at index $index, I saw $elem"
}

ZОператор застібає два списки разом (тобто він приймає один елемент з першого списку, то один елемент з другого, то один елемент з першого, і так далі). Другий список - це лінивий список, який містить кожне ціле число від 0 до нескінченності (принаймні теоретично). Це -> $elem, $indexговорить про те, що ми беремо два значення одночасно з результату zip. Решта повинна виглядати нормально для вас (якщо ви ще не знайомі з sayфункцією з 5.10).

perldoc perlvar схоже, не пропонує жодної такої змінної.

Не з foreach.

Якщо вам точно потрібна потужність елемента в масиві, використовуйте ітератор 'for':

for ($i=0; $i<@x; ++$i) {
  print "Element at index $i is " , $x[$i] , "\n";
}

Це можна зробити за допомогою whileциклу ( foreachце не підтримує):

my @arr = (1111, 2222, 3333);

while (my ($index, $element) = each(@arr))
{
   # You may need to "use feature 'say';"
   say "Index: $index, Element: $element";
}

Вихід:

Index: 0, Element: 1111
Index: 1, Element: 2222
Index: 2, Element: 3333

Версія Perl: 5.14.4

Ні, ви повинні зробити власний лічильник. Ще один приклад:

my $index;
foreach (@x) {
    print $index++;
}

при використанні для індексації

my $index;
foreach (@x) {
    print $x[$index]+$y[$index];
    $index++;
}

І звичайно ви можете використовувати local $index;замість цього my $index;і так і так.

Так. Я перевірив стільки книг та інших блогів ... Висновок полягає в тому, що для лічильника циклів не існує жодної системної змінної. Ми повинні зробити власний лічильник. Виправте мене, якщо я помиляюся.

autobox::Coreсеред багатьох інших речей пропонує зручний forметод:

use autobox::Core;

['a'..'z']->for( sub{
    my ($index, $value) = @_;
    say "$index => $value";
});

Або подивіться на модуль ітератора, наприклад: Array::Iterator

use Array::Iterator;

my $iter = Array::Iterator->new( ['a'..'z'] );
while ($iter->hasNext) {
    $iter->getNext;
    say $iter->currentIndex . ' => ' . $iter->current;
}

Також див.

• кожен до свого (автобокс)
• perl5i

О так, ти можеш! (начебто, але не слід). each(@array)у скалярному контексті дає вам поточний індекс масиву.

@a = (a..z);
for (@a) { 
  print each(@a) . "\t" . $_ . "\n"; 
}

Ось each(@a)у скалярному контексті і повертає лише індекс, а не значення цього індексу. Оскільки ми в forциклі, ми вже маємо значення в $ _. Той самий механізм часто використовується в циклі while-each. Та сама проблема.

Проблема виникає, якщо ви for(@a)повторите. Індекс не повертається до 0, як ви очікували; за ним undefйде 0,1,2 ... один відлік. Перлдок each()каже, щоб уникати цієї проблеми. Використовуйте forцикл для відстеження індексу.

кожен

В основному:

for(my $i=0; $i<=$#a; $i++) {
  print "The Element at $i is $a[$i]\n";
}

Я шанувальник альтернативного методу:

my $index=0;
for (@a) {
  print "The Element at $index is $a[$index]\n";
  $index++;
}

Будь ласка, враховуйте:

print "Element at index $_ is $x[$_]\n" for keys @x;

Ну, є такий спосіб:

use List::Rubyish;

$list = List::Rubyish->new( [ qw<a b c> ] );
$list->each_index( sub { say "\$_=$_" } );

Див. Список :: Рубіновий .

Вам не потрібно знати індекс у більшості обставин. Ви можете зробити це:

my @arr = (1, 2, 3);
foreach (@arr) {
    $_++;
}
print join(", ", @arr);

У цьому випадку результат буде 2, 3, 4, оскільки foreach встановлює псевдонім фактичного елемента, а не просто копії.

Я пробував, як ....

@array = qw /tomato banana papaya potato/;             # Example array
my $count;                                             # Local variable initial value will be 0.
print "\nBefore For loop value of counter is $count";  # Just printing value before entering the loop.

for (@array) { print "\n",$count++," $_" ; }           # String and variable seperated by comma to
                                                       # execute the value and print.
undef $count;                                          # Undefining so that later parts again it will
                                                       # be reset to 0.

print "\nAfter for loop value of counter is $count";   # Checking the counter value after for loop.

Коротко...

@array = qw /a b c d/;
my $count;
for (@array) { print "\n",$count++," $_"; }
undef $count;