Пакетне перейменування файлу із суфіксом як випадкове буквено-цифрове

Ось код, який перейменовує всі файли в папці на буквено-цифрові.

@echo off
setlocal disableDelayedExpansion
set "chars=ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
for /f "eol=: delims=" %%F in ('dir /b /a-d *.jpg') do call :renameFile "%%F"
exit /b

:renameFile
setlocal enableDelayedExpansion
:retry
set "name="
for /l %%N in (1 1 8) do (
  set /a I=!random!%%36
  for %%I in (!I!) do set "name=!name!!chars:~%%I,1!"
)
echo if exist !name!.jpg goto :retry
endlocal & ren %1 %name%.jpg

Все, що вам потрібно зробити, - скопіювати / вставити цей код і зберегти його .bat файл і розмістити у будь-яких папках, де ви хочете перейменувати файли.

Ось як це працює:

приклад: якщо ім'я файлу - lenovo-wallpaper.jpg, воно перейменовано його на AF45ASLJ.JPG

Що я хочу, це ім'я файлу + alphanumeric.jpg

приклад: якщо ім'я файлу - lenovo-wallpaper.jpg, тоді воно повинно бути lenovo-wallpaper-adfs45fad1.jpg

Змініть останні два рядки з

echo if exist !name!.jpg goto :retry
endlocal & ren %1 %name%.jpg

до

echo if exist %~n1+!name!.jpg goto :retry
endlocal & ren %1 %~n1+%name%.jpg

%~n1отримає ім'я файлу без розширення, а потім просто додаючи +до нового імені змінної.

EDIT: Повна партія з великої літери та зйомки файлів JPG, BMP, PNG та GIF

@echo off
setlocal disableDelayedExpansion
set "chars=ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
for /f "eol=: delims=" %%F in ('dir /b /a-d *.jpg *.png *.bmp *.gif') do call :renameFile "%%F"
exit /b

:renameFile
setlocal enableDelayedExpansion
:retry
set "name="
for /l %%N in (1 1 8) do (
  set /a I=!random!%%36
  for %%I in (!I!) do set "name=!name!!chars:~%%I,1!"
)
echo if exist %~n1+!name!.jpg goto :retry
call :FirstUp result %~n1
endlocal & ren %1 %result%+%name%.*

exit /b

:FirstUp
setlocal EnableDelayedExpansion
set "temp=%~2"
set "helper=##AABBCCDDEEFFGGHHIIJJKKLLMMNNOOPPQQRRSSTTUUVVWWXXYYZZ"
set "first=!helper:*%temp:~0,1%=!"
set "first=!first:~0,1!"
if "!first!"=="#" set "first=!temp:~0,1!"
set "temp=!first!!temp:~1!"
(
    endlocal
    set "result=%temp%"
    goto :eof
)