Використання wmic, щоб знайти, чи існує продукт

Я хочу написати пакетний файл, який перевіряє, чи існує програма, і чи існує вона, я хотів би її видалити. Це те, що у мене поки що.

 @echo off
 (wmic product get name| findstr /i "abc123")

Це не так багато, але в основному, якщо він знаходить "abc123", я хотів би, щоб він запустив запустити видалення на ньому. Ось що я маю за це поки що.

 wmic product where name="abc123" call uninstall/nointeractive

Я не впевнений, як встановити тип оператора 'if true' для першого набору коду, який активує другий набір коду.

Все, що повертається як "помилкове", програма в основному пропускає видалення.

Якщо у вас є якісь питання, будь ласка, не соромтеся їх задавати. Дякую!

Виберіть будь-який:

• 'перенаправлення' спосіб
• спосіб 'if errorlevel'
• спосіб "прямий дзвінок"

Прочитайте, як FINDSTRбуде встановленоERRORLEVEL

@ECHO OFF
SETLOCAL EnableExtensions
set "_product=abc123"
rem set "_product=avg zen"

echo 'redirection' way
(wmic product get name| findstr /i /C:"%_product%")&&(
    echo %_product% exists
    rem uninstall here
  )||(
    echo %_product% no instance
  )

echo 'if errorlevel' way
wmic product get name| findstr /i /C:"%_product%"
if errorlevel 1 (
  echo %_product% no instance
) else (
  echo %_product% exists
  rem uninstall here
)

echo 'direct call' way
wmic product where "name='%_product%'" call uninstall/nointeractive

Вихід для set "_product=abc123":

==> D:\bat\SU\1087355.bat
'redirection' way
abc123 no instance
'if errorlevel' way
abc123 no instance
'direct call' way
No Instance(s) Available.

Вихід для, set "_product=avg zen"але з "прямим викликом" пропущено:

==> D:\bat\SU\1087355.bat
'redirection' way
AVG Zen
avg zen exists
'if errorlevel' way
AVG Zen
avg zen exists