Як визначити, чи є в моїй системі Windows 10 за допомогою командного рядка? [дублікат]

Я працюю з InstallAnywhere, старою програмою створення інсталяторів. Я хотів би встановити певний файл, лише у випадку Windows XP та Windows Vista.

Через обмеження InstallAnywhere це неможливо. Я можу вирішити видалити файл лише після того, як він уже встановлений, виходячи з правила.

У рамках цього правила я можу перевірити платформу, на якій я працюю, що дає мені можливість перевірити наявність Windows XP, Windows Vista, Windows 7 тощо, але не для Windows 10. Я не можу сказати "Виконай це дії, коли система не є XP чи Vista ", тому мені потрібно сказати" Виконайте цю дію на всіх тих платформах, які не є XP чи Vista ".

Однак я можу запускати команди командного рядка і отримувати результат, тому ось моє запитання: чи є команда, яку я можу використовувати для визначення, чи працюю я в системі Windows 10?

Чи є команда визначити, чи працюю я в системі Windows 10?

Можна використовувати wmic.

Наступна команда поверне версію Windows.

wmic os get Caption | findstr /v Caption

Приклад виводу:

F:\test>wmic os get Caption | findstr /v Caption
Microsoft Windows 7 Home Premium

Якщо ви хочете трохи більше інформації, ви можете використовувати наступний пакетний файл (GetOS.cmd), який буде завантажений та відображений:

• Версія операційної системи
• Основна версія пакета оновлень
• Архітектура (64 або 32 біт)

@echo off
setlocal
setlocal enabledelayedexpansion
set _os=
set _sp=
rem use findstr to strip blank lines from wmic output
rem get OS
for /f "usebackq skip=1 tokens=3" %%i in (`wmic os get caption ^| findstr /r /v "^$"`) do (
  set "_os=%%i"
  )
rem get Service Pack
for /f "usebackq skip=1 tokens=*" %%i in (`wmic os get ServicePackMajorVersion ^| findstr /r /v "^$"`) do (
  set "_sp=%%i"
  )
rem get Architecture
for /f "usebackq skip=1 tokens=*" %%i in (`wmic OS get OSArchitecture ^| findstr /r /v "^$"`) do (
  set "_bits=%%i"
  )
echo Operating System Version: %_os%
echo Service Pack Major Version: %_sp%
echo Architecture: %_bits%
endlocal

Версія ОС зберігається в %_os, Основна версія пакета оновлень зберігається %_sp%, а архітектура зберігається в %_bits%.

Примітки:

• Не повністю перевірений, оскільки я не маю всіх комбінацій ОС та Service Pack, щоб перевірити його.

• forКоманда отримує лише 3 - у частину (токенов) ОС. Це буде працювати для версій для настільних ПК (якщо ви хочете відрізнити Server 2008 від інших версій, вам потрібно буде знайти інше рішення).

• %_osбуде встановлений в одне з наступних значень: Server, Vista, 7, 8, 8.1або 10.

Приклад виводу:

F:\test>GetOS
Operating System Version: 7
Service Pack Major Version: 1
Architecture: 64-bit

F:\test>

Подальше читання

• Індекс AZ командного рядка Windows CMD - відмінна довідка для всіх речей, пов'язаних з командним рядком Windows.
• Findstr - Пошук рядків - Windows CMD - SS64.com
• Для / f - Цикл виводу команд - Windows CMD - SS64.com
• Якщо - Умовно виконуйте команду - Windows CMD - SS64.com
• WMIC - Керування Windows - Windows CMD - SS64.com

Я не можу повірити в це довго і жодної верховної команди

C:\>ver

Microsoft Windows [Version 10.0.10586]

C:\>

Він працює в переадресаціях, щоб ви могли це зробити

ver | find "Version 10."

Але зазвичай слід писати "для цієї та всіх майбутніх версій", щоб вам було краще перерахувати попередні.

системна інформація

отримує багато корисних відомостей, таких як Операційна система, Тип системи (32/64 біт) і так довго:

Я не маю досвіду з InstallAnywhere, але є два варіанти, щоб побачити, яка ОС встановлена ​​за допомогою командного рядка.

1. Використання Cmd

   systeminfo.exe
   

   Використовуючи команду systeminfo.exe, ви можете побачити результат під полем OS Name. Це може дати вам більше інформації, ніж вам потрібно.

   Більше інформації про цю команду можна знайти в Microsoft TechNet .

2. Powershell

   Крім того, ви можете використовувати наступний скрипт Powershell, який поверне точну інформацію, яку ви хочете.

   Get-CimInstance Win32_OperatingSystem | Select-Object  Caption | ForEach{ $_.Caption }