Дані XML з однієї комірки Excel до нового файлу XML [закрито]

У A1, A2, A3 ... A16000 я маю весь контекст XML в одній комірці.

Приклад: Весь XML для одного рахунка-фактури знаходиться в A1, наступний рахунок-фактура в A2 і так далі.

Як я можу зберегти контекст кожної комірки в окремі файли XML?

Я спробував витягти відповідні дані безпосередньо з комірки, використовуючи "filterxml", але я зіткнувся з неприємностями, коли інновація містила рядки пунктів.

Припускаючи, що весь XML дійсно є дійсним форматом XML, і вам просто потрібно експортувати кожну клітинку як її власний файл, ви можете використовувати наступні VBA:

Sub ExportCellsToXMLFiles()
    On Error GoTo err:
    Dim OutputFolder: OutputFolder = "D:\Test\XML\" 'Specify a valid dir to output to - make sure you include the trailing slash.
    Dim objFSO: Set objFSO = CreateObject("Scripting.FileSystemObject")
    Dim objFile
    Dim Count: Count = 1 'Row number to start on
    Do
        Set objFile = objFSO.CreateTextFile(OutputFolder & "Invoice_" & Count & ".xml", False, True) ' You can change the file names if needed here
        objFile.Write (Cells(Count, 1).Value)
        objFile.Close
        Count = Count + 1
    Loop Until IsEmpty(Cells(Count, 1).Value)

err:
    Set objFile = Nothing
    Set objFSO = Nothing
End Sub

EDIT: Я думаю, що деякі програми можуть не інтерпретувати його правильно, оскільки вони очікують кодування UTF-8. Спробуйте замість цього коду:

Sub ExportCellsToXMLFiles()
    On Error GoTo err:
    Dim OutputFolder: OutputFolder = "D:\Test\XML\"
    Dim fsT As Object
    Dim Count: Count = 1
    Do
        Set fsT = CreateObject("ADODB.Stream")
        fsT.Type = 2
        fsT.Charset = "utf-8"
        fsT.Open
        fsT.WriteText (Cells(Count, 1).Value)
        fsT.SaveToFile OutputFolder & "Invoice_" & Count & ".xml", 2
        Count = Count + 1
    Loop Until IsEmpty(Cells(Count, 1).Value)

err:
    Set fsT = Nothing
End Sub