Вибірково включати Intel turbo boost?

На ноутбуках технологія Intel "Turbo-Boost" від Intel може призвести до небажаних високих температур процесора та супутнього шуму вентиляторів, а в залежності від моделі - навіть до звукової нестабільної котушки, яка скуголить при використанні максимальних тактових частот. Зокрема, веб-перегляд веб-сайтів, як правило, призводить до частого сплеску тактової частоти, а блокатори реклами зменшують, але не усувають симптоми. Зокрема, веб-перегляд призводить до небажаних сплесків температури процесора, хоча це не дуже вимагає такої продуктивності.

Встановлення максимальної швидкості процесора до 99% у розширених налаштуваннях плану живлення Windows дозволяє ефективно відключити Turboboost, щоб уникнути цієї проблеми.

На жаль, це рішення кувалдою до тріщини-горіха. Знижені викиди є актуальними для безперервно запущених програм (Webbrowser, Office, ...), але суттєвий вплив на швидкість обробки небажаний для деяких короткочасних завдань (Компіляція, аналіз даних, ...), де я як користувач контролювати, коли і на який термін вони бігають - і часто вимагати часу очікування, поки вони роблять.

Чи можна якось знайти посередництво, де програмам заборонено використовувати TurboBoost за замовчуванням, але виконуваним файлам можна вибірково дозволити доступ до повної продуктивності процесора?

Напевно, неможливо ввімкнути Turboboost вибірково, про що я вже задавав питання. Однак, як "наступна найкраща річ", може бути достатньо використовувати обгортку, яка змінює силові плани до та після виконання нетривалої команди. Я опублікував це як https://github.com/kbauer/with-high-performance

На момент написання сценарію така форма:

:: -- with-high-performance.cmd
@echo off
if "%~1"=="" (
   echo.
   echo    Usage: %0 COMMAND ...
   echo.
   echo    Execute COMMAND with HighPerformance powerplan.
   echo    Once COMMAND is finished, switch back to Balanced.
   echo.
   echo    For the time being, doesn't support detecting if another
   echo    process is being executed in this panner.
   echo.
   echo    If you need other power plans than the "balanced"
   echo    and "high performance" plans, change the UIDs in the 
   echo    script to a value as obtained by running
   echo.
   echo    ^ ^ ^ ^ POWERCFG /LIST
   echo.
   exit /b 1
)

setlocal
set high=8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c
set balanced=381b4222-f694-41f0-9685-ff5bb260df2e
echo %0^> %* >&2
call powercfg.exe -setactive %high%
call %*
set command_errorlevel=%errorlevel%
call powercfg.exe -setactive %balanced%
endlocal
exit /b %command_errorlevel%

Зауважте, що, хоча сценарій правильно перемикає силові плани, поки що я не бачив прискорення роботи під час використання pdflatex / latexmk.