У мене є правило Outlook 2007, яке копіює певні вихідні повідомлення в іншу папку - як я автоматично позначаю ці повідомлення як "прочитані"?

Повідомлення успішно копіюються в іншу папку, але відображаються як непрочитані.

"Позначити як прочитане" відображається як фільтр у списку дій при створенні правила, яке застосовується до вхідних повідомлень, але я не бачу його під час створення правила, що застосовується до повідомлень OUTGOING . Як я можу це досягти?

Ось повний текст мого існуючого рядка з описом правила:

Apply this rule after I send the message
on this machine only
move a copy to the Archive folder

Оновлення:
@ xxl3ww зазначає, що там є сценарії VB, які можуть досягти цього. Я б хотів не платити за один із них. Якісь безкоштовні альтернативи, про які хтось знає?

Вам потрібно буде включити Макроси для роботи наступного коду. У розділі Інструменти> Макроси> Зміни безпеки на "Попередження для всіх макросів" або "Немає перевірок безпеки"

Клацніть Інструменти> Макроси> Редактор Visual Basic

Скопіюйте та вставте наступне:

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Item.UnRead = False
End Sub

Це воно! (Поряд із наявним правилом повідомлення)

Вам потрібно налаштувати це, щоб воно відповідало іменам вашої папки / поштової скриньки, але це встановить нещодавно додані елементи (тобто електронні листи, переміщені вашим правилом) як прочитані:

Option Explicit
'##############################################
'### all code for the ThisOutlookSession module
'### Module level Declarations
'expose the items in the target folder to events
Dim WithEvents TargetFolderItems As Items

'###############################################
Private Sub Application_Startup()
'some startup code to set our "event-sensitive"
'items collection

Dim myMailbox As String, myFolder As String

'You need to set these
myMailbox = "Mailbox - My Name"
myFolder = "Archive Folder Name"

Dim ns As Outlook.NameSpace

Set ns = Application.GetNamespace("MAPI")
Set TargetFolderItems = ns.Folders(myMailbox).Folders(myFolder).Items

End Sub

'#################################################
'### this is the ItemAdd event code
Sub TargetFolderItems_ItemAdd(ByVal Item As Object)
'when a new item is added to our "Testing Folder"
'we can process it
Dim myEmail As MailItem
Set myEmail = Item
myEmail.UnRead = False
End Sub

'#################################################
Private Sub Application_Quit()

Dim ns As Outlook.NameSpace
Set TargetFolderItems = Nothing
Set ns = Nothing

End Sub

Побудуйте своє правило за допомогою майстра правил (інструменти -> правила та сповіщення). Третій екран дозволяє позначити повідомлення як прочитане. Можливо, вам доведеться трохи прокрутити вниз, щоб знайти потрібний прапорець.

Хоча це технічно не є "вихідним" правилом, воно буде працювати, якщо запустити його вручну. Я не думаю, що в офісі є вбудований спосіб зробити перевірку автоматично.