Видаліть контакт із груп контактів у перспективі

Нещодавно колега пішов у відставку з нашої компанії, і мені потрібно видалити її з
усіх груп контактів у моєму Outlook.
Будь-яка пропозиція буде вдячна!
Чи легко це зробити?

Для видалення одного контакту з усіх груп потрібен макрос VBA.

Такий макрос детально описаний у статті Як швидко видалити конкретний контакт із усіх груп контактів через Outlook VBA .

У статті детально описано, як такий макрос встановлюється на вкладці Developer / Visual Basic, а згодом його можна запустити за допомогою піктограми Run на панелі інструментів.

Якщо ця стаття пізніше зникне, макрос VBA детально описаний тут:

Sub RemoveSpecificContactfromAllGroups()
    Dim strSpecificContact As String
    Dim objTempMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objContactsFolder As Outlook.Folder
    Dim objItem As Object
    Dim objContactGroup As Outlook.DistListItem
    Dim objContact As Outlook.ContactItem
    Dim nprompt As Integer

    strSpecificContact = InputBox("Input the fullname or email address of the specific contact to be removed from all contact groups:")
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
    Set objRecipient = objTempMail.Recipients.Add(strSpecificContact)
    objRecipient.Resolve

    If objRecipient.Resolved = True Then
       Set objContactsFolder = Outlook.Application.Session.GetDefaultFolder(olFolderContacts)
       For Each objItem In objContactsFolder.Items
           If TypeOf objItem Is DistListItem Then
              Set objContactGroup = objItem
              With objContactGroup
                   .RemoveMember objRecipient
                   .Body = "Contact Removed: " & strSpecificContact & vbTab & "(" & Now & ")" & .Body
                   .Save
              End With
           End If
       Next
       nprompt = MsgBox("Removing Completes!", vbExclamation, "Remove Contact from Group")
    Else
       nprompt = MsgBox("This contact cannot be resolved!", vbExclamation, "Resolving Error")
    End If
End Sub